419202_it-IT

liliconcom

Aggiungi limiti SPEC univoci al generatore di grafici per ogni selezione di parametri da parte dell'utente

Ciao

Ho scritto uno script per visualizzare un grafico interattivo con il costruttore di grafici, con la scelta dell'utente di selezione di due parametri (MODULE_MONITOR e CHART_TYPE).

ogni parametro ha due opzioni di selezione.

 

Ognuno di quattro l'opzione di visualizzazione del grafico ha un set unico di limiti SPEC (in colonna): CENTERLINE, UCL, LCL.

Vorrei che ogni grafico tracciasse i relativi limiti SPEC.

Grazie!

 

Script JSL:

 

Graph Builder(
 Size( 866, 897 ),
 Show Control Panel( 0 ),
 Variables( X( :PROCESS_DATE ), Y( :VALUE ), Overlay( :group ) ),
 Elements( Points( X, Y, Legend( 7 ) ), Smoother( X, Y, Legend( 9 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :MODULE_MONITOR, :CHART_TYPE ),
   Where( :MODULE_MONITOR == "PLPN" ),
   Where( :CHART_TYPE == "SIGMA" )
  )
 ),
 SendToReport(
  Dispatch(
   {},
   "VALUE",
   ScaleBox,
   {Add Ref Line( :UCL, "Solid", "Red", "UCL", 1 ),
   Add Ref Line( :LCL, "Solid", "Red", "LCL", 1 ),
   Add Ref Line( :CENTERLINE, "Solid", "Black", "CENTERLINE", 1 )
   }
  )
 )
)

 

 

AnalisiTabella datiScriptingRe: Aggiungere limiti SPEC univoci al generatore di grafici per ogni selezione di parametri da parte dell'utente

Ecco un esempio di un modo per gestire il tuo problema

Names Default To Here( 1 );
// Open Data Table: big class.jmp
// → Data Table( "big class" )
dt = Open( "$SAMPLE_DATA/big class.jmp" );

gb = dt << Graph Builder(
 Size( 866, 897 ),
 Show Control Panel( 0 ),
 Variables( X( :age ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 7 ) ), Smoother( X, Y, Legend( 9 ) ) )
);
ldf = gb << Local Data Filter( Add Filter( columns( :sex ), Where( :sex == "F" ) ) );
Report( gb )[FrameBox( 1 )] << add graphics script(
 wc = ldf << get where clause;
 Eval( Parse( "dt << " || wc ) );
 Try( Report( gb )[AxisBox( 2 )] << add Ref Line( UC, "Solid", "Blue", "", 0 ) );
 Try( Report( gb )[AxisBox( 2 )] << remove Ref Line( LC, "Solid", "Blue", "", 0 ) );
 Try( Report( gb )[AxisBox( 2 )] << remove Ref Line( cLINE, "Solid", "Blue", "", 0 ) );
 cline = Try( dt:centerline[(dt << get selected rows)[1]], . );
 uc = Try( dt:ucl[(dt << get selected rows)[1]], . );
 lc = Try( dt:lcl[(dt << get selected rows)[1]], . );
 Report( gb )[AxisBox( 2 )] << Add Ref Line( UC, "Solid", "Red", "UCL", 1 );
 Report( gb )[AxisBox( 2 )] << Add Ref Line( LC, "Solid", "Red", "LCL", 1 );
 Report( gb )[AxisBox( 2 )] << Add Ref Line( cLINE, "Solid", "Black", "CENTERLINE", 1 );
);

La tabella dati allegata contiene una tabella dati di esempio che penso sia simile a quella che è la tua tabella

Re: Aggiungere limiti SPEC univoci al generatore di grafici per ogni selezione di parametri da parte dell'utente

Ciao

Grazie per la risposta

Ho provato ad abbinare il mio script al tuo aiuto, ma non funziona.

Script e tabella allegati qui

 

Spero che tu possa aiutare

Tomer

Names default to here (1);

dt = Current Data Table(); // Assuming the data table is open

gb = Graph Builder(
 Size( 866, 897 ),
 Show Control Panel( 0 ),
 Variables( X( :PROCESS_DATE ), Y( :VALUE ), Overlay( :group ) ),
 Elements( Points( X, Y, Legend( 7 ) ), Smoother( X, Y, Legend( 9 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :MODULE_MONITOR, :CHART_TYPE ),
   Where( :MODULE_MONITOR == "PLPN" ),
   Where( :CHART_TYPE == "SIGMA" )
  )
 ),

);

ldf = gb << Local Data Filter( Add Filter( columns( :MODULE_MONITOR, :CHART_TYPE ), Where( :MODULE_MONITOR == "PLPN" ),Where( :CHART_TYPE == "SIGMA" ) ) );

Report( gb )[FrameBox( 1 )] << add graphics script(
 wc = ldf << get where clause;
 Eval( Parse( "dt << " || wc ) );
 Try( Report( gb )[AxisBox( 2 )] << add Ref Line( UCl, "Solid", "Blue", "", 0 ) );
 Try( Report( gb )[AxisBox( 2 )] << remove Ref Line( LCl, "Solid", "Blue", "", 0 ) );
 Try( Report( gb )[AxisBox( 2 )] << remove Ref Line( CENTERLINE, "Solid", "Blue", "", 0 ) );
 cline = Try( dt:CENTERLINE[(dt << get selected rows)[1]], . );
 uc = Try( dt:UCL[(dt << get selected rows)[1]], . );
 lc = Try( dt:LCL[(dt << get selected rows)[1]], . );
 Report( gb )[AxisBox( 2 )] << Add Ref Line( UC, "Solid", "Red", "UCL", 1 );
 Report( gb )[AxisBox( 2 )] << Add Ref Line( LC, "Solid", "Red", "LCL", 1 );
 Report( gb )[AxisBox( 2 )] << Add Ref Line( cLINE, "Solid", "Black", "CENTERLINE", 1 );
);

 

Re: Aggiungere limiti SPEC univoci al generatore di grafici per ogni selezione di parametri da parte dell'utente

C'erano un paio di problemi nel codice.

1. Avevi lasciato nel codice del filtro dati locale nel corpo del Graph Builder.La modifica che avevo inviato ha rimosso quel codice e lo ha sostituito usando a

   ldf = gb << Local Data Filter(..........

   L'inclusione di entrambi i riferimenti di filtro ha costretto il secondo a non funzionare correttamente.
2. Avevo lasciato due riferimenti sbagliati in

   Try( Report( gb )[AxisBox( 2 )] << remove Ref Line( LC, "Solid", "Blue", "", 0 ) );

   C'è un bug nella Rimuovi linea di riferimento.Quindi, piuttosto che rimuovere la linea, la linea deve essere impostata sulla larghezza della linea di 0, quindi la linea deve essere letta

   Try( Report( gb )[AxisBox( 2 )] << add Ref Line( LC, "Solid", "Blue", "", 0 ) );

   Dopo queste modifiche, lo script ha funzionato bene per me con i tuoi dati.

   Names default to here (1);
   
   dt = Current Data Table(); // Assuming the data table is open
   
   gb = Graph Builder(
    Size( 866, 897 ),
    Show Control Panel( 0 ),
    Variables( X( :PROCESS_DATE ), Y( :VALUE ), Overlay( :group ) ),
    Elements( Points( X, Y, Legend( 7 ) ), Smoother( X, Y, Legend( 9 ) ) )/*,
    Local Data Filter(
     Add Filter(
      columns( :MODULE_MONITOR, :CHART_TYPE ),
      Where( :MODULE_MONITOR == "PLPN" ),
      Where( :CHART_TYPE == "SIGMA" )
     )
    ),*/
   
   );
   
   ldf = gb << Local Data Filter( Add Filter( columns( :MODULE_MONITOR, :CHART_TYPE ), Where( :MODULE_MONITOR == "PLPN" ),Where( :CHART_TYPE == "SIGMA" ) ) );
   
   Report( gb )[FrameBox( 1 )] << add graphics script(
    wc = ldf << get where clause;
    Eval( Parse( "dt << " || wc ) );
    Try( Report( gb )[AxisBox( 2 )] << add Ref Line( UC, "Solid", "Blue", "", 0 ) );
    Try( Report( gb )[AxisBox( 2 )] << add Ref Line( LC, "Solid", "Blue", "", 0 ) );
    Try( Report( gb )[AxisBox( 2 )] << add Ref Line( cLine, "Solid", "Blue", "", 0 ) );
    cline = Try( dt:CENTERLINE[(dt << get selected rows)[1]], . );
    uc = Try( dt:UCL[(dt << get selected rows)[1]], . );
    lc = Try( dt:LCL[(dt << get selected rows)[1]], . );
    Report( gb )[AxisBox( 2 )] << Add Ref Line( UC, "Solid", "Red", "UCL", 1 );
    Report( gb )[AxisBox( 2 )] << Add Ref Line( LC, "Solid", "Red", "LCL", 1 );
    Report( gb )[AxisBox( 2 )] << Add Ref Line( cLINE, "Solid", "Black", "CENTERLINE", 1 );
   );

Re: Aggiungere limiti SPEC univoci al generatore di grafici per ogni selezione di parametri da parte dell'utente

Grazie. Lavorando!

Puoi per favore spiegare perché usando

Try( Report( gb )[AxisBox( 2 )] << add Ref Line

poi

 Report( gb )[AxisBox( 2 )] << Add Ref Line( UC, "Solid", "Red", "UCL", 1 );

per l'UCL, CLINE, LCL?

 

Tomer