421612_de-DE

liliconcom

Dunnetts für mehrere Ys

Ich versuche, ein Skript zu erhalten, das Dunnetts auf mehreren Ys automatisch im Fit-Modell ausführt, meine Probleme:

 

Wenn ich den Mehrfachvergleichsteil ändere, bei dem der Faktor und das Niveau keine Variable sind, funktioniert es, aber nur für das erste Y, es wird den Dunnett-Teil für die verbleibenden Ys nicht wiederholen. Also meine Fragen:

 

1. Warum funktioniert dies nicht wie das Anpassungsmodell mit einer Variablen, die für den Faktor und das Kontrollniveau für Dunnett verwendet wird?

2. Können wir Dunnetts für mehrere Ys automatisch erhalten?

 

Lisa

 

Das habe ich bisher:

Names Default To Here( 1 );

Clear Log();
lbwidth = 130;
Tolerance = .01;

If( Not( Is Scriptable( dt ) ), 

// Check that there is a data set open;
 //ca=Caption("Please Open Design Data Set", Back Color(yellow));
 //Stop();

 dtsel = Pick File( "Open File", {"JMP|jmp", "All files|*"} );
 If( dtsel == "",
  Stop(),
  Try( dt = Open( dtsel ), Stop() )
 );
);

Dia_Window = Expr(

// Window to get list of factors and response;
 Factorws = New Window( "Fit Model With Dunnetts",
  show toolbars( 0 ),
  Show Menu( 0 ),
  Border Box( Left( 3 ), top( 2 ),
   V List Box(
    H List Box(
     Panel Box( "Select Column to be used as the Factor and the Response(s)",
      colListData = Col List Box(
       All,
       width( lbWidth ),
       nLines( Min( nc, 10 ) )
      )

     ), 

     Panel Box( "The Factor",
      Lineup Box( N Col( 2 ), Spacing( 3 ),
       Button Box( "Factor",
        colListW << Append( colListData << GetSelected )
       ),
       colListW = Col List Box(
        width( lbWidth ),
        nLines( 1 ),
        MinItems( 1 )
       ),

      )
     ), 

     Panel Box( "The Response(s)",
      Lineup Box( N Col( 2 ), Spacing( 3 ),
       Button Box( "Response(s)",
        colListY << Append( colListData << GetSelected )
       ),
       colListY = Col List Box(
        width( lbWidth ),
        nLines( 8 ),
        MinItems( 1 )
       ),

      )
     ), 

     Panel Box( "Action",
      Lineup Box( N Col( 1 ),
       Button Box( "OK",
        nm = colListW << GetItems;
        nY = colListY << GetItems;
        If( N Items( nm ) > 0,
         dm = dt << Get As Matrix( nm );
         Factorws << Close Window;
         Eval( next );
        );
       ),
       Button Box( "Cancel",
        Factorws << Close Window;
        Stop();
       ),
       Text Box( " " ),
       Button Box( "Remove",
        colListW << RemoveSelected;
        colListY << RemoveSelected;
       )
      )
     )
    ),
    Text Box( "Written by Lisa Winland lisawinland@icloud.com" )
   )
  )
 )
);
next = Expr(
 Show( nm );
 colvalues = Associative Array( Column( nm ) ) << Get Keys;
 Show( colvalues );
 listvalues = {};
 Show( nY );
 nw = New Window( "User Input for Dunnett's",
  Outline Box( "Level Selection for Dunnett's",
   values = {};
   i = 1;
   For( i = 1, i <= N Items( colvalues ), i += 1,
    Values[i] = Char( colvalues[i] )
   );
   Show( Values );
   H List Box(
    Text Box( "Select Value for Control" ),
    listvalues = List Box( Values )
   );,
   Button Box( "OK",
    level = (listvalues << Get selected);
    nw << Close Window;
    Eval( fiteval );
    Show( level );
   )
  )
 );
);
Fiteval = Expr(
 Show( nm );
 Show( nY );
 Show( level );
 controllevel = (Char( nm ) || ":" || Char( level ));
 Show( controllevel );
 Fit Model(
  Y( Eval( nY ) ),
  Effects( Eval( nm ) ),
  Personality( "Standard Least Squares" ),
  Emphasis( "Minimal Report" ),
  Run(
   :Y << {Summary of Fit( 1 ), Analysis of Variance( 1 ), Parameter Estimates( 1 ),
   Lack of Fit( 0 ), Expanded  Estimates( 1 ), Show Prediction Expression( 1 ),
   Sorted Estimates( 1 ), Scaled Estimates( 0 ), Plot Actual by Predicted( 0 ),
   Plot Regression( 0 ), Plot Residual by Predicted( 0 ),
   Plot Studentized Residuals( 0 ), Plot Effect Leverage( 0 ),
   Plot Residual by Normal Quantiles( 0 ), Box Cox Y Transformation( 0 ), Show VIF( 1 ),
   Multiple Comparisons(
    Effect( Eval( nm ) ),
    Comparisons with Control(
     1,
     Control Level( Eval( Parse( controllevel ) ) ),
     Comparisons with Control Decision Chart(
      Control Differences Chart( 1, Point Options( "Show Needles" ) )
     )
    )
   )},
  )
 );
);

dt = Current Data Table();
nc = N Col( dt );
nr = N Row( dt );
Eval( Dia_Window );

SkriptingRe: Dunnetts für mehrere Ys

Ich habe versucht, Ihr Ziel zuerst interaktiv zu erreichen und dann habe ich das Skript gespeichert. Es scheint, dass Sie dies tun können, aber Sie müssen die Liste der Optionen an jede Antwort senden. Sie können Ausdrücke einfügen, um mehrere Antworten zu berücksichtigen.

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

fit = dt << Fit Model(
 Y( :height, :weight ),
 Effects( :age ),
 Personality( "Standard Least Squares" ),
 Emphasis( "Effect Leverage" ),
 Run(
  :height << {Summary of Fit( 1 ), Analysis of Variance( 1 ),
  Parameter Estimates( 1 ), Lack of Fit( 0 ), Scaled Estimates( 0 ),
  Plot Actual by Predicted( 1 ), Plot Regression( 0 ),
  Plot Residual by Predicted( 1 ), Plot Studentized Residuals( 0 ),
  Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ),
  Box Cox Y Transformation( 0 ),
  Multiple Comparisons( Effect( :age ), Tukey HSD( 1 ) )},
  :weight << {Summary of Fit( 1 ), Analysis of Variance( 1 ),
  Parameter Estimates( 1 ), Lack of Fit( 0 ), Scaled Estimates( 0 ),
  Plot Actual by Predicted( 1 ), Plot Regression( 0 ),
  Plot Residual by Predicted( 1 ), Plot Studentized Residuals( 0 ),
  Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ),
  Box Cox Y Transformation( 0 ),
  Multiple Comparisons(
   Effect( :age ),
   Comparisons with Control(
    1,
    Control Level( "age:12" ),
    Comparisons with Control Decision Chart(
     Control Differences Chart( 1, Point Options( "Show Needles" ) )
    )
   )
  )}
 )
);

Re: Dunnetts für mehrere Ys

Ich konnte die Dunnetts nicht dazu bringen, eine Variable für den Effekt oder die Kontrollstufe zu akzeptieren. Wie bekommen Sie es, eine Variable zu akzeptieren?

 

Ich brauche etwas, wo sie die Variable und das Niveau auswählen, dann wird es für jede Antwort wiederholt. Wie Sie es in Ihrer Antwort haben, ist der tatsächliche Spaltenname und die tatsächliche Ebene.

 

 

Re: Dunnetts für mehrere Ys

Ich habe mein Beispiel weiter modifiziert, um Ihnen zu zeigen, wie Sie Ausdrücke verwenden, um das adaptive Skript für eine beliebige Anzahl von Antworten zu erstellen.

 

For( c = 1, c <= N Items( y ), c++,
 Insert Into( run expr,
  Substitute(
   Expr(
    yyy << {Summary of Fit( 1 ), Analysis of Variance( 1 ),
    Parameter Estimates( 1 ), Lack of Fit( 0 ), Scaled Estimates( 0 ),
    Plot Actual by Predicted( 1 ), Plot Regression( 0 ),
    Plot Residual by Predicted( 1 ), Plot Studentized Residuals( 0 ),
    Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ),
    Box Cox Y Transformation( 0 ),
    Multiple Comparisons(
     Effect( :age ),
     Comparisons with Control(
      1,
      Control Level( "age:12" ),
      Comparisons with Control Decision Chart(
       Control Differences Chart( 1, Point Options( "Show Needles" ) )
      )
     )
    )}
   ),
   Expr( yyy ),
   y[c];
  )
 )
);

Eval(
 Substitute(
  Expr(
   fit = dt << Fit Model(
    Y( Eval( y ) ),
    Effects( Eval( x ) ),
    Personality( "Standard Least Squares" ),
    Emphasis( "Effect Leverage" ),
    rrr
   )
  ),
  Expr( rrr ),
  Name Expr( run expr )
 )
);

Betreff: Dunnett's für mehrere Ys

Ich habe versucht, es folgendermaßen in einen String umzuwandeln:

controllevel = (Char( nm ) || ":" || Char( level ));

Aber wenn ich es in JMP zeige, wird \!" '\!: \!" '\! mit den Werten von nm und level zwischen den " " angezeigt.

Was mache ich falsch?