427205_zh-TW

liliconcom

5-4-4 會計日曆、col 公式或 jsl 腳本

有沒有人寫過一個列公式或腳本，允許我將日期：時間轉換為我公司的 OBSCURE 財政日曆中的特定週或季度，稱為“5-4-4”財政日曆？ 我看到谷歌對其他財政日曆的引用，但顯然 5-4-4 並不常見。

其他腳本編寫回复：5-4-4 會計日曆、col 公式或 jsl 腳本

根據我對該系統的理解，您可以找到從給定年份開始的天數，然後根據每個季度的天數和長度計算周和季度。您可能需要考慮 53 週年，但這應該會讓您開始：

 

New Table( "Fiscal Week",
 Add Rows( 1000 ),
 New Column( "Date", Numeric, "Continuous", Format( "yyyy-mm-ddThh:mm:ss", 19, 0 ),
  Input Format( "yyyy-mm-ddThh:mm:ss", 0 ),
  Formula( Date DMY( 4, 1, 2021 ) + Row() * In Hours( 12 ) )
 ),
 New Column( "Fiscal Year", Numeric, "Continuous", Format( "Best", 12 ),
  Formula(
   Floor( (:Date - Date DMY( 4, 1, 2021 )) / In Days( 52 * 7 ) ) + 2021
  )
 ),
 New Column( "Fiscal Day of Year", Numeric, "Continuous", Format( "Best", 12 ),
  Formula(
   Floor( Mod( (:Date - Date DMY( 4, 1, 2021 )) / In Days( 1 ), 52 * 7 ) )
    + 1
  ),
  Set Display Width( 67 )
 ),
 New Column( "Fiscal Week of Year", Numeric, "Continuous", Format( "Best", 12 ),
  Formula( Floor( (:Fiscal Day of Year - 1) / 7 ) + 1 ),
  Set Display Width( 85 )
 ),
 New Column( "Fiscal Quarter", Numeric, "Continuous", Format( "Best", 12 ),
  Formula( Floor( (:Fiscal Week of Year - 1) / 13 ) + 1 ),
  Set Display Width( 65 )
 )
);

回复：5-4-4 會計日曆、col 公式或 jsl 腳本

那應該讓我直到 53 週的一年，然後就無所謂了，因為世界末日將開始。 :>謝謝