400410_fr-FR

liliconcom

jmp 15 graph builder conserve en quelque sorte une référence obsolète aux formes de carte

Cela a été demandé il y a quelques mois ici : JMP15 Graph Builder ne met pas à jour la carte après avoir modifié le fichier de coordonnées -XY

 

J'ai le même problème et j'ai l'impression d'avoir tout essayé.

J'ai essayé de nuking la colonne "Nom"

ramener la colonne de nom

réattribuer le rôle de carte.

 

Si je quitte jmp puis que j'ouvre exactement la même table de données et que je fais glisser "Nom" vers le bas dans les formes de la carte, ÇA FONCTIONNE !

Ok, il semble donc POSSIBLE d'avoir 2 formes de carte distinctes et de les dessiner en même temps.

Il semble qu'il ne soit PAS POSSIBLE de modifier XY,Name,Main --> actualiser une configuration existante sans quitter et rouvrir jmp.

 

Je dirais que c'est un bug, mais je peux danser autour de ça pour le moment, Heureusement pour moi, il n'y a que quelques rotations potentielles, donc je vais juste les générer toutes à l'avance et les servir comme les statiques les plus amateurs du monde page Web.

 

Si nous avons besoin d'un exemple en direct, j'essaierai de créer un cas d'utilisation simple qui ne contient pas toutes les adresses IP que mes fichiers actuels traînent.

Mais j'ai besoin de ce script de manière appropriée car j'essaie de créer une fonction de "rotation", donc après avoir ajusté toutes les coordonnées XY de mes formes de carte, je dois pouvoir les redessiner!

 

aidez-moi communauté obi wan jmp vous êtes mon seul espoir.

 

La mise à jour a essayé plus de choses. Littéralement, la seule façon de faire fonctionner cela est de quitter et de rouvrir jmp

 

Il est même résistant à supprimer les symboles ();

 

Au lieu de refaire mon trio actuel d'échecs "données principales, XY, NOM"
Je vais essayer d'en générer de nouveaux et voir si jmp sélectionne simplement le dernier fichier de carte ouvert et y reste définitivement bloqué.

GraphiqueScriptRe: jmp 15 graph builder conserve en quelque sorte une référence obsolète aux formes de carte

Je n'ai pas testé avec JMP16, mais avec JMP15, j'ai réussi à reproduire le problème que vous rencontrez. Je n'ai pas compris comment gérer la modification de la forme de la carte sans en créer de nouvelles, puis mettre à jour la propriété de la colonne avec un nouveau fichier de carte et la propriété Shape dans le générateur de graphique (vous n'avez donc pas à recréer le générateur de graphique).

 

Voici un exemple qui fonctionnera avec la rotation, mais pour l'utiliser en production, il faudra plus de code pour gérer la création/rotation du fichier de carte de manière plus efficace.

Voir plus...

Names Default To Here(1);

::GLOBAL_MAP_ID = 1;
Create Directory("$TEMP/MAPTEST/");

mapNames = New Table("MAPTEST"||Char(::GLOBAL_MAP_ID)||"-Name",
 Add Rows(4),
 New Column("Shape Id", Numeric, "Continuous", Format("Best", 12), Set Values([1, 2, 3, 4]), Set Display Width(48)),
 New Column("Name",
  Character,
  "Nominal",
  Set Property("Map Role", Map Role(Shape Name Definition)),
  Set Values({"TopLeft", "TopRight", "BottomRight", "BottomLeft"}),
  Set Display Width(67)
 ),
 private
);
Close(mapNames, Save("$TEMP/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-Name.jmp"));
mapXy = New Table("MAPTEST-XY",
 Add Rows(16),
 Compress File When Saved(1),
 New Column("Shape ID",
  Numeric,
  "Continuous",
  Format("Best", 10),
  Set Values([1, 1, 1, 1, 2, 2, 2, 2, 3, 3, 3, 3, 4, 4, 4, 4]),
  Set Display Width(50)
 ),
 New Column("Part ID",
  Numeric,
  "Continuous",
  Format("Best", 10),
  Set Values([1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1]),
  Set Display Width(39)
 ),
 New Column("X1",
  Numeric,
  "Continuous",
  Format("Best", 10),
  Set Values([-2, -2, 0, 0, 0, 0, 2, 2, 0, 0, 2, 2, -2, -2, 0, 0]),
  Set Display Width(60)
 ),
 New Column("Y1",
  Numeric,
  "Continuous",
  Format("Best", 10),
  Set Values([0, 2, 2, 0, 0, 2, 2, 0, -2, 0, 0, -2, -2, 0, 0, -2]),
  Set Display Width(52)
 ),
 private
);
Close(mapXy, Save("$TEMP/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-XY.jmp"));

dt = Eval(EvalExpr(New Table("gb",
 Add Rows(4),
 New Column("Shape",
  Character,
  "Nominal",
  Set Property("Map Role", Map Role(Shape Name Use(Expr(Get Path Variable("$TEMP")||"/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-Name.jmp"), "Name"))),
  Set Values({"TopLeft", "TopRight", "BottomRight", "BottomLeft"}),
  Set Display Width(80)
 ),
 New Column("OrigLoc", Character, "Nominal", Set Values({"TopLeft", "TopRight", "BottomRight", "BottomLeft"}))
)));

nw = New Window("rotation",
 H List Box(
  V List Box(
   Button Box("$TEMP/MAPTEST/", Open("$TEMP/MAPTEST/")),
   Button Box("Rotate",
   //Rotate
    dtXY = Open("$TEMP/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-XY.jmp");
    origX = dtXY:X1 << get as matrix;
    dtXY:X1 << set values(origX[5 :: 16]` || origX[1 :: 4]`);

    origY = dtXY:Y1 << get as matrix;
    dtXY:Y1 << set values(origY[5 :: 16]` || origY[1 :: 4]`);
    
    ::GLOBAL_MAP_ID++; //move to next 
    
    Close(dtXY, Save("$TEMP/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-XY.jmp"));
    Wait(0);
    mapNames = New Table("MAPTEST"||Char(::GLOBAL_MAP_ID)||"-Name",
     Add Rows(4),
     New Column("Shape Id", Numeric, "Continuous", Format("Best", 12), Set Values([1, 2, 3, 4]), Set Display Width(48)),
     New Column("Name",
      Character,
      "Nominal",
      Set Property("Map Role", Map Role(Shape Name Definition)),
      Set Values({"TopLeft", "TopRight", "BottomRight", "BottomLeft"}),
      Set Display Width(67)
     ),
     private
    );
    Close(mapNames, Save("$TEMP/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-Name.jmp"));
    Current Data Table():Shape << Set Property("Map Role", Eval(EvalExpr(Map Role(Shape Name Use(Expr(Get Path Variable("$TEMP")||"/MAPTEST/MAPTEST"||Char(::GLOBAL_MAP_ID)||"-Name.jmp"), "Name")))));
   )
  ),
  gb = Graph Builder(Size(640, 534), Show Control Panel(0), Variables(Color(:OrigLoc), Shape(:Shape)), Elements(Map Shapes(Legend(7)))); 
 )
);

dt << On Close(
 Try(Window("rotation") << Close Window);
 delFiles = Files In Directory("$TEMP/MAPTEST/");
 Show(delFiles);
 For(i = 1, i <= N Items(delFiles), i++,
  Try(Delete File("$TEMP/MAPTEST/"||delFiles[i]), Show(exception_msg));
 );
);

Je ne sais pas qui taguer, mais je sais @julien a donné des instructions sur la façon de modifier les variables et les éléments dans les générateurs de graphiques, alors peut-être qu'il a des idées à ce sujet.