414445_fr-FR

liliconcom

Filtrage des données tabulées avec un filtre de données local en HTML interactif

Comment ajouter un tableau Tabulate au HTML interactif qui recalcule lorsque le filtre de données local est mis à jour ?

Voici un exemple:

savePath = Pick Directory( "Where should the report be saved?" );

dt = Open( "$SAMPLE_dATA/Big Class.jmp" );

genders = {};
Insert Into( genders, "F" );
Insert Into( genders, "M" );

webreport = New Web Report();
dtTitle = dt << get window title;
webreport << Index( title( dtTitle ), style( "Smalllist" ) );
windows = {};

For( i = 1, i <= N Items( genders ), i++,
 lub1 = Lineup Box( N Col( 2 ) );
 lub1 << append(
  dt << data filter(
   local,
   add filter(
    columns( :column( dt, "age" ), :column( dt, "height" ), :column( dt, "weight" ) ),
    where( :name( "sex" ) == genders[i] )
   ),
   Mode( Include( 0 ) )
  )
 );
 lub2 = Lineup Box( N Col( 2 ) );
 lub2 << append(
  Tabulate(
   Title( "Summary" ),
   Show Control Panel( 0 ),
   Add Table(
    Column Table(
     Statistics( Min, Max, Median, Mean, Std Dev ),
     Analysis Columns( :column( dt, "height" ) )
    ),
    Row Table( Grouping Columns( :age ) )
   )
  )
 );
 lub3 = Lineup Box( N Col( 2 ) );
 lub3 << append(
  Graph Builder(
   Title( "age vs height" ),
   Size( 290, 270 ),
   Show control Panel( 0 ),
   Variables( X( :column( dt, "age" ) ), Y( :column( dt, "height" ) ) ),
   Elements( Points( X, Y ) ),
   show title( 0 ),
   show footer( 0 )
  )
 );
 lub3 << append(
  Graph Builder(
   Title( "age vs weight" ),
   Size( 290, 270 ),
   Show control Panel( 0 ),
   Variables( X( :column( dt, "age" ) ), Y( :column( dt, "weight" ) ) ),
   Elements( Points( X, Y ) ),
   show title( 0 ),
   show footer( 0 )
  )
 );
 lub3 << horizontalalignment( Left );
 lub2 << append( lub3 );
 lub2 << verticalalignment( top );
 lub1 << append( lub2 );
 lub1 << horizontalalignment( Left );
 dfcb = Data Filter Context Box( lub1 );
 win = New Window( genders[i], dfcb );
 //dfcb << report;
 webreport << add report( dfcb, Title( genders[i] ) );
 Insert Into( windows, win );
);

webreport << save( savePath || "Report for Big Class" );

For( j = 1, j <= N Items( windows ), j++,
 windows[j] << close window
);

Ce code génère du HTML interactif. Chaque page possède un filtre de données local (LDF), un tableau de tabulation (appelé « Résumé ») et deux graphiques.

Les graphiques mettent à jour leur contenu lorsque le LDF est modifié. Ce n’est pas le cas du résumé. Ceci est identique au comportement dans JMP.

Si je change le mode du LDF en

Mode( Include( 1 ) )

Ensuite, le résumé est mis à jour avec les modifications apportées au LDF dans JMP, mais le LDF est complètement désactivé dans le HTML interactif.

Tabulate a également la possibilité d'inclure son propre filtre de données local. Ce filtre est également désactivé dans le HTML interactif.

J'utilise JMP 16.0.0.

Personnalisation de masseRe : Filtrage des données tabulées avec un filtre de données local en HTML interactif

Bonjour, c'est intentionnel.

 

Le HTML interactif vous permet de sélectionner des points à l'aide d'un LDF, mais est incapable de réexécuter des analyses à l'aide d'un LDF, car aucune connexion à JMP n'est présente.

 

Pour mettre à jour de manière interactive les analyses affichées sur les pages Web, JMP en direct est nécessaire.

 

Acclamations,

Brady