408383_fr-FR

liliconcom

Automatisation de la simulation du profil de prédiction

Bonjour à tous!

 

Dans le profileur de prédiction, l'utilisateur peut générer des valeurs PPM avec des formules de prédiction, des entrées et des limites de spécification données. Cela peut être fait en appuyant simplement sur le bouton "simuler" à côté du profileur de prédiction dans la configuration de l'interface graphique du profileur. À ce stade, un tableau sera généré contenant les valeurs de moyenne, de PPM et d'écart-type.

 

Je suis curieux: Ce processus peut-il être automatisé dans un script (ou ailleurs dans l'interface graphique) pour produire plusieurs valeurs PPM sur une plage de valeurs définie pour l'une des variables d'entrée . J'utiliserais ces données pour tracer et afficher les différentes valeurs PPM par rapport aux paramètres d'entrée donnés. Pour l'instant, je n'ai pas trouvé le moyen de le faire. Le seul moyen actuellement est de simplement modifier la valeur d'entrée et d'appuyer à nouveau sur le bouton de simulation, puis de documenter manuellement la valeur PPM de sortie. Ce n'est évidemment pas un moyen très efficace de le faire, mais à travers mes recherches en ligne et dans ces forums je n'ai pas trouvé d'autre méthode.

 

J'apprécierais grandement tous les conseils pour aider à automatiser ce processus! Merci.

BICHEScriptles fenêtresRe : Automatisation de la simulation du profil de prédiction

salut @L'homme céréale , bienvenue dans la communauté !

 

Le simulateur de JMP dispose d'un outil appelé expérience de simulation qui a été conçu pour ce que je pense que vous essayez d'accomplir ici.Le script ci-dessous contient des commentaires que vous devriez pouvoir suivre, ainsi qu'une exploration des menus de simulation pour trouver les bonnes commandes (regardez dans le triangle rouge à côté de Simulation dans le profileur).Est-ce le chemin que vous recherchez?

 

Names default to here(1);

// Open a sample data set and make a prediction for yield
dt = Open("$Sample_data/Ro.jmp");

fm = Fit Model(
 Y( :Yield ),
 Effects( :Aperture, :Ranging, :Cadence ),
 Personality( "Standard Least Squares" ),
 Emphasis( "Effect Leverage" ),
 Run(
  :Yield << {Summary of Fit( 1 ), Analysis of Variance( 1 ),
  Parameter Estimates( 1 ), Lack of Fit( 0 ), Scaled Estimates( 0 ),
  Plot Actual by Predicted( 1 ), Plot Regression( 0 ),
  Plot Residual by Predicted( 1 ), Plot Studentized Residuals( 0 ),
  Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ),
  Box Cox Y Transformation( 0 )}
 )
);

fm << Prediction Formula;

// Use simulation in the profiler to estimate variation in yield at a single point
prf = Profiler(
 Y( :Pred Formula Yield ),
 Profiler(
  1,
  Term Value(
   Aperture( 11.25, Lock( 0 ), Show( 1 ) ),
   Ranging( 10, Lock( 0 ), Show( 1 ) ),
   Cadence( 22.5, Lock( 0 ), Show( 1 ) )
  ),
  Simulator(
   1,
   Factors(
    Aperture << Random( Normal( 11.25, 2 ) ),
    Ranging << Random( Normal( 10, 1 ) ),
    Cadence << Random( Normal( 22.5, 4 ) )
   ),
   Responses( Pred Formula Yield << No Noise )
  )
 )
);

// Do a simulation experiment to calculation variation in yield for 
// different levels of your inputs.  Note that you might need to
// adjust the ranges for different variables before this step using
// 'resent factor grid' to ensure you explore the relevant space.
dtSim = prf << Simulator( Simulation Experiment( 512, 1 ) );
dtSim << New Column( "Lowest Yield Expected",
 Numeric,
 "Continuous",
 Format( "Best", 12 ),
 Formula( :Pred Formula Yield Mean - 3 * :Pred Formula Yield SD )
);

// Graph results
dtSim << Graph Builder(
 Size( 558, 552 ),
 Show Control Panel( 0 ),
 Variables(
  X( :Aperture ),
  Y( :Ranging ),
  Wrap( :Cadence, Levels( 9 ) ),
  Color( :Lowest Yield Expected )
 ),
 Elements( Contour( X, Y, Legend( 9 ) ) )
);

 

Re : Automatisation de la simulation du profil de prédiction

Merci @ih , cette réponse est exactement ce que je cherchais ! J'apprécie les commentaires et le code complet pour chacune des sections que j'avais décrites.

 

Ma seule question supplémentaire est de savoir comment je peux également définir les "limites de spécification" du simulateur dans ce script. Tel que cela:

// Use simulation in the profiler to estimate variation in yield at a single point
prf = Profiler(
 Y( :Pred Formula Yield ),
 Profiler(
  1,
  Term Value(
   Aperture( 11.25, Lock( 0 ), Show( 1 ) ),
   Ranging( 10, Lock( 0 ), Show( 1 ) ),
   Cadence( 22.5, Lock( 0 ), Show( 1 ) )
  ),
  Simulator(
   1,
   Factors(
    Aperture << Random( Normal( 11.25, 2 ) ),
    Ranging << Random( Normal( 10, 1 ) ),
    Cadence << Random( Normal( 22.5, 4 ) )
   ),
   Responses( Pred Formula Yield << No Noise ),
<FONT color="#FF0000">            Spec Limits( Pred Formula Yield, LSL(0), USL(2) )     // insert actual Spec Limits Code here</FONT>  )
 )
);

Si j'ajoute cet équivalent de code, la boîte de dialogue Spec Limits s'affiche, mais je n'ai pas pu la remplir avec diverses expressions dans l'appel "Spec Limits()". J'ai eu du mal à trouver de la documentation pour de petites choses comme celle-ci.