427090_ja-JP

liliconcom

別のjslスクリプトの別の式内のコンボボックスから選択した値を取得するにはどうすればよいですか？

皆さんこんにちは、

 

2つのスクリプトがあります。 ScriptAには、動的制限のある2変量チャートを作成するための式があります。 ScriptBは基本的に、ユーザーにx軸とy軸の列名を選択するように求めるフロントエンドアプリケーションコードです。 ScriptBからのユーザーからの選択された入力（つまり、コンボボックスから選択されたもの）をScriptA式コードに使用して、選択された列の出力として2変量グラフを取得したいと思います。

 

 

私の目的は、スクリプトBを実行するときに、選択したパラメーターのスライダーを使用してグラフを取得することです。

/////////////////////////////////SCRIPT B///////////////////////////////////////////////////
include("ScriptA");

myStaticLibContainer = vListBox();          //Making a static container



//////Calling the expression "myFinalDisplay" from ScriptA and adding it to the static container//////

sliderGraph = buttonBox("Get Slider Graph", myStaticLibContainer << append(vListBox(myFinalDisplay)));



///Creating user input boxes///

inputParameter = comboBox("Parameter");
response = comboBox("Response");
blocking = comboBox("FAB");

myMainToolPanelBox = panelBox("myMainToolPanelBox",
 vListBox(
  spacerBox(size(1000,0)),
  V List Box(Text Box("Predictor"), inputParameter),
  V List Box(Text Box("Response"), response),
  V List Box(Text Box("Block By"), blocking)),
  H List Box(sliderGraph), 
  scrollBox(size(1000,550), myStaticLibContainer),
 );


myPlatform = newWindow("Loss Curves", myMainToolPanelBox);   

/////////////////////////////////SCRIPT B  ENDS///////////////////////////////////////////////////

////////////////////////////////////SCRIPT A//////////////////////////////////////

DT = open("data.jmp", invisible);


//Getting the inputs
x = inputParameter  << get Selected;
y = response << get Selected;
z = blocking << get Selected;

//Making graphs  

myFinalDisplay = expr(
 myGbDispObj = dt << Bivariate(
 Size( 550, 400 ),
 Y( Eval(y) ),
 X( Eval(x) ),
 Automatic Recalc( 1 ),
 Histogram Borders( 1 ),
 Summary Statistics( 1 ),
 Fit Spline( 2, {Line Color( {212, 73, 88} )} ),
 SendToReport( 
  Dispatch(
   {},
   "Bivar Plot",
   FrameBox,
   {Row Legend(
    Eval(z),
    Color( 1 ),
    Color Theme( "JMP Default" ),
    Marker( 1 ),
    Marker Theme( "Solid" ),
    Continuous Scale( 1 ),
    Reverse Scale( 0 ),
    Excluded Rows( 0 )
   )}
  ),
  Dispatch( {}, "Summary Statistics", OutlineBox, {Close( 1 )} )
 )
);

 myLimitCol = column(DT, Eval(x));
 
 myLimitMin = colMinimum(myLimitCol); show(myLimitMin);
 myLimitMax = colMaximum(myLimitCol); show(myLimitMax);
 myTbLo = textBox(Char(round(myLimitMin, 2)) || " (OOC = " || char(0.00, 10, 2) || "%)");
 myTbHi = textBox(Char(round(myLimitMax, 2)) || " (OOC = " || char(0.00, 10, 2) || "%)");

 mySbDispObj = rangeSliderBox(
  myLimitMin,
  myLimitMax,
  32,
  36,
     
  //script
  mySelectedLower = mySbDispObj << getLower;
  mySelectedUpper = mySbDispObj << getUpper;
  myGbDispObj << Dispatch( {}, "1", ScaleBox, {Add Ref Line( mySelectedLower, "Dashed", "blue", "LCL", 4 )} );
  myGbDispObj << Dispatch( {}, "1", ScaleBox, {Add Ref Line( mySelectedUpper, "Dashed", "blue", "UCL", 4 )} );
  
  rUpper = dt << Get Rows Where( myLimitCol[] > mySelectedUpper );
  OOC_valUpper = (N Items(rUpper) / N rows(dt))*100;
  myTbHi << setText(Char(round(mySelectedUpper, 1)) || " (OOC = " || char(OOC_valUpper, 10, 2) || "%)");

  rLower = dt << Get Rows Where( myLimitCol[] < mySelectedLower );
  OOC_valLower = (N Items(rLower) / N rows(dt))*100;
  myTbLo << setText(Char(round(mySelectedLower, 1)) || " (OOC = " || char(OOC_valLower, 10, 2) || "%)");
 );
 mySbDispObj << Set Width( 275 );
  
 myLayout = vListBox(
  myGbDispObj,
  hListBox(myTbLo, spacerBox(size(50,0)), myTbHi),
  mySbDispObj
 );
);



//PLATFORM = newWindow("TEST", vListBox(myFinalDisplay));



////////////////////////////////////SCRIPT A    ENDS//////////////////////////////////////

 

///////////////////////////////////////// SCRIPT A ENDS ////// /////////////////////////////////

データテーブルとスクリプトも添付しました!!

前もって感謝します。

@txnelson

 

 

pmroz

データ表グラフィックスRe：別のjslスクリプトの別の式内のコンボボックスから選択した値を取得する方法を教えてください。

スクリプトAにいくつかの変更を加えました。基本的に、変更は、呼び出される変数が呼び出される前に定義されていることを確認することでした。Clear Symbols（）;を追加しました。これは、変数がぶらぶらしていないことを確認するのに役立ちます。

Clear Symbols();
DT = open("data.jmp", invisible);

//Making graphs  

myFinalDisplay = Expr(
//Getting the inputs
 x = inputParameter << get Selected;
 y = response << get Selected;
 z = blocking << get Selected;
 myGbDispObj = dt << Bivariate(
  Size( 550, 400 ),
  Y( Eval( y ) ),
  X( Eval( x ) ),
  Automatic Recalc( 1 ),
  Histogram Borders( 1 ),
  Summary Statistics( 1 ),
  Fit Spline( 2, {Line Color( {212, 73, 88} )} ),
  SendToReport(
   Dispatch(
    {},
    "Bivar Plot",
    FrameBox,
    {Row Legend(
     Eval( z ),
     Color( 1 ),
     Color Theme( "JMP Default" ),
     Marker( 1 ),
     Marker Theme( "Solid" ),
     Continuous Scale( 1 ),
     Reverse Scale( 0 ),
     Excluded Rows( 0 )
    )}
   ),
   Dispatch( {}, "Summary Statistics", OutlineBox, {Close( 1 )} )
  )
 );

 myLimitCol = Column( DT, Eval( x ) );
 
 myLimitMin = Col Minimum( myLimitCol );
 Show( myLimitMin );
 myLimitMax = Col Maximum( myLimitCol );
 Show( myLimitMax );
 myTbLo = Text Box( Char( Round( myLimitMin, 2 ) ) || " (OOC = " || Char( 0.00, 10, 2 ) || "%)" );
 myTbHi = Text Box( Char( Round( myLimitMax, 2 ) ) || " (OOC = " || Char( 0.00, 10, 2 ) || "%)" );

 mySbDispObj = Range Slider Box(
  myLimitMin,
  myLimitMax,
  mySelectedLower,
  mySelectedUpper, 
     
  //script
  //mySelectedLower = mySbDispObj << getLower;
  //mySelectedUpper = mySbDispObj << getUpper;
  myGbDispObj << Dispatch( {}, "1", ScaleBox, {Add Ref Line( mySelectedLower, "Dashed", "blue", "LCL", 4 )} );
  myGbDispObj << Dispatch( {}, "1", ScaleBox, {Add Ref Line( mySelectedUpper, "Dashed", "blue", "UCL", 4 )} );
  
  rUpper = dt << Get Rows Where( myLimitCol[] > mySelectedUpper );
  OOC_valUpper = (N Items( rUpper ) / N Rows( dt )) * 100;
  myTbHi << setText( Char( Round( mySelectedUpper, 1 ) ) || " (OOC = " || Char( OOC_valUpper, 10, 2 ) || "%)" );

  rLower = dt << Get Rows Where( myLimitCol[] < mySelectedLower );
  OOC_valLower = (N Items( rLower ) / N Rows( dt )) * 100;
  myTbLo << setText( Char( Round( mySelectedLower, 1 ) ) || " (OOC = " || Char( OOC_valLower, 10, 2 ) || "%)" );
 );
 mySbDispObj << Set Width( 275 );
  
 myLayout = V List Box( myGbDispObj, H List Box( myTbLo, Spacer Box( size( 50, 0 ) ), myTbHi ), mySbDispObj );
);



//PLATFORM = newWindow("TEST", vListBox(myFinalDisplay));

スクリプトBへの唯一の変更は、「応答」変数にスコープの説明を追加することでした。スクリプトで使用しており、列名でもあります。JMPは混乱していました。そのため、その前に「::」を追加することで、JMPは、使用する列ではなく、メモリ変数を検索するように強制されました。

myStaticLibContainer = vListBox();          //Making a static container



//////Calling the expression "myFinalDisplay" from ScriptA and adding it to the static container//////

sliderGraph = buttonBox("Get Slider Graph", myStaticLibContainer << append(vListBox(myFinalDisplay)));



///Creating user input boxes///

inputParameter = comboBox("Parameter");
::response = comboBox("Response");
blocking = comboBox("FAB");

myMainToolPanelBox = panelBox("myMainToolPanelBox",
 vListBox(
  spacerBox(size(1000,0)),
  V List Box(Text Box("Predictor"), inputParameter),
  V List Box(Text Box("Response"), response),
  V List Box(Text Box("Block By"), blocking)),
  H List Box(sliderGraph), 
  scrollBox(size(1000,550), myStaticLibContainer),
 );


myPlatform = newWindow("Loss Curves", myMainToolPanelBox);   

Re：別のjslスクリプトの別の式内のコンボボックスから選択した値を取得する方法を教えてください。

ありがとうございました。 これはうまくいきました。 変数が重複していました。