423877_zh-CN

liliconcom

如何使用子集按钮功能为控制图创建数据表子组

大家好，

我正在尝试使用子集按钮功能为控制图创建数据表子组。我找到了这个链接Creating a Subset from an Interactive Graph?类似的东西，但它是针对行的。我想改用列。我有多个列，并且正在使用带有控制图的列切换器。我希望能够选择控制图上的特定数据点，并仅获取该特定列中这些点的数据。

下面是我尝试使用的 JSL，我尝试修改列但失败了。

dt5= Data Table( "SPC Columns" );
colNamesList = dt5 << get Column names (string, Continuous);

gb= dt5 << Control Chart Builder(
	Size( 534, 464 ),
	Show Control Panel( 0 ),
	Variables( Y( eval(colNamesList[1]) ) ),
	Chart(
		Position( 1 ),
		Limits( Shade Zones( 1 ) ),
		Warnings(
			Test 1( 1 ),
			Test 2( 1 ),
			Test 3( 1 ),
			Test 4( 1 ),
			Test 5( 1 ),
			Test 6( 1 ),
			Test 7( 1 ),
			Test 8( 1 )
		)),
Column Switcher(colNamesList[1], Eval( colNamesList ))
	
);

subsetButton = Button Box( "Click to Create a Subset of Selected Points",
	If( N Rows( dt5 << get selected rows ) > 0,
		dt5 << subset( selected rows( 1 ), selected columns( 0 ) )
	)
);

Report( gb )["Graph Builder"] << append( subsetButton );

这将为我提供在行中包含数据的所有列，当我选择这些特定数据点时，我只想要单列数据。

感谢您的帮助，

-瑞安

数据探索与可视化大规模定制回复：如何使用子集按钮功能为控制图创建数据表子组

你已经完成了大部分工作。 这是完成它的一种方法：

NamesDefaultToHere(1);

// Data table with some continuous columns
dt = Open("$SAMPLE_DATA/Big Class.jmp" );
colNamesList = dt << get Column names (string, Continuous);

// Control chart
gb = dt << Control Chart Builder(Show Control Panel( 0 ), Variables( Y( eval(colNamesList[1]) ) ));

// Add a column switcher
cs = gb << Column Switcher(colNamesList[1], Eval( colNamesList ));

// 'Extra' button with subset action
subsetButton = Button Box("Click to Create a Subset of Selected Points",
       If( N Rows( dt << get selected rows ) > 0,
        currentCol = cs << getCurrent;
        dt2 = dt << subset( selected rows( 1 ), Columns(Eval(Column(dt, currentCol))));
        dt2 << setName("Subset of "||(dt << getName)||" using "||currentCol);
        ,
        Beep();
        );
       );

// Add this button to the control chart report (use 'topParent' so that this is not affected by any column switcher changes)
(Report(gb)[OutlineBox("Control Chart Builder")] << topParent) << append(subsetButton);