こんにちは皆さん！
Prediction Profiler内で、ユーザーは指定された予測式、入力、および仕様制限を使用してPPM値を生成できます。 これは、プロファイラーGUIセットアップの予測プロファイラーの横にある[シミュレーション]ボタンを押すだけで実行できます。 この時点で、平均値、PPM値、および標準偏差値を含むテーブルが生成されます。
気になります：このプロセスをスクリプト内（またはGUIの他の場所）で自動化して、任意の入力変数の値の設定範囲にわたって複数のPPM値を生成できますか？ 。 このデータを使用して、さまざまなPPM値と指定された入力パラメーターをプロットして表示します。 今のところ、私はこれを行う方法を見つけていません。 現在のところ唯一の方法は、入力値を変更してシミュレーションボタンをもう一度押してから、出力PPM値を手動で文書化することです。 これは明らかにそれを行うための非常に効率的な方法ではありませんが、オンラインおよびこれらのフォーラムでの検索では、別の方法は見つかりませんでした。
このプロセスを自動化するのに役立つヒントをいただければ幸いです。 ありがとう。
やあ@CerealGuy 、コミュニティへようこそ！
JMPのシミュレーターには、シミュレーション実験と呼ばれるツールがあります。これは、あなたがここで達成しようとしていると私が信じていることのために構築されました。以下のスクリプトには、適切なコマンドを見つけるためのシミュレーションメニューの調査とともに、従うことができるはずのコメントがあります（プロファイラー内のシミュレーションの横にある赤い三角形を見てください）。これはあなたが探している道ですか？
Names default to here(1);
// Open a sample data set and make a prediction for yield
dt = Open("$Sample_data/Ro.jmp");
fm = Fit Model(
Y( :Yield ),
Effects( :Aperture, :Ranging, :Cadence ),
Personality( "Standard Least Squares" ),
Emphasis( "Effect Leverage" ),
Run(
:Yield << {Summary of Fit( 1 ), Analysis of Variance( 1 ),
Parameter Estimates( 1 ), Lack of Fit( 0 ), Scaled Estimates( 0 ),
Plot Actual by Predicted( 1 ), Plot Regression( 0 ),
Plot Residual by Predicted( 1 ), Plot Studentized Residuals( 0 ),
Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ),
Box Cox Y Transformation( 0 )}
)
);
fm << Prediction Formula;
// Use simulation in the profiler to estimate variation in yield at a single point
prf = Profiler(
Y( :Pred Formula Yield ),
Profiler(
1,
Term Value(
Aperture( 11.25, Lock( 0 ), Show( 1 ) ),
Ranging( 10, Lock( 0 ), Show( 1 ) ),
Cadence( 22.5, Lock( 0 ), Show( 1 ) )
),
Simulator(
1,
Factors(
Aperture << Random( Normal( 11.25, 2 ) ),
Ranging << Random( Normal( 10, 1 ) ),
Cadence << Random( Normal( 22.5, 4 ) )
),
Responses( Pred Formula Yield << No Noise )
)
)
);
// Do a simulation experiment to calculation variation in yield for
// different levels of your inputs. Note that you might need to
// adjust the ranges for different variables before this step using
// 'resent factor grid' to ensure you explore the relevant space.
dtSim = prf << Simulator( Simulation Experiment( 512, 1 ) );
dtSim << New Column( "Lowest Yield Expected",
Numeric,
"Continuous",
Format( "Best", 12 ),
Formula( :Pred Formula Yield Mean - 3 * :Pred Formula Yield SD )
);
// Graph results
dtSim << Graph Builder(
Size( 558, 552 ),
Show Control Panel( 0 ),
Variables(
X( :Aperture ),
Y( :Ranging ),
Wrap( :Cadence, Levels( 9 ) ),
Color( :Lowest Yield Expected )
),
Elements( Contour( X, Y, Legend( 9 ) ) )
);
ありがとうございました@ih 、この答えはまさに私が探していたものです！ 私が説明した各セクションのコメントと完全なコードに感謝します。
私の唯一の追加の質問は、このスクリプトでもシミュレータから「スペック制限」を設定する方法です。 このような：
// Use simulation in the profiler to estimate variation in yield at a single point
prf = Profiler(
Y( :Pred Formula Yield ),
Profiler(
1,
Term Value(
Aperture( 11.25, Lock( 0 ), Show( 1 ) ),
Ranging( 10, Lock( 0 ), Show( 1 ) ),
Cadence( 22.5, Lock( 0 ), Show( 1 ) )
),
Simulator(
1,
Factors(
Aperture << Random( Normal( 11.25, 2 ) ),
Ranging << Random( Normal( 10, 1 ) ),
Cadence << Random( Normal( 22.5, 4 ) )
),
Responses( Pred Formula Yield << No Noise ),
<FONT color="#FF0000"> Spec Limits( Pred Formula Yield, LSL(0), USL(2) ) // insert actual Spec Limits Code here</FONT> )
)
);この同等のコードを追加すると、[スペック制限]ダイアログボックスが表示されますが、「スペック制限（）」呼び出しでさまざまな式を入力できませんでした。 私はこのような小さなもののドキュメントを見つけるのに苦労しています。
