やあみんな
グラフビルダーを使用して、レポートにグラフを作成しています。 グラフにCL、LCL、UCLとして参照線を追加するのが好きです。 テーブルの列（Xなど）にそれらがあります。 私はスクリプトでそれらを次のように呼び出そうとしています、
{Ref Line（：X、 "Solid"、 "Black"、 "LCL"、1）}を追加します。
しかし、それは機能しません
手伝っていただけませんか
ありがとう
データに応じて、次のようにすることができます。
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
//add limit columns
dt << New Column("UCL", Numeric, Continuous, Set Each Value(70));
dt << New Column("CL", Numeric, Continuous, Set Each Value(60));
dt << New Column("LCL", Numeric, Continuous, Set Each Value(50));
gb = Graph Builder(Variables(X(:age), Y(:height)), Elements(Points(X, Y, Legend(4))));
axisb = (report(gb)[axisbox(2)]);
axisb << ({
Add Ref Line(dt:UCL[1], "Solid", "Black", "UCL", 1),
Add Ref Line(dt:CL[1], "Solid", "Black", "CL", 1),
Add Ref Line(dt:LCL[1], "Solid", "Black", "LCL", 1)
});または、これらの列を直接プロットします。
または、それらを仕様制限として列プロパティに設定します。
これらはすべて、必要に応じてスクリプト化できます。
編集：
また、Control Limit Columnプロパティを設定する場合は、列プロパティから制限を取得するために少し余分なスクリプトが必要になります（解析部分は、ケースと管理制限の設定方法に少し依存しますが、考え方は同じである必要があります）：：
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Quality Control/Coating.jmp");
obj = dt << Control Chart(Sample Size(:Sample), KSigma(3), Chart Col(:Weight, XBar, R));
Wait(0);
obj << Save Limits(in Column);
gb = Graph Builder(
Variables(X(:Sample), Y(:Weight)),
Elements(Points(X, Y, Legend(3)), Smoother(X, Y, Legend(4)))
);
//get Control Limits column property and parse limits
colProp = dt:weight << Get Property("Control Limits");
xbarLimits = Words(Char(colProp[1]));
xbarCL = Num(Word(3, xbarLimits[1], "()"));
xbarLCL = Num(Word(2, xbarLimits[2], "()"));
xbarUCL = Num(Word(2, xbarLimits[3], "()"));
//add control limits
axisb = (report(gb)[axisbox(2)]);
axisb << ({
Add Ref Line(xbarUCL, "Solid", "Black", "UCL", 1),
Add Ref Line(xbarCL, "Solid", "Black", "CL", 1),
Add Ref Line(xbarLCL, "Solid", "Black", "LCL", 1)
});@jthi 、 ありがとうございました。
列として管理限界があります。 1つのセルをUCL [1]と呼ぶことができますが、問題は、これらの列の一部に、最初のセルまたは他のセルである可能性のある空のセルがあることです。 空ではない列のセルからRef行を追加したいと思います。
どうすればそれができるか分かりますか？
ありがとう
