418865_it-IT

liliconcom

Perché il valore lambda dell'adattamento Spline utilizzato nell'analisi "Adatta Y per X" è diverso dal "Generatore grafico"?

Salve, sviluppatori JMP,

 

Sto usando la versione JMP15.2.1.

 

Come sotto i risultati di adattamento uniforme (stessi set di dati) in JMP quando si utilizza la piattaforma One Way Analysis (fit Y by X) rispetto a Graph Builder, impostando lo stesso lambda=100, l'uniformità della curva è completamente diversa. ( Le misure sono le stesse anche se il lambda i valori differiscono di circa 20x )

 

C'è un motivo per tale differenza?

 

 

GraficaRi: Perché il valore lambda dell'adattamento Spline utilizzato nell'analisi "Adatta Y per X" è diverso dal "Graph Builder"?

Ciao @Jing ,

 

Il generatore di grafici utilizza variabili X standardizzate.Per ottenere la stessa linea in Bivariate, scegli 'Altro...' sotto il triangolo rosso > Flessibile > Adatta spline, usa un lamda di 0,05 (predefinito nel generatore di grafici) e seleziona 'Standardizza X'.

 

 

Visualizza di più...

Names default to here(1);

dt = Open("$Sample_data/Car Physical Data.jmp");

New Window("Compare",
 H List Box(
  Bivariate(
   Y( :Weight ),
   X( :Displacement ),
   Fit Spline( 0.05, Standardized, {Line Color( {61, 174, 70} )} ),
   Where( :Country == "Japan" )
  ),
  Graph Builder(
   Size( 400, 320 ),
   Show Control Panel( 0 ),
   Variables( X( :Displacement ), Y( :Weight ), Overlay( :Country ) ),
   Elements(
    Points( X, Y, Legend( 14 ) ),
    Smoother( X, Y, Legend( 15 ), Lambda( 0.05 ) )
   ),
   Local Data Filter(
    Close Outline( 1 ),
    Add Filter( columns( :Country ), Where( :Country == "Japan" ) )
   )
  )
 )
);