423877_fr-FR

liliconcom

Comment créer un sous-groupe de table de données pour une carte de contrôle à l'aide d'une fonction de bouton de sous-ensemble

Bonjour à tous,

 

J'essaie de créer un sous-groupe de table de données pour une carte de contrôle à l'aide d'une fonction de bouton de sous-ensemble. j'ai trouvé ce lien Créer un sous-ensemble à partir d'un graphique interactif ?à quelque chose de similaire mais c'est pour les lignes. Je voudrais utiliser les colonnes à la place. J'ai plusieurs colonnes et j'utilise le sélecteur de colonnes avec les cartes de contrôle. J'aimerais pouvoir sélectionner des points de données spécifiques sur la carte de contrôle et obtenir uniquement les données pour ces points dans cette colonne spécifique.

 

Vous trouverez ci-dessous le JSL que j'ai essayé d'utiliser et j'ai essayé de modifier les colonnes et j'ai échoué.

dt5= Data Table( "SPC Columns" );
colNamesList = dt5 << get Column names (string, Continuous);

gb= dt5 << Control Chart Builder(
 Size( 534, 464 ),
 Show Control Panel( 0 ),
 Variables( Y( eval(colNamesList[1]) ) ),
 Chart(
  Position( 1 ),
  Limits( Shade Zones( 1 ) ),
  Warnings(
   Test 1( 1 ),
   Test 2( 1 ),
   Test 3( 1 ),
   Test 4( 1 ),
   Test 5( 1 ),
   Test 6( 1 ),
   Test 7( 1 ),
   Test 8( 1 )
  )),
Column Switcher(colNamesList[1], Eval( colNamesList ))
 
);

subsetButton = Button Box( "Click to Create a Subset of Selected Points",
 If( N Rows( dt5 << get selected rows ) > 0,
  dt5 << subset( selected rows( 1 ), selected columns( 0 ) )
 )
);

Report( gb )["Graph Builder"] << append( subsetButton );

 

Cela me donnera toutes les colonnes qui contiennent des données dans les lignes que je voudrais juste une seule colonne de données lorsque je sélectionne ces points de données spécifiques.

 

Merci de votre aide,

 

-Ryan

 

 

 

ScriptRe : Comment créer un sous-groupe de table de données pour une carte de contrôle à l'aide d'une fonction de bouton de sous-ensemble

Vous avez fait l'essentiel du travail. Voici une façon de le terminer :

NamesDefaultToHere(1);

// Data table with some continuous columns
dt = Open("$SAMPLE_DATA/Big Class.jmp" );
colNamesList = dt << get Column names (string, Continuous);

// Control chart
gb = dt << Control Chart Builder(Show Control Panel( 0 ), Variables( Y( eval(colNamesList[1]) ) ));

// Add a column switcher
cs = gb << Column Switcher(colNamesList[1], Eval( colNamesList ));

// 'Extra' button with subset action
subsetButton = Button Box("Click to Create a Subset of Selected Points",
       If( N Rows( dt << get selected rows ) > 0,
        currentCol = cs << getCurrent;
        dt2 = dt << subset( selected rows( 1 ), Columns(Eval(Column(dt, currentCol))));
        dt2 << setName("Subset of "||(dt << getName)||" using "||currentCol);
        ,
        Beep();
        );
       );

// Add this button to the control chart report (use 'topParent' so that this is not affected by any column switcher changes)
(Report(gb)[OutlineBox("Control Chart Builder")] << topParent) << append(subsetButton);