409090_de-DE

liliconcom

JSL: Rufen Sie eine Liste von Spalten ab, die einen bestimmten Wert enthalten

Hallo,

Ich möchte alle Spalten auflisten, die in einer ihrer Zeilen einen bestimmten Wert enthalten, und die Auflistung dieser Spalten erhalten.

Ich beginne mit der Auflistung aller Zeichenspalten in einer Liste und führe eine Schleife durch, um zu prüfen, ob in jeder der Spalten ein bestimmter Wert enthalten ist. Hier ist der Code, den ich verwendet habe. Irgendeine Idee, wie man mir helfen kann? Vielen Dank im Voraus

 

col = dt << get column names( character );
nc = N Items( col );
colList = {};

For( i = 1, i <= nc, i++,
 If(Contains (as column(dt,col[i]) ,"null"),
 Insert Into( colList, col[i] ))
);<BR />

 

Erweiterte statistische ModellierungQualitäts- und VerfahrenstechnikBetreff: JSL: Rufen Sie eine Liste von Spalten ab, die einen bestimmten Wert enthalten

Viele Lösungen, vielen Dank für diese Einblicke!

Betreff: JSL: Rufen Sie eine Liste von Spalten ab, die einen bestimmten Wert enthalten

Vielen Dank, das funktioniert wie ein Zauber!

Betreff: JSL: Rufen Sie eine Liste von Spalten ab, die einen bestimmten Wert enthalten

Nachfolgend finden Sie einige weitere Möglichkeiten. Ich würde vorschlagen, die Lösung von txnelson zu verwenden, da sie einfacher zu verstehen ist.

Names Default To Here(1);

dt = New Table("Untitled",
 Add Rows(5),
 New Column("Column 1", Character, "Nominal", Set Values({"null", "a", "s", "d", "vb"})),
 New Column("Column 2", Character, "Nominal", Set Values({"a", "a", "a", "a", "a"})),
 New Column("Column 3", Character, "Nominal", Set Values({"a", "a", "a", "a", "a"})),
 New Column("Column 4", Character, "Nominal", Set Values({"null", "a", "a", "a", "a"})),
 New Column("Column 5", Numeric, "Continuous", Format("Best", 12), Set Values([1, 2, 3, 4, 5])),
 New Column("Column 6", Numeric, "Continuous", Format("Best", 12), Set Values([1, 2, 3, 4, 5])),
 New Column("Column 7", Character, "Nominal", Set Values({"a", "a", "a", "null", "a"}))
);

//using Loc and matrix subscripting
char_col_names = dt << Get Column Names(character);
null_cols = {};
For(i = 1, i <= N Items(char_col_names), i++,
 If(N Items(Loc(dt[0, char(char_col_names[i])], "null")) > 0,
  Insert Into(null_cols, char_col_names[i]);
 );
);
Show(null_cols);

//Using list flattening and loc with "2d" matrix

//List flattening function from here https://community.jmp.com/t5/Discussions/JSL-Question-How-to-flatten-quot-a-list-of-lists/td-p/56535
rec = Function({ll},
 {i},
 If(Is List(ll),
  For(i = 1, i <= N Items(ll), i++,
   If(!Is List(ll[i]),
    Insert Into(llnew, ll[i]), //else
    rec(ll[i])
   )
  )
 )
);
flatten = Function({ulist},
 {llnew = {}},
 rec(ulist);
 llnew;
);

col_names = dt << Get Column Names();
//https://community.jmp.com/t5/JSL-Cookbook/Using-Loc-with-a-2D-Matrix/ta-p/195207
null_loc = Loc(flatten(dt[0, col_names ]), "null") - 1;
column_loc = Mod(null_loc, N Items(col_names )) + 1;
Show(col_names[column_loc]);

Wenn Sie Probleme mit der Geschwindigkeit des Skripts haben, können Sie sehen, ob dieses Thema hilfreich sein könnte Sollten Sie eine Datentabelle durchlaufen oder Recode verwenden oder Get verwenden?

 

Betreff: JSL: Rufen Sie eine Liste von Spalten ab, die einen bestimmten Wert enthalten

Ich denke, das könnte das tun, was Sie wollen

Names Default To Here( 1 );
dt = current data table();
col = dt << get column names( character );
nc = N Items( col );
colList = {};

For( i = 1, i <= nc, i++,
 If( N Rows( dt << get rows where( As Column( dt, col[i] ) == "null" ) ) > 0,
  Insert Into( colList, col[i] )
 )
);