Add unique SPEC limits to graph builder for each user selection of parameters

Question

Hi

I wrote a script to view an interactive chart with graph builder, with user choice of selection of two parameters (MODULE_MONITOR and CHART_TYPE).

each parameters has two selection options.

Each of the four option of chart display has unique set of SPEC limits (in column): CENTERLINE, UCL, LCL.

I would like that each graph would plot the relevant SPEC limits.

Thanks!

JSL script:

Graph Builder(
	Size( 866, 897 ),
	Show Control Panel( 0 ),
	Variables( X( :PROCESS_DATE ), Y( :VALUE ), Overlay( :group ) ),
	Elements( Points( X, Y, Legend( 7 ) ), Smoother( X, Y, Legend( 9 ) ) ),
	Local Data Filter(
		Add Filter(
			columns( :MODULE_MONITOR, :CHART_TYPE ),
			Where( :MODULE_MONITOR == "PLPN" ),
			Where( :CHART_TYPE == "SIGMA" )
		)
	),
	SendToReport(
		Dispatch(
			{},
			"VALUE",
			ScaleBox,
			{Add Ref Line( :UCL, "Solid", "Red", "UCL", 1 ),
			Add Ref Line( :LCL, "Solid", "Red", "LCL", 1 ),
			Add Ref Line( :CENTERLINE, "Solid", "Black", "CENTERLINE", 1 )
			}
		)
	)
)

txnelson · Answer

The issue lies it the JMP behavior, where once a ref line is added, it remains for the duration of the display, unless the reference line is removed.  Therefore, what is being run, is the statement to "Remove Ref Line" and then to add the new ref line.  The problem is, that the "Remove Ref Line" command has a bug, and does not work.  Below is the Remove Ref Line example from the Scripting Index, and if you run it, you will see that the line is not removed.

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
biv = Bivariate( Y( :weight ), X( :height ), FitLine );
rbiv = biv << report;
axisbox = rbiv[axis box( 1 )];
axisbox << Add Ref Line( 90, "Dashed", blue );
axisbox << Remove Ref Line( 90 );

A workaround for the bug, is to instead of Removing the ref line, but to rather add a new ref line on top of the old one, but make it of zero line width, which effectively make it invisible.

The key to the removal is to tell JMP which line to remove/add zero width line to.  That is determined by the value of the reference line.  And since it is the previous reference line you want to remove, that is why the UC, LC, and Cline variables are specified, since they contain the previous values of the LCL, UCL and CENTERLINE variables,

Tomer9w · Answer

Thanks. working!

Can you please explain why using

Try( Report( gb )[AxisBox( 2 )] << add Ref Line

and then

Report( gb )[AxisBox( 2 )] << Add Ref Line( UC, "Solid", "Red", "UCL", 1 );

for the UCL,CLINE, LCL?

Tomer

txnelson · Answer

There were a couple of issues in the code.

* You had left in the Local Data Filter code in the body of the Graph Builder.  The modification I had sent removed that code and replace it using aldf = gb << Local Data Filter(..........

The inclusion of both filter references forced the second one to not work properly.
* I had left two wrong references in Try( Report( gb )[AxisBox( 2 )] << remove Ref Line( LC, "Solid", "Blue", "", 0 ) );

There is a bug in the Remove Ref Line.  So rather than removing the line, the line needs to be set to line width of 0, so the line needs to read

Try( Report( gb )[AxisBox( 2 )] << add Ref Line( LC, "Solid", "Blue", "", 0 ) );

After those changes the script worked fine for me with your data.

Names default to here (1);

dt = Current Data Table(); // Assuming the data table is open

gb = Graph Builder(
	Size( 866, 897 ),
	Show Control Panel( 0 ),
	Variables( X( :PROCESS_DATE ), Y( :VALUE ), Overlay( :group ) ),
	Elements( Points( X, Y, Legend( 7 ) ), Smoother( X, Y, Legend( 9 ) ) )/*,
	Local Data Filter(
		Add Filter(
			columns( :MODULE_MONITOR, :CHART_TYPE ),
			Where( :MODULE_MONITOR == "PLPN" ),
			Where( :CHART_TYPE == "SIGMA" )
		)
	),*/

);

ldf = gb << Local Data Filter( Add Filter( columns( :MODULE_MONITOR, :CHART_TYPE ), Where( :MODULE_MONITOR == "PLPN" ),Where( :CHART_TYPE == "SIGMA" ) ) );

Report( gb )[FrameBox( 1 )] << add graphics script(
	wc = ldf << get where clause;
	Eval( Parse( "dt << " || wc ) );
	Try( Report( gb )[AxisBox( 2 )] << add Ref Line( UC, "Solid", "Blue", "", 0 ) );
	Try( Report( gb )[AxisBox( 2 )] << add Ref Line( LC, "Solid", "Blue", "", 0 ) );
	Try( Report( gb )[AxisBox( 2 )] << add Ref Line( cLine, "Solid", "Blue", "", 0 ) );
	cline = Try( dt:CENTERLINE[(dt << get selected rows)[1]], . );
	uc = Try( dt:UCL[(dt << get selected rows)[1]], . );
	lc = Try( dt:LCL[(dt << get selected rows)[1]], . );
	Report( gb )[AxisBox( 2 )] << Add Ref Line( UC, "Solid", "Red", "UCL", 1 );
	Report( gb )[AxisBox( 2 )] << Add Ref Line( LC, "Solid", "Red", "LCL", 1 );
	Report( gb )[AxisBox( 2 )] << Add Ref Line( cLINE, "Solid", "Black", "CENTERLINE", 1 );
);