nav[aria-label="Primary Navigation"] { padding: 0; & ul { list-style: none; width: 100%; display: flex; flex-direction: row; justify-content: start; align-items: start; gap: 30px; padding: 0; & li { margin: 0; } & ul li { list-style: none; } } }

Distribution analysis (e.g. summarize statistics) direct calculation after selection?

Fabian88

Dear all,
I´m sure its an easy question - so for you I think its an quick and easy answer

I would like to calculate the data in the distribution-overview based on the selection:

Here for example I would like to see the summary statistics direct after selecting this data (new table calculation). For now I just can see this specific calculation if I Hide and Exclude the unneccesary data in the raw-data-table.

Is this possible?

Im looking forward to your answer. Thanks alot!
Fabian

Accepted answers

ian_jmp

Perhaps you can use the local data filter?

NamesDefaultToHere(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
dist = dt << Distribution(
					Automatic Recalc( 1 ),
					Continuous Distribution( Column( :height ) ),
					Continuous Distribution( Column( :weight ) ),
					Local Data Filter(
						Add Filter(
							columns( :age, :sex ),
							Display( :age, Size( 160, 90 ), List Display )
						)
					)
				);

Alternatively, you could use a dashboard with a selection filter

txnelson

Or are you looking to click on the Male/Female distribution, and for it to change the values in the other graphs

Here is an example from the Scripting Index using a Data Filter Source Box

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Window( "Selection Filter",
	Data Filter Context Box(
		H List Box(
			Data Filter Source Box(
				Graph Builder(
					Size( 208, 207 ),
					Show Control Panel( 0 ),
					Show Legend( 0 ),
					Variables( X( :age ) ),
					Elements( Bar( X, Legend( 3 ) ) ),
					SendToReport(
						Dispatch(
							{},
							"Graph Builder",
							OutlineBox,
							{Set Title( "Filter" )}
						)
					)
				)
			),
			Platform(
				Current Data Table(),
				Bubble Plot(
					X( :weight ),
					Y( :height ),
					Sizes( :age ),
					Title Position( 0, 0 )
				)
			)
		)
	)
);

Here is the code adapted to the example you gave

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Window( "Selection Filter",
	Data Filter Context Box(
		H List Box(
			Data Filter Source Box( Distribution( Nominal Distribution( Column( :sex ) ) ) ),
			Platform(
				Current Data Table(),
				Distribution(
					Nominal Distribution( Column( :age ) ),
					Continuous Distribution( Column( :height ) ),
					Continuous Distribution( Column( :weight ) )
				)
			)
		)
	)
);

All comments

ron_horne

perhaps the following,

once you selected the subset go to Tables>>>subset and produce a subset with only the selected rows.

then, if you open the distribution platform and hit the recall button you should get what you are looking for.

Ron