412025_zh-TW

liliconcom

每行最後30條並刪除其他數據

大家好，

 

我有一個包含多列的數據表，每列都有不同數量的包含數據的行。 我試圖找到一種方法來獲取每列中數據的最後 30 行。 例如，第 1 列有 50 行，第 2 列有 75 行，我希望每一行都有最後 30 行信息。 有沒有可以做到這一點的腳本？

 

數據表腳本編寫回复：每行最後 30 條並刪除其他數據

刪除數據表中除最後 30 行之外的所有行很容易。

Names Default To Here( 1 );
dt = Current Data Table();
dt << select where( Row() > N Rows( dt ) - 30 );
dt << delete rows;

如果您要求找到每列的最後 30 個非缺失數據點，然後將其保存為您的 n 列乘 30 行數據，那就有點困難了，我會質疑這樣做的有效性。這樣做的結果將是消除不同列之間數據點之間的幾乎所有關係。

Names Default To Here( 1 );
dt = Current Data Table();

// Copy the data table retaining no rows;
dtCopy = dt << subset( selected rows( 0 ), selected columns( 0 ) );
dtCopy << select where( Row() >= 0 );
dtCopy << delete rows;
For( i = 1, i <= N Cols( dtCopy ), i++,
 theList = {};
 For( k = N Rows( dt ), k >= 1, k--,
  If( Is Missing( Column( dt, i )[k] ) == 0,
   Insert Into( theList, Column( dt, i )[k] );
   If( N Items( theList ) >= 30,
    Break()
   );
  )
 );
 Column( dtCopy, i ) << set values( Reverse( theList ) );
);

回复：每行最後 30 條並刪除其他數據

這是另一個版本，可實現與第二個解決方案相同的結果@txnelson

 

For( col = 1, col <= N Col( dt ), col++,
 values = Column( dt, col ) << Get Values;
 end = Contains( values, . ) - 1;
 If( end == -1, end = N Row( dt ) );
 view = end - 29 :: end;
 Column( dt, col ) << Set Values( values[view] );
);
dt << Select Where( Row() > 30 ) << Delete Rows;

回复：每行最後 30 條並刪除其他數據

@馬克貝利這很好用！ 我開始意識到我的列中有小於 30 和大於 30 的數據，有沒有一種簡單的方法可以只顯示這個？ 一個例子第 1 列有 50 行，第 2 列有 75 行，第 3 列有 28 行，我希望每一行都有最後 30 行的信息，沒有低於 30 的信息，所以如果它有 29 個或更少的數據點，我想刪除它還。 謝謝您的幫助！

回复：每行最後 30 條並刪除其他數據

試試這個版本。

 

Names Default to Here( 1 );

// create the example

dt = New Table( "Odd Lengths",
 New Column( "Column 1", Numeric, Continuous, Values( 1::50 ) ),
 New Column( "Column 2", Numeric, Continuous, Values( 1::75 ) ),
 New Column( "Column 3", Numeric, Continuous, Values( 1::28 ) )
);

Wait( 0 );

// process the data table

For( col = N Col( dt ), col > 0, col--,
 values = Column( dt, col ) << Get Values;
 not missing = Sum( Not( Is Missing( values ) ) );
 If( not missing < 30,
  dt << Delete Columns( Column( dt, col ) ),
  end = Contains( values, . ) - 1;
  If( end == -1, end = N Row( dt ) );
  view = end - 29 :: end;
  Column( dt, col ) << Set Values( values[view] );
  
 );
);

dt << Select Where( Row() > 30 ) << Delete Rows;