406319_fr-FR

liliconcom

Comment définir les limites de contrôle à partir d'une colonne à l'aide du générateur de graphiques ?

Salut à tous

J'utilise graph builder pour créer les graphiques dans un rapport. J'aime ajouter les lignes de référence sur le graphique comme CL,LCL,UCL. Je les ai dans les colonnes (par exemple X) dans ma table. J'essaie de les appeler dans le script comme,

{Ajouter une ligne de référence(:X, "Solide", "Black", "LCL", 1 )}

Mais ça ne marche pas

Pourrais-tu m'aider s'il te plaît

Merci

ScriptRe : Comment définir les limites de contrôle d'une colonne à l'aide du générateur de graphes ?

En fonction de vos données, vous pouvez procéder de la manière suivante :

 

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
//add limit columns
dt << New Column("UCL", Numeric, Continuous, Set Each Value(70));
dt << New Column("CL", Numeric, Continuous, Set Each Value(60));
dt << New Column("LCL", Numeric, Continuous, Set Each Value(50));

gb = Graph Builder(Variables(X(:age), Y(:height)), Elements(Points(X, Y, Legend(4))));

axisb = (report(gb)[axisbox(2)]);
axisb << ({
 Add Ref Line(dt:UCL[1], "Solid", "Black", "UCL", 1),
 Add Ref Line(dt:CL[1], "Solid", "Black", "CL", 1),
 Add Ref Line(dt:LCL[1], "Solid", "Black", "LCL", 1)
});

Ou tracez ces colonnes directement :

 

ou définissez-les sur les propriétés de la colonne comme limites de spécification :

Tout cela peut être scénarisé si nécessaire.

 

Éditer:

Et si vous voulez dire que vous avez défini la propriété de la colonne de limite de contrôle, il faudra un peu de script supplémentaire pour extraire les limites de la propriété de colonne (la partie d'analyse dépendra un peu de la casse et de la façon dont les limites de contrôle sont définies, mais l'idée devrait être la même

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Quality Control/Coating.jmp");
obj = dt << Control Chart(Sample Size(:Sample), KSigma(3), Chart Col(:Weight, XBar, R));
Wait(0);
obj << Save Limits(in Column);

gb = Graph Builder(
 Variables(X(:Sample), Y(:Weight)),
 Elements(Points(X, Y, Legend(3)), Smoother(X, Y, Legend(4)))
);

//get Control Limits column property and parse limits
colProp = dt:weight << Get Property("Control Limits");
xbarLimits = Words(Char(colProp[1]));
xbarCL = Num(Word(3, xbarLimits[1], "()"));
xbarLCL = Num(Word(2, xbarLimits[2], "()"));
xbarUCL = Num(Word(2, xbarLimits[3], "()"));

//add control limits
axisb = (report(gb)[axisbox(2)]);
axisb << ({
 Add Ref Line(xbarUCL, "Solid", "Black", "UCL", 1),
 Add Ref Line(xbarCL, "Solid", "Black", "CL", 1),
 Add Ref Line(xbarLCL, "Solid", "Black", "LCL", 1)
});

Re : Comment définir les limites de contrôle d'une colonne à l'aide du générateur de graphes ?

@jthi , Merci.

J'ai les limites de contrôle sous forme de colonnes. Je peux appeler une cellule comme UCL[1], mais le problème est que certaines de ces colonnes ont des cellules vides qui peuvent être la première ou toute autre cellule. Je veux ajouter la ligne Ref de la cellule dans la colonne qui n'est pas vide.

Avez-vous une idée de comment je peux faire ça?

Merci