私は農業分野で研究を行っており、ほとんどの人と同じようにExcelを使用してデータを整理しています。 ただし、一般的な分析は、成長期を通じて病気の変化を追跡するための病気の進行曲線（AUDPC）の下の領域です。 トレンドライン/回帰分析を適合させずに、折れ線グラフの下の総面積を計算する方法はありますか？
やあ、
これを実現する唯一の方法は、データポイントとグラフのフロアによって定義されるポリゴン領域を計算することです。
area = Polygon Area( {0, 0}, {0, 10}, {10, 10}, {10, 0} );
注：1）この関数は数式で使用できます。 2）上記の簡単な例に示すように、ポリゴンの原点を含めることが重要です。
一番、
NS
ティエリー、
ご返信ありがとうございます。 あなたが投稿した数式はExcelソフトウェア内で適用されると思いますか？ または、JMPソフトウェア内でこれを使用する方法はありますか？
一番、
掲載されている数式は、ExcelではなくJMP用です。 からの返信に基づいて構築@Thierry_Sこの種のことは、JMPのスクリプト言語であるJSLで行うことができます。
NamesDefaultToHere(1);
// Some simple data
dt =
New Table( "AUDPC Example",
Add Rows( 4 ),
New Column( "x", Numeric, "Continuous", Set Values( [0, 1, 2, 3] )),
New Column( "y", Numeric, "Continuous", Set Values( [3, 4, 4.5, 5] ))
);
// A graph
gb = dt << Graph Builder(
Size( 526, 454 ),
Show Control Panel( 0 ),
Show Legend( 0 ),
Variables( X( :x ), Y( :y ) ),
Elements( Line( X, Y, Legend( 5 ) ) ),
SendToReport(
Dispatch(
{},
"x",
ScaleBox,
{Min( -1 ), Max( 4 ), Inc( 0.5 ), Minor Ticks( 0 ),
Add Ref Line( 0, "Dashed", "Red", "", 1 ),
Add Ref Line( 3, "Dashed", "Red", "", 1 )}
),
Dispatch(
{},
"y",
ScaleBox,
{Format( "Best", 12 ), Min( -1 ), Max( 6 ), Inc( 1 ), Minor Ticks( 1 ),
Add Ref Line( 0, "Dashed", "Red", "", 1 ),
Add Ref Line( 1, "Dashed", "Red", "", 1 )}
)
)
);
// Start here . . .
dt = CurrentDataTable();
// Get the x and y values
xVals = Column(dt, "x") << getValues;
yVals = Column(dt, "y") << getValues;
// Insert two points that define the base of the polygon at the value y = 0
baseLine = [0];
xVals2 = VConcat(xVals[1], xVals, xVals[NRow(xVals)]);
yVals2 = VConcat(baseLine, yVals, baseline);
// Get the area
a2 = PolygonArea(xVals2, yVals2);
Print(a2);
// Insert two points that define the base of the polygon at the value y = 1
baseLine = [1];
xVals3 = VConcat(xVals[1], xVals, xVals[NRow(xVals)]);
yVals3 = VConcat(baseLine, yVals, baseline);
// Get the area
a3 = PolygonArea(xVals3, yVals3);
Print(a3);
[ファイル]> [新規]> [新しいスクリプト]を実行し、上記のコードを切り取って表示されるウィンドウに貼り付けてから、[編集]> [スクリプトの実行]を実行します。 JSLを学びたくないと思われるかもしれません。 これにより、データ値によって定義されたポリゴンの下の領域が得られることに注意してください。 ある種のフィットカーブの下の領域が必要な場合と不要な場合がありますが、これも可能です。
