저는 농업 분야에서 연구를 수행하며 대부분의 사람들처럼 Excel을 사용하여 데이터를 구성합니다. 그러나 일반적인 분석은 성장기 전반에 걸쳐 질병의 변화를 추적하기 위한 질병 진행 곡선 아래 면적(AUDPC)입니다. 추세선/회귀 분석을 맞추지 않고 선 그래프 아래의 총 면적을 계산하는 방법이 있습니까?
안녕하세요,
이를 달성할 수 있는 유일한 방법은 데이터 포인트와 그래프의 바닥에 의해 정의된 다각형 영역을 계산하는 것입니다.
area = Polygon Area( {0, 0}, {0, 10}, {10, 10}, {10, 0} );
참고: 1) 수식에서 이 함수를 사용할 수 있습니다. 2)위의 간단한 예와 같이 다각형의 원점을 포함하는 것이 중요합니다.
최상의,
TS
티에리,
응답해 주셔서 감사합니다. 게시한 공식이 Excel 소프트웨어 내에서 적용된다고 가정하고 있습니까? 아니면 JMP 소프트웨어 내에서 이것을 사용하는 방법이 있습니까?
최상의,
게시된 공식은 Excel이 아닌 JMP용입니다. 의 회신을 바탕으로 @티에리_S JMP용 스크립팅 언어인 JSL에서 이러한 종류의 작업을 수행할 수 있습니다.
NamesDefaultToHere(1);
// Some simple data
dt =
New Table( "AUDPC Example",
Add Rows( 4 ),
New Column( "x", Numeric, "Continuous", Set Values( [0, 1, 2, 3] )),
New Column( "y", Numeric, "Continuous", Set Values( [3, 4, 4.5, 5] ))
);
// A graph
gb = dt << Graph Builder(
Size( 526, 454 ),
Show Control Panel( 0 ),
Show Legend( 0 ),
Variables( X( :x ), Y( :y ) ),
Elements( Line( X, Y, Legend( 5 ) ) ),
SendToReport(
Dispatch(
{},
"x",
ScaleBox,
{Min( -1 ), Max( 4 ), Inc( 0.5 ), Minor Ticks( 0 ),
Add Ref Line( 0, "Dashed", "Red", "", 1 ),
Add Ref Line( 3, "Dashed", "Red", "", 1 )}
),
Dispatch(
{},
"y",
ScaleBox,
{Format( "Best", 12 ), Min( -1 ), Max( 6 ), Inc( 1 ), Minor Ticks( 1 ),
Add Ref Line( 0, "Dashed", "Red", "", 1 ),
Add Ref Line( 1, "Dashed", "Red", "", 1 )}
)
)
);
// Start here . . .
dt = CurrentDataTable();
// Get the x and y values
xVals = Column(dt, "x") << getValues;
yVals = Column(dt, "y") << getValues;
// Insert two points that define the base of the polygon at the value y = 0
baseLine = [0];
xVals2 = VConcat(xVals[1], xVals, xVals[NRow(xVals)]);
yVals2 = VConcat(baseLine, yVals, baseline);
// Get the area
a2 = PolygonArea(xVals2, yVals2);
Print(a2);
// Insert two points that define the base of the polygon at the value y = 1
baseLine = [1];
xVals3 = VConcat(xVals[1], xVals, xVals[NRow(xVals)]);
yVals3 = VConcat(baseLine, yVals, baseline);
// Get the area
a3 = PolygonArea(xVals3, yVals3);
Print(a3);
'파일 > 새로 만들기 > 새 스크립트'를 실행하고 위의 코드를 잘라내어 나타나는 창에 붙여넣은 다음 '편집 > 스크립트 실행'을 수행합니다. JSL을 배우고 싶지 않을 수도 있다는 것을 이해합니다. 이것은 데이터 값으로 정의된 폴리곤 '아래' 영역을 제공합니다. 어떤 종류의 적합 곡선 아래 영역을 원할 수도 있고 원하지 않을 수도 있지만 이것도 가능합니다.
