415838_zh-TW

liliconcom

檢查數據表中是否未創建行的代碼，關閉數據表

我正在從主數據表創建列表數據表子集。 然後，我通過 Tabulate() 操作數據並將其放入表格中進行處理。 然後，檢查每個數據表N Rows，如果N Rows = 0，則關閉數據表。 最後，將數據表附加到報告中。 下面是我的腳本。

 

問題是在我添加以下代碼後，要檢查 N 行，它不再起作用。 沒有錯誤出現。

If(N Rows(mDT)==0, Close(mDT, no save));

 

我相信編寫的代碼可能存在一些錯誤。 在這裡需要指導和幫助。

 

saveFolder = "$TEMP/";

listDT = {};
listtab = {};
mDT = {};

col = Column(dt1Sub, ":PART");

colLevs = Associative Array(col) << Get Keys;

hb = V List Box( );

For (i=1, i<=NItems(colLevs), i++,

     r2get = dt1 << Get Rows Where(:PART == colLevs[i]);

     listDT[i] = dt1 << Subset(Rows(r2get));

     listDT[i] << Set Name(Char(colLevs[i]));
 
     listDT[i] << Save( saveFolder || Word( 1, listDT[i] << get name, "-" )||".csv");
     
     listtab = listDT[i] << Tabulate(
                Show Control Panel( 0 ),
                Add Table(
                 Column Table( Grouping Columns( :ORDER ) ),
                 Column Table( Statistics( Sum ), Analysis Columns( :Qty ) ),
                 Row Table(
                  Grouping Columns(
                  ::PART,
                  ::PART DESC,
                  :LOW PART #,
                  :LOW PART DESC,
                  :FAILURE MODE
                  )
                 )
                )
                ); 
                
     mDT= listtab << Make Into Data Table;   
     
     Close(listDT[i], no save);
    
     mDT << New Column ("Criteria", Character, "Nominal",
            Formula(
             If(As Column(6)>= 3, "Failure")
            )
     );
     mDT:Criteria << Delete Formula;
     mDT << Sort(By(Column(6)),Order(Descending), Replace Table);
     mDT << Select Where (:As Column(6) == 0);
     mDT << Delete Rows;
     
     If(N Rows(mDT)==0, Close(mDT, no save));   
          
     mDT << Set Window Size (2400, 800);
     
     mDT << Get As Report;
     
     hb << Append( ( mDT << Get As Report ) );
          
);

New Window( "Report", hb );

腳本編寫回复：檢查數據表中是否未創建行的代碼，關閉數據表

可能是您在關閉數據表後繼續循環執行。 您可以嘗試將 if 語句之後的 for 循環中的行移動到 else 語句：

If(N Rows(mDT) == 0,
 Close(mDT, no save)
,//else
 mDT << Set Window Size(2400, 800);
 mDT << Get As Report;
 hb << Append((mDT << Get As Report));
);

或在關閉 mDT 後使用Continue()：

If(N Rows(mDT) == 0,
 Close(mDT, no save)
 Continue();
);