423877_de-DE

liliconcom

So erstellen Sie eine Datentabellenuntergruppe für ein Kontrolldiagramm mithilfe einer Teilmengenschaltflächenfunktion

Hallo zusammen,

Ich versuche, mithilfe einer Teilmengen-Schaltflächenfunktion eine Datentabellenuntergruppe für ein Kontrolldiagramm zu erstellen. Ich habe diesen Link gefunden . Eine Teilmenge aus einem interaktiven Diagramm erstellen? zu etwas Ähnlichem, aber es ist für Zeilen. Ich möchte stattdessen die Spalten verwenden. Ich habe mehrere Spalten und verwende den Spaltenumschalter mit den Kontrolldiagrammen. Ich möchte in der Lage sein, bestimmte Datenpunkte im Kontrolldiagramm auszuwählen und nur die Daten für diese Punkte in dieser bestimmten Spalte zu erhalten.

Unten ist die JSL aufgeführt, die ich zu verwenden versucht habe, und ich habe versucht, sie in Spalten zu ändern, was jedoch fehlgeschlagen ist.

dt5= Data Table( "SPC Columns" );
colNamesList = dt5 << get Column names (string, Continuous);

gb= dt5 << Control Chart Builder(
	Size( 534, 464 ),
	Show Control Panel( 0 ),
	Variables( Y( eval(colNamesList[1]) ) ),
	Chart(
		Position( 1 ),
		Limits( Shade Zones( 1 ) ),
		Warnings(
			Test 1( 1 ),
			Test 2( 1 ),
			Test 3( 1 ),
			Test 4( 1 ),
			Test 5( 1 ),
			Test 6( 1 ),
			Test 7( 1 ),
			Test 8( 1 )
		)),
Column Switcher(colNamesList[1], Eval( colNamesList ))
	
);

subsetButton = Button Box( "Click to Create a Subset of Selected Points",
	If( N Rows( dt5 << get selected rows ) > 0,
		dt5 << subset( selected rows( 1 ), selected columns( 0 ) )
	)
);

Report( gb )["Graph Builder"] << append( subsetButton );

Dadurch erhalte ich alle Spalten, die Daten in den Zeilen enthalten. Ich möchte nur die einzelne Datenspalte, wenn ich diese spezifischen Datenpunkte auswähle.

Ich danke Ihnen für Ihre Hilfe,

-Ryan

Datenexploration und -visualisierungMassenanpassungBetreff: So erstellen Sie eine Datentabellen-Untergruppe für ein Regeldiagramm mit einer Subset-Schaltflächenfunktion

Sie haben die meiste Arbeit erledigt. Hier ist eine Möglichkeit, es zu beenden:

NamesDefaultToHere(1);

// Data table with some continuous columns
dt = Open("$SAMPLE_DATA/Big Class.jmp" );
colNamesList = dt << get Column names (string, Continuous);

// Control chart
gb = dt << Control Chart Builder(Show Control Panel( 0 ), Variables( Y( eval(colNamesList[1]) ) ));

// Add a column switcher
cs = gb << Column Switcher(colNamesList[1], Eval( colNamesList ));

// 'Extra' button with subset action
subsetButton = Button Box("Click to Create a Subset of Selected Points",
       If( N Rows( dt << get selected rows ) > 0,
        currentCol = cs << getCurrent;
        dt2 = dt << subset( selected rows( 1 ), Columns(Eval(Column(dt, currentCol))));
        dt2 << setName("Subset of "||(dt << getName)||" using "||currentCol);
        ,
        Beep();
        );
       );

// Add this button to the control chart report (use 'topParent' so that this is not affected by any column switcher changes)
(Report(gb)[OutlineBox("Control Chart Builder")] << topParent) << append(subsetButton);