430849_es-ES

liliconcom

¿Cómo actualizo un script para una tabla de variabilidad para dibujar líneas de referencia que hagan referencia a la configuración del filtro de datos?

Hola,

Estoy trabajando en un gráfico de variabilidad en el que tengo datos continuos que estoy representando por subgrupo. Tengo 3 bandas de temperatura de datos: "1 °C a 13 °C", "16 °C a 28 °C" y "30 °C a 45 °C". Me gustaría tener líneas de referencia dibujadas para cada categoría de filtro que selecciono en los datos; hay 3 grupos de líneas de referencia diferentes.

Vea el archivo adjunto y el script de variabilidad.

Soy relativamente nuevo en la creación de scripts. He visto cómo el comando de creación de scripts JMP permite escribir el comando para cada línea de referencia. Quiero que el comando sea dinámico en función de lo que seleccione el filtro de datos. (sección subrayada en negrita del script).

Por favor avise,

Gracias

Mate

New Window( "Sample set 1 - Variability Chart by Lot",
	V List Box(
		Variability Chart(
			Y( :Test 1 ),
			X( :Lot ),
			Std Dev Chart( 0 ),
			Local Data Filter( Add Filter( columns( :Temp Band 2 ) ) ),
			SendToReport(
				Dispatch(
					{"Variability Chart for Test 1"},
					"2",
					ScaleBox,
					{Min( 0.814090277777778 ), Max( 1.13166666666667 ), Inc( 0.05 ),
					Minor Ticks( 1 ), Add Ref Line(
						0, "Dotted", "Medium Light Gray", "", 1
					), Add Ref Line( <U><STRONG>1.1</STRONG></U>, "Solid", "Black", "", 1 ),
					Add Ref Line(<U> <STRONG>0.9</STRONG></U>, "Solid", "Black", "", 1 )}
				)
			)
		),
		Variability Chart(
			Y( :Test 2 ),
			X( :Lot ),
			Std Dev Chart( 0 ),
			Local Data Filter( Add Filter( columns( :Temp Band 2 ) ) )
		),
		Variability Chart(
			Y( :Test3 ),
			X( :Lot ),
			Std Dev Chart( 0 ),
			Local Data Filter( Add Filter( columns( :Temp Band 2 ) ) )
		)
	)
)

Exploración y visualización de datosRe: ¿Cómo actualizo una secuencia de comandos para la tabla de variabilidad para dibujar líneas de referencia que se refieran a la configuración del filtro de datos?

Hola @mcastner , diría que eligió una tarea bastante complicada para comenzar a crear secuencias de comandos.A continuación hay una forma de hacer lo que me pidió (si lo interpreté correctamente), pero me pregunto si podría hacerlo más fácil usando el generador de gráficos para dibujar un diagrama de caja y una línea al mismo tiempo.¿Cómo se te ocurren valores para las líneas de referencia?¿Hay alguna posibilidad de que sea un resumen de los datos disponibles (mediana, cuantil, etc.), o podría hacerlo en una columna de fórmula?

 

 

Names default to here(1);

dt = Open( "$Sample_data/big class.jmp" );

//Valeus for ref lines - hopefully populated by your script
reflines = Associative Array({
 {"height", 
  Associative Array({
   { 12, 62 },
   { 13, 63 },
   { 14, 64 },
   { 15, 65 },
   { 16, 66 },
   { 17, 67 }
  })
 },
 {"weight",
  Associative Array({
   { 12, 112 },
   { 13, 113 },
   { 14, 114 },
   { 15, 115 },
   { 16, 116 },
   { 17, 117 }
  })
 }
});

//A window with a single data filter that will be applied to all graphs inside it
New Window("charts",
 Data Filter Context Box(
  H List Box(
   ldf = dt << Data Filter( Local,
    Add Filter(
     columns( :age ),
     Where( :age == 13 ),
     Display( :age, N Items( 6 ) )
    ),
    Mode( Select( 0 ), Show( 1 ), Include( 1 ) )
   ),
   vc1 = Variability Chart(
    Y( :height ),
    X( :sex )
   );
   vc2 = Variability Chart(
    Y( :weight ),
    X( :sex )
   );
  )
 )
);

//Function that is called when data filter changes and when the window is first opened, this will redraw lines on charts
UpdateRefLines = function({}, 
 
 //find out what ages were selected, there is probably a better way to do this too
 filteredagelast = filteredage;
 filteredage = median(dt:age[ldf << get filtered rows()]);
 
 //detect if there was a change in the age (prevents flickering of the screen)
 if(is missing(filteredagelast) | (filteredagelast != filteredage),
  
  //remove any existing ref lines
  (vc1 << XPath("//AxisBox[@charID=2]"))[1] << Revert Axis;
  (vc2 << XPath("//AxisBox[@charID=2]"))[1] << Revert Axis;
  
  //draw new lines
  (vc1 << XPath("//ScaleBox[@ID=2]")) << Add Ref Line( reflines["height"][FilteredAge], "Solid", "Black", "", 1 );
  (vc2 << XPath("//ScaleBox[@ID=2]")) << Add Ref Line( reflines["weight"][FilteredAge], "Solid", "Black", "", 1 );
 )
);

//function called when data filter changes, here it only redraws reference lines
UpdatesOnRowStateChanges = function({x}, if(is matrix(x), UpdateRefLines ) );

//variable used to keep track of the last filter applied
filteredage = .;

//Assign function to data filter 
rsh = vc1 << Make Row State Handler( dt, UpdatesOnRowStateChanges );

//draw initial reference lines
UpdateRefLines();