400410_it-IT

liliconcom

jmp 15 grafico builder conserva in qualche modo riferimenti obsoleti alle forme della mappa

Me lo chiedevo qualche mese fa qui: JMP15 Graph Builder non aggiorna la mappa dopo aver modificato il file delle coordinate -XY

 

Ho lo stesso problema e mi sembra di aver provato di tutto.

Ho provato a cancellare la colonna "Nome"

riportando indietro la colonna del nome

riassegnazione del ruolo della mappa.

 

Se esco da jmp e quindi apro la stessa identica tabella di dati e trascino "Nome" in basso nelle forme della mappa, FUNZIONA!

Ok, quindi sembra POSSIBILE avere 2 forme di mappa separate e disegnarle contemporaneamente.

Sembra che NON sia POSSIBILE modificare XY, Nome, Principale -> aggiorna una configurazione esistente senza uscire e riaprire jmp.

 

Direi che è un bug, ma per ora posso girarci intorno, fortunatamente ci sono solo poche rotazioni potenziali, quindi le genererò tutte in anticipo e le servirò come la statica più amatoriale del mondo pagina web.

 

Se abbiamo bisogno di un esempio dal vivo, proverò a creare un semplice caso d'uso che non contenga tutto l'IP che i miei file attuali stanno trascinando.

Ma ho bisogno di questo script in modo appropriato perché sto cercando di creare una funzione "ruota", quindi dopo aver regolato tutte le coordinate XY delle forme della mia mappa devo essere in grado di ridisegnarle!

 

aiutami obi wan jmp community sei la mia unica speranza.

 

L'aggiornamento ha provato più cose. Letteralmente, l'unico modo per farlo funzionare è uscire e riaprire jmp

 

È persino resistente all'eliminazione dei simboli ();

 

Invece di rifare il mio attuale trio di errori "dati principali, XY, NOME"
Proverò a generarne di nuovi e vedrò se jmp seleziona solo l'ultimo file di mappa aperto e rimane permanentemente bloccato su di esso.

GraficaScriptingRe: il costruttore di grafici jmp 15 mantiene in qualche modo un riferimento obsoleto alle forme della mappa

Non ho testato con JMP16, ma con JMP15 sono riuscito a replicare il problema che stai riscontrando. Non ho capito come gestire la modifica della forma della mappa senza crearne di nuove e quindi aggiornare la proprietà della colonna con il nuovo file mappa e la proprietà Shape nel generatore di grafici (quindi non è necessario ricreare il generatore di grafici).

 

Ecco un esempio che funzionerà con la rotazione, ma per usarlo in produzione sarà necessario più codice per gestire la creazione/rotazione del file mappa in modo più efficiente.

Visualizza di più...

Names Default To Here(1);

::GLOBAL_MAP_ID = 1;
Create Directory("$TEMP/MAPTEST/");

mapNames = New Table("MAPTEST"||Char(::GLOBAL_MAP_ID)||"-Name",
 Add Rows(4),
 New Column("Shape Id", Numeric, "Continuous", Format("Best", 12), Set Values([1, 2, 3, 4]), Set Display Width(48)),
 New Column("Name",
  Character,
  "Nominal",
  Set Property("Map Role", Map Role(Shape Name Definition)),
  Set Values({"TopLeft", "TopRight", "BottomRight", "BottomLeft"}),
  Set Display Width(67)
 ),
 private
);
Close(mapNames, Save("$TEMP/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-Name.jmp"));
mapXy = New Table("MAPTEST-XY",
 Add Rows(16),
 Compress File When Saved(1),
 New Column("Shape ID",
  Numeric,
  "Continuous",
  Format("Best", 10),
  Set Values([1, 1, 1, 1, 2, 2, 2, 2, 3, 3, 3, 3, 4, 4, 4, 4]),
  Set Display Width(50)
 ),
 New Column("Part ID",
  Numeric,
  "Continuous",
  Format("Best", 10),
  Set Values([1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1]),
  Set Display Width(39)
 ),
 New Column("X1",
  Numeric,
  "Continuous",
  Format("Best", 10),
  Set Values([-2, -2, 0, 0, 0, 0, 2, 2, 0, 0, 2, 2, -2, -2, 0, 0]),
  Set Display Width(60)
 ),
 New Column("Y1",
  Numeric,
  "Continuous",
  Format("Best", 10),
  Set Values([0, 2, 2, 0, 0, 2, 2, 0, -2, 0, 0, -2, -2, 0, 0, -2]),
  Set Display Width(52)
 ),
 private
);
Close(mapXy, Save("$TEMP/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-XY.jmp"));

dt = Eval(EvalExpr(New Table("gb",
 Add Rows(4),
 New Column("Shape",
  Character,
  "Nominal",
  Set Property("Map Role", Map Role(Shape Name Use(Expr(Get Path Variable("$TEMP")||"/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-Name.jmp"), "Name"))),
  Set Values({"TopLeft", "TopRight", "BottomRight", "BottomLeft"}),
  Set Display Width(80)
 ),
 New Column("OrigLoc", Character, "Nominal", Set Values({"TopLeft", "TopRight", "BottomRight", "BottomLeft"}))
)));

nw = New Window("rotation",
 H List Box(
  V List Box(
   Button Box("$TEMP/MAPTEST/", Open("$TEMP/MAPTEST/")),
   Button Box("Rotate",
   //Rotate
    dtXY = Open("$TEMP/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-XY.jmp");
    origX = dtXY:X1 << get as matrix;
    dtXY:X1 << set values(origX[5 :: 16]` || origX[1 :: 4]`);

    origY = dtXY:Y1 << get as matrix;
    dtXY:Y1 << set values(origY[5 :: 16]` || origY[1 :: 4]`);
    
    ::GLOBAL_MAP_ID++; //move to next 
    
    Close(dtXY, Save("$TEMP/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-XY.jmp"));
    Wait(0);
    mapNames = New Table("MAPTEST"||Char(::GLOBAL_MAP_ID)||"-Name",
     Add Rows(4),
     New Column("Shape Id", Numeric, "Continuous", Format("Best", 12), Set Values([1, 2, 3, 4]), Set Display Width(48)),
     New Column("Name",
      Character,
      "Nominal",
      Set Property("Map Role", Map Role(Shape Name Definition)),
      Set Values({"TopLeft", "TopRight", "BottomRight", "BottomLeft"}),
      Set Display Width(67)
     ),
     private
    );
    Close(mapNames, Save("$TEMP/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-Name.jmp"));
    Current Data Table():Shape << Set Property("Map Role", Eval(EvalExpr(Map Role(Shape Name Use(Expr(Get Path Variable("$TEMP")||"/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-Name.jmp"), "Name")))));
   )
  ),
  gb = Graph Builder(Size(640, 534), Show Control Panel(0), Variables(Color(:OrigLoc), Shape(:Shape)), Elements(Map Shapes(Legend(7)))); 
 )
);

dt << On Close(
 Try(Window("rotation") << Close Window);
 delFiles = Files In Directory("$TEMP/MAPTEST/");
 Show(delFiles);
 For(i = 1, i <= N Items(delFiles), i++,
  Try(Delete File("$TEMP/MAPTEST/"||delFiles[i]), Show(exception_msg));
 );
);

Non so chi taggare, ma lo so @giuliano ha fornito alcune istruzioni su come modificare variabili ed elementi nei costruttori di grafici, quindi forse ha alcune idee su questo.