406319_zh-TW

liliconcom

如何使用圖形構建器從列中定義控制限？

嗨，大家好

我正在使用圖形構建器在報告中製作圖形。 我喜歡在圖表上添加參考線作為 CL、LCL、UCL。 我在我的表的列（例如 X）中有它們。 我試圖在腳本中調用它們，例如，

{添加參考線(:X, "Solid", "Black", "LCL", 1 )}

但它不起作用

請你幫助我好嗎

謝謝

腳本編寫回复：如何使用圖形構建器從列中定義控制限？

根據您的數據，您可以這樣做：

 

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
//add limit columns
dt << New Column("UCL", Numeric, Continuous, Set Each Value(70));
dt << New Column("CL", Numeric, Continuous, Set Each Value(60));
dt << New Column("LCL", Numeric, Continuous, Set Each Value(50));

gb = Graph Builder(Variables(X(:age), Y(:height)), Elements(Points(X, Y, Legend(4))));

axisb = (report(gb)[axisbox(2)]);
axisb << ({
 Add Ref Line(dt:UCL[1], "Solid", "Black", "UCL", 1),
 Add Ref Line(dt:CL[1], "Solid", "Black", "CL", 1),
 Add Ref Line(dt:LCL[1], "Solid", "Black", "LCL", 1)
});

或者直接繪製這些列：

 

或將這些設置為列屬性作為規格限制：

如果需要，所有這些都可以編寫腳本。

 

編輯：

如果您的意思是設置了 Control Limit Column 屬性，則需要一些額外的腳本來從列屬性中獲取限制（解析部分將主要取決於案例和控制限制的設置方式，但想法應該是相同的)：

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Quality Control/Coating.jmp");
obj = dt << Control Chart(Sample Size(:Sample), KSigma(3), Chart Col(:Weight, XBar, R));
Wait(0);
obj << Save Limits(in Column);

gb = Graph Builder(
 Variables(X(:Sample), Y(:Weight)),
 Elements(Points(X, Y, Legend(3)), Smoother(X, Y, Legend(4)))
);

//get Control Limits column property and parse limits
colProp = dt:weight << Get Property("Control Limits");
xbarLimits = Words(Char(colProp[1]));
xbarCL = Num(Word(3, xbarLimits[1], "()"));
xbarLCL = Num(Word(2, xbarLimits[2], "()"));
xbarUCL = Num(Word(2, xbarLimits[3], "()"));

//add control limits
axisb = (report(gb)[axisbox(2)]);
axisb << ({
 Add Ref Line(xbarUCL, "Solid", "Black", "UCL", 1),
 Add Ref Line(xbarCL, "Solid", "Black", "CL", 1),
 Add Ref Line(xbarLCL, "Solid", "Black", "LCL", 1)
});