406319_zh-CN

liliconcom

如何使用图形构建器从列中定义控制限？

嗨，大家好

我正在使用图形构建器在报告中制作图形。 我喜欢在图表上添加参考线作为 CL、LCL、UCL。 我将它们放在我表的列（例如 X）中。 我试图在脚本中调用它们，例如，

{添加参考线(:X, "Solid", "Black", "LCL", 1 )}

但它不起作用

请你帮助我好吗

谢谢

脚本编写回复：如何使用图形构建器从列中定义控制限？

根据您的数据，您可以这样做：

 

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
//add limit columns
dt << New Column("UCL", Numeric, Continuous, Set Each Value(70));
dt << New Column("CL", Numeric, Continuous, Set Each Value(60));
dt << New Column("LCL", Numeric, Continuous, Set Each Value(50));

gb = Graph Builder(Variables(X(:age), Y(:height)), Elements(Points(X, Y, Legend(4))));

axisb = (report(gb)[axisbox(2)]);
axisb << ({
 Add Ref Line(dt:UCL[1], "Solid", "Black", "UCL", 1),
 Add Ref Line(dt:CL[1], "Solid", "Black", "CL", 1),
 Add Ref Line(dt:LCL[1], "Solid", "Black", "LCL", 1)
});

或者直接绘制这些列：

 

或将这些设置为列属性作为规格限制：

如果需要，所有这些都可以编写脚本。

 

编辑：

如果您的意思是设置了 Control Limit Column 属性，则需要一些额外的脚本来从列属性中获取限制（解析部分将主要取决于案例和控制限制的设置方式，但想法应该是相同的)：

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Quality Control/Coating.jmp");
obj = dt << Control Chart(Sample Size(:Sample), KSigma(3), Chart Col(:Weight, XBar, R));
Wait(0);
obj << Save Limits(in Column);

gb = Graph Builder(
 Variables(X(:Sample), Y(:Weight)),
 Elements(Points(X, Y, Legend(3)), Smoother(X, Y, Legend(4)))
);

//get Control Limits column property and parse limits
colProp = dt:weight << Get Property("Control Limits");
xbarLimits = Words(Char(colProp[1]));
xbarCL = Num(Word(3, xbarLimits[1], "()"));
xbarLCL = Num(Word(2, xbarLimits[2], "()"));
xbarUCL = Num(Word(2, xbarLimits[3], "()"));

//add control limits
axisb = (report(gb)[axisbox(2)]);
axisb << ({
 Add Ref Line(xbarUCL, "Solid", "Black", "UCL", 1),
 Add Ref Line(xbarCL, "Solid", "Black", "CL", 1),
 Add Ref Line(xbarLCL, "Solid", "Black", "LCL", 1)
});

回复：如何使用图形构建器从列中定义控制限？

@jthi ， 谢谢。

我有控制限作为列。 我可以将一个单元格称为 UCL[1]，但问题是，其中一些列有可能是第一个或任何其他单元格的空单元格。 我想从非空列中的单元格添加 Ref 行。

你知道我该怎么做吗？

谢谢