415838_zh-CN

liliconcom

检查数据表中是否未创建行的代码，关闭数据表

我正在从主数据表创建列表数据表子集。 然后，我通过 Tabulate() 操作数据并将其放入表格中进行处理。 然后，检查每个数据表N Rows，如果N Rows = 0，则关闭数据表。 最后，将数据表附加到报告中。 下面是我的脚本。

 

问题是在我添加以下代码后，要检查 N 行，它不再起作用。 没有错误出现。

If(N Rows(mDT)==0, Close(mDT, no save));

 

我相信编写的代码可能存在一些错误。 在这里需要指导和帮助。

 

saveFolder = "$TEMP/";

listDT = {};
listtab = {};
mDT = {};

col = Column(dt1Sub, ":PART");

colLevs = Associative Array(col) << Get Keys;

hb = V List Box( );

For (i=1, i<=NItems(colLevs), i++,

     r2get = dt1 << Get Rows Where(:PART == colLevs[i]);

     listDT[i] = dt1 << Subset(Rows(r2get));

     listDT[i] << Set Name(Char(colLevs[i]));
 
     listDT[i] << Save( saveFolder || Word( 1, listDT[i] << get name, "-" )||".csv");
     
     listtab = listDT[i] << Tabulate(
                Show Control Panel( 0 ),
                Add Table(
                 Column Table( Grouping Columns( :ORDER ) ),
                 Column Table( Statistics( Sum ), Analysis Columns( :Qty ) ),
                 Row Table(
                  Grouping Columns(
                  ::PART,
                  ::PART DESC,
                  :LOW PART #,
                  :LOW PART DESC,
                  :FAILURE MODE
                  )
                 )
                )
                ); 
                
     mDT= listtab << Make Into Data Table;   
     
     Close(listDT[i], no save);
    
     mDT << New Column ("Criteria", Character, "Nominal",
            Formula(
             If(As Column(6)>= 3, "Failure")
            )
     );
     mDT:Criteria << Delete Formula;
     mDT << Sort(By(Column(6)),Order(Descending), Replace Table);
     mDT << Select Where (:As Column(6) == 0);
     mDT << Delete Rows;
     
     If(N Rows(mDT)==0, Close(mDT, no save));   
          
     mDT << Set Window Size (2400, 800);
     
     mDT << Get As Report;
     
     hb << Append( ( mDT << Get As Report ) );
          
);

New Window( "Report", hb );

脚本编写回复：检查数据表中是否未创建行的代码，关闭数据表

可能是您在关闭数据表后继续循环执行。 您可以尝试将 if 语句之后的 for 循环中的行移动到 else 语句：

If(N Rows(mDT) == 0,
 Close(mDT, no save)
,//else
 mDT << Set Window Size(2400, 800);
 mDT << Get As Report;
 hb << Append((mDT << Get As Report));
);

或在关闭 mDT 后使用Continue()：

If(N Rows(mDT) == 0,
 Close(mDT, no save)
 Continue();
);