429037_ja-JP

liliconcom

名前ではなく頻度に基づいて列を並べ替える...

SASでそれを行う方法を知っていますが、JMPではこれを理解できません!!! 添付のダミーデータとして、各行に一意のIDがあり、1または0のさまざまな変数があります。 IDごとに、どの変数に1のフラグが付けられているかを要約し、各変数の頻度の順序に基づいてリストを作成する必要があります（1が最も多いものから1が最も少ないものまで）。 列を手動で並べ替えてから、すべてを結果列に連結するのは簡単ですが、並べ替える行と列は数千行あります。 私は手動ではなく方法を見つけなければなりません...ここで死にます。助けてください！  

Re：名前ではなく頻度に基づいて列を並べ替えます。

この投稿は、コミュニティディスカッション領域ではなくディスカッションにある可能性があります。

 

これを行うためのより良い方法がある可能性が高いですが、サンプルデータで機能するように見える重いソリューションのスクリプトを次に示します。

Names Default To Here(1);

//Example datatable

dt = New Table("Q OF THE DAY",
 Add Rows(5),
 New Column("ID", Character(1), "Nominal", Set Values({"A", "B", "C", "D", "E"}), Set Display Width(38)),
 New Column("V1", Numeric, "Continuous", Format("Best", 12), Set Values([1, 0, 1, 0, 0]), Set Display Width(38)),
 New Column("V2", Numeric, "Continuous", Format("Best", 12), Set Values([1, 1, 1, 0, 0]), Set Display Width(38)),
 New Column("V3", Numeric, "Continuous", Format("Best", 12), Set Values([0, 0, 1, 0, 0]), Set Display Width(38)),
 New Column("V4", Numeric, "Continuous", Format("Best", 12), Set Values([1, 1, 1, 0, 1]), Set Display Width(42)),
 New Column("V6", Numeric, "Continuous", Format("Best", 12), Set Values([0, 0, 1, 0, 1]))
);

/*
colCount = 10;
dt = new table("example", 
 add rows(1000),
 New Column("ID", Numeric, Ordinal, << Set Each Value(Row()));
);

For(i = 1, i <= colCount, i++,
 dt << New Column("V" || char(i), Numeric, Ordinal,
  << Set Each Value(Random Binomial(1, 0.9))
 );
);
*/

colNames = dt << Get Column Names("String");

//Drop ID column 
colNames = Substr(colNames, 2);

//sorting list https://community.jmp.com/t5/JSL-Cookbook/Sorting-Lists/ta-p/240795
//create ranking based on sums and column idx
sumsOfCols = V Sum(dt[0, colNames]); //order is same as in coLNames
orderCols = Reverse(Rank(sumsOfCols));

newCol = dt << New Column("ORDERED", Character, Nominal);
For Each Row(dt,
 //Indices of columns which have 1
 idxWithOne = Loc(dt[Row(), colNames]);
 //if all values are missing continue to next row
 If(N Items(idxWithOne) == 0,
  continue();
 );
 //fill list with empty values
 tempList = Repeat({""}, N Items(colNames));
 //replace empty with colnames which had 1
 tempList[idxWithOne] = colNames[idxWithOne];
 //reorder list based on sum ranking
 reOrderedList = tempList[orderCols];
 //create string of list and remove whitespaces
 orderedString = Trim Whitespace(Collapse Whitespace(Concat Items(tempList[orderCols], " ")));
 //add value to column
 newCol[Row()] = orderedString;
);

また、ネクタイの特別な取り扱いはありません。

 

これをインタラクティブに行うこともできます。

スタックデータ：

数式を追加します。

 New Column("Orders",
  Numeric,
  "Continuous",
  Format("Best", 12),
  Formula(Col Sum(:Data, :Label))
 ),
 New Column("RankForId",
  Numeric,
  "Continuous",
  Format("Best", 12),
  Formula(Col Rank(Col Max(:Orders) - :Orders, :ID)),
  Set Display Width(70)
 ),
 New Column("ColumnName",
  Character,
  "Nominal",
  Formula(If(:Data == 1, :Label))
 )

IDとRankForIdでデータを並べ替えます（両方を選択して昇順で並べ替えます）。

データの転置：

 

[列]メニューから[ラベル]列と[行の結合]列を削除します。

不要な列を削除し、必要に応じて元のデータテーブルに結合し直します。

 

インタラクティブソリューションでは、スクリプトバージョンとは関係の順序が異なる場合があります