每行最后30条，删除其他数据大家好，
我有一个包含多列的数据表，每列都有不同数量的行，其中包含数据。 我正在尝试找到一种方法来获取每列中最后 30 行的数据。 例如，第 1 列有 50 行，第 2 列有 75 行，我希望每行都有最后 30 行信息。 有一个脚本可以做到这一点吗？
自动化和脚本编写数据混合和清理大规模定制回复：每行最后30条并删除其他数据对于本曲目的未来读者，更正@马克贝利与 @txnelson 响应中的第二段代码相比，有关他的代码的声明需要澄清。如果假设一旦找到缺失值，该列中不会出现其他非缺失值，则这两段代码将产生相同的结果。@马克贝利代码要求必须存在最小数量的非缺失值，其中 @txnelson 代码不存在
回复：每行最后30条并删除其他数据FWIW，这是使用矩阵的另一个版本：
NamesDefaultToHere(1);
// Make a data table 'dt', to play with.
nr = 100; // Number of rows
nc = 30; // Number of columns
p = 0.7; // Proportion of missing values
vals = J(nr*nc, 1, RandomInteger(0, 99));
makeMissing = RandomIndex(nr*nc, Floor(nr*nc*p));
vals[makeMissing] = .;
dt = AsTable(Shape(vals, nr, nc));
dt << setName("Random Integers with some missing");
// Start here with the current table . . .
lastN = 30; // Number of non-missing values to retain
dt = CurrentDataTable();
vals = dt << getAsMatrix;
// Loop over columns . . .
newVals = [];
for(c=1, c<=NCol(vals), c++,
NMV = vals[LocNonMissing(vals[0, c]), c]; // Non-mising values in this column
if(NRow(NMV) >= lastN, // Do we have enough non-missing values?
lastNMV = NMV[(NRow(NMV) - lastN + 1)::NRow(NMV)]; // If so, get the 'lastN' of these . . .
newVals = newVals||lastNMV; // . . . and add them into a new column
);
);
dt2 = AsTable(newVals);
dt2 << setName("Last "||Char(lastN)||" non-missing Random Integers");回复：每行最后30条并删除其他数据试试这个版本。
Names Default to Here( 1 );
// create the example
dt = New Table( "Odd Lengths",
New Column( "Column 1", Numeric, Continuous, Values( 1::50 ) ),
New Column( "Column 2", Numeric, Continuous, Values( 1::75 ) ),
New Column( "Column 3", Numeric, Continuous, Values( 1::28 ) )
);
Wait( 0 );
// process the data table
For( col = N Col( dt ), col > 0, col--,
values = Column( dt, col ) << Get Values;
not missing = Sum( Not( Is Missing( values ) ) );
If( not missing < 30,
dt << Delete Columns( Column( dt, col ) ),
end = Contains( values, . ) - 1;
If( end == -1, end = N Row( dt ) );
view = end - 29 :: end;
Column( dt, col ) << Set Values( values[view] );
);
);
dt << Select Where( Row() > 30 ) << Delete Rows;
回复：每行最后30条并删除其他数据@马克贝利这太棒了！ 我开始意识到我的列中的数据小于 30 和大于 30 有没有一种简单的方法来仅显示这一点？ 一个例子第 1 列有 50 行，第 2 列有 75 行，第 3 列有 28 行，我希望每行都有最后 30 行信息，没有低于 30 的信息，所以如果它有 29 个或更少的数据点，我想删除它还。 谢谢您的帮助！
回复：每行最后30条并删除其他数据这是另一个版本，可以实现与第二个解决方案相同的结果@tx尼尔森
For( col = 1, col <= N Col( dt ), col++,
values = Column( dt, col ) << Get Values;
end = Contains( values, . ) - 1;
If( end == -1, end = N Row( dt ) );
view = end - 29 :: end;
Column( dt, col ) << Set Values( values[view] );
);
dt << Select Where( Row() > 30 ) << Delete Rows;
回复：每行最后30条并删除其他数据删除数据表中除最后 30 行之外的所有行很容易。
Names Default To Here( 1 );
dt = Current Data Table();
dt << select where( Row() > N Rows( dt ) - 30 );
dt << delete rows;
如果您要求找到每列的最后 30 个非缺失数据点，然后将其保存为 n 列 x 30 行数据，那就有点困难了，我会质疑这样做的有效性。这样做的结果将消除不同列之间的数据点之间的几乎所有关系。
Names Default To Here( 1 );
dt = Current Data Table();
// Copy the data table retaining no rows;
dtCopy = dt << subset( selected rows( 0 ), selected columns( 0 ) );
dtCopy << select where( Row() >= 0 );
dtCopy << delete rows;
For( i = 1, i <= N Cols( dtCopy ), i++,
theList = {};
For( k = N Rows( dt ), k >= 1, k--,
If( Is Missing( Column( dt, i )[k] ) == 0,
Insert Into( theList, Column( dt, i )[k] );
If( N Items( theList ) >= 30,
Break()
);
)
);
Column( dtCopy, i ) << set values( Reverse( theList ) );
);
