430369_es-ES

liliconcom

Cómo cambiar una columna a la hora si tiene un formato extraño

Hola, todos,

 

Tengo una columna que tiene tiempo y está formateada como esta 01h17m03s Me gustaría hacer estos datos continuos y todo lo que trato de hacer no funciona. ¿Puedo usar un script para cambiar esto?

 

Cualquier idea ayudaría enormemente.

 

Gracias,

 

-Ryan

Tabla de datosScriptingRe: como cambiar una columna a la hora si esta en un formato extraño

Podría usar una fórmula donde: txt es su columna con tiempo:

InHours(Num(Word(1, :Txt, "hms"))) + InMinutes(Num(Word(2, :Txt, "hms"))) + Num(Word(3, :Txt, "hms"))

Y luego cambie la columna a Numérico continuo y formatee como Hora h: m: s (puede diferir dependiendo de su formato de hora)

 

 

Re: como cambiar una columna a la hora si esta en un formato extraño

Names Default to Here( 1 );

// make data like 01h17m03s
dt = New Table( "Time",
 Add Rows( 10 ),
 New Column( "Original", Character, Ordinal ),
 New Column( "Converted", Numeric, Continuous, Format( "H:M:S" ) )
);

// utility
padded = Function( { l, h }, { v },
 v = Random Integer( l, h );
 v = If( v < 10, "0", "" ) || Char( v );
);

// populate original value
For Each Row(
 h = padded( 0, 24 );
 m = padded( 0, 60 );
 s = padded( 0, 60 );
 :Original = Concat( h, "h", m, "m", s, "s" );
);

// now convert it to JMP time number
For Each Row(
 :Converted = Eval(
  Parse(
   Regex( :Original,
    "(\d\d)h(\d\d)m(\d\d)s",
    "\3 + 60*(\2) + 3600*(\1)"
   )
  )
 )
);