399730_ja-JP

liliconcom

条件が満たされた後にJSLコマンドを実行するにはどうすればよいですか

JMPコミュニティユーザーの皆様、
私はJMPの初心者であり、問題に直面しています。 うまくいけば、私はあなたたちから助けを得ることができます。

データテーブルがあります。 一部の特定の値のみの列に対してグラフビルダーを実行したいと思います。

たとえば、AB766とRSDFに属する列「monitor_set_name」と「measurement_set_name」、および「AB766」と「RSDF」に対応する他の列と行であるセルを選択したいと思います。

次に、必要な情報が含まれているテーブルに対して「グラフビルダー」を実行したいと思います。
「monitor_set_name」と「measurement_set_name」に「AB766」と「RSDF」が含まれていない場合は、スキップして「グラフビルダー」を実行します。

アドバイスをいただけますか？

よろしくお願いいたします。

 

データ表スクリプティングRe：条件が満たされた後にJSLコマンドを実行するにはどうすればよいですか

以下のJSLを生成するには、ステップをインタラクティブに実行し、ログからコードを取得してスクリプトウィンドウに貼り付けました。

names default to here(1);

// Open Data Table: big class.jmp
// → Data Table( "big class" )
Open( "$SAMPLE_DATA/big class.jmp" );


// Select matching cells
Data Table( "big class" ) << Select Where( :age == 12 & :sex == "F" );


// Subset data table
// → Data Table( "Subset of big class" )
Data Table( "big class" ) << Subset( Selected Rows( 1 ), Selected columns only( 0 ) );


// Report snapshot: Subset of big class - Graph Builder
Data Table( "Subset of big class" ) << Graph Builder(
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) )
);

// Invert current selection
Data Table( "big class" ) << Invert Row Selection;


// Subset data table
// → Data Table( "Subset of big class 2" )
Data Table( "big class" ) << Subset( Selected Rows( 1 ), Selected columns only( 0 ) );


// Report snapshot: Subset of big class 2 - Graph Builder
Data Table( "Subset of big class 2" ) <<
Graph Builder(
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 6 ) ), Smoother( X, Y, Legend( 7 ) ) )
);

Re：条件が満たされた後にJSLコマンドを実行するにはどうすればよいですか

こんにちは、

 

JMPを初めて使用する場合は、ローカルデータフィルターと列スイッチャーを確認してください。 ローカルデータフィルターはおそらくここであなたを助けるでしょう... 何ができるかを知らせるために、例に列スイッチャーを含めました。

 

メニュー項目をクリックするだけで、グラフを検討したいデータに制限できます。 コーディングは不要で、使いやすいです...誰でも使用できます。

 

ローカルデータフィルターを取得するには、グラフビルダーの赤い三角形のメニューから[ローカルデータフィルターの追加]を選択します。

 

カラムスイッチャーを入手するには、メインメニューから[やり直し]> [カラムスイッチャー]を選択します。 また、スワップアウトする列と、ローテーションする列を選択する必要があります。 このセットには、スワップアウトする列を必ず含めてください。 すべての列は同じデータ型である必要があります。

 

以下のスクリプトを実行して、これらの動作を垣間見ることができます。

 

乾杯、

ブレイディ

 

Names Default To Here(1);

dt = open ("$Sample_Data\Car Physical Data.jmp");

Graph Builder(
 Size( 526, 448 ),
 Show Control Panel( 0 ),
 Variables( X( :Country ), Y( :Gas Tank Size ) ),
 Elements( Box Plot( X, Y, Legend( 8 ) ), Points( X, Y, Legend( 9 ) ) ),
 Local Data Filter(
  Show Histograms and Bars( 0 ),
  Add Filter(
   columns( :Type ),
   Where( :Type == "Compact" ),
   Display( :Type, N Items( 5 ) )
  )
 ),
 Column Switcher(
  :Gas Tank Size,
  {:Weight, :Turning Circle, :Displacement, :Horsepower, :Gas Tank Size}
 )
);

Re：条件が満たされた後にJSLコマンドを実行するにはどうすればよいですか

親愛なるtxnelson、
できます。 たくさん感謝します。
私はあなたの指導に従い、それを自分自身に適用しようとします

dt = Open( "raw_data.csv", "invisible" );

dt << Select Where(
 :monitor_set_name == "CSP_FAST_TC" & :spc_chart_subset == "STDDEV" & :measurement_set_name == "U1_X"
);

df = dt << Subset( Selected Rows( 1 ), Selected columns only( 0 ), "invisible" );

df << Graph Builder(
 Size( 1056, 675 ),
 Show Control Panel( 0 ),
 Automatic Recalc( 0 ),
 Variables(
  X( :spc_txn_date ),
  Y( :chart_value ),
  Y( :lo_control_lmt, Position( 1 ) ),
  Y( :up_control_lmt, Position( 1 ) ),
  Y( :centerline, Position( 1 ) ),
  Group Y( :monitor_set_name ),
  Group Y( :measurement_set_name ),
  Group Y( :spc_chart_subset ),
  Wrap( :spc_entity )
 ),
 Elements(
  Line( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 25 ), Connection( "Curve" ), Smoothness( 0.5 ) )
 ),
 SendToReport(
  Dispatch( {}, "spc_txn_date", ScaleBox, {Label Row( Automatic Font Size( 0 ) )} ),
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    25,
    Properties( 2, {Line Color( 19 )} ),
    Properties( 3, {Line Color( 0 ), Line Style( "Dotted" )} )
   )}
  )
 )
);

df << save picture( "C:\Users\lamquocb\image.jpg" );

ただし、画像を保存できないという別の問題が発生しました。それは、dfのグラフビルダーです。
写真を保存したい場所にアクセスしようとしましたが、見つかりませんでした。
何かアドバイスはありますか？
よろしくお願いいたします。

Re：条件が満たされた後にJSLコマンドを実行するにはどうすればよいですか

変数「df」は、サブセット化されたデータテーブルを指します。データテーブルからレポートを作成する場合、そのレポートはデータテーブルの一部にはなりません。それ自体が実体です。したがって、作成されたレポートにアクセスする最も簡単な方法は、レポートを指す変数を指定することです。以下のスクリプトの変更でこれを行いました。

gb = df << Graph Builder(

変数「gb」はグラフビルダーオブジェクトを指します。コードの後半で、[画像の保存]メッセージがグラフビルダープラットフォームによって生成されたレポートに適用されます

report(gb) << save picture( "C:\Users\lamquocb\image.jpg" );

これが変更されたスクリプトです

names default to here( 1 );
dt = Open( "raw_data.csv", "invisible" );

dt << Select Where(
 :monitor_set_name == "CSP_FAST_TC" & :spc_chart_subset == "STDDEV" & :measurement_set_name == "U1_X"
);

df = dt << Subset( Selected Rows( 1 ), Selected columns only( 0 ), "invisible" );

gb = df << Graph Builder(
 Size( 1056, 675 ),
 Show Control Panel( 0 ),
 Automatic Recalc( 0 ),
 Variables(
  X( :spc_txn_date ),
  Y( :chart_value ),
  Y( :lo_control_lmt, Position( 1 ) ),
  Y( :up_control_lmt, Position( 1 ) ),
  Y( :centerline, Position( 1 ) ),
  Group Y( :monitor_set_name ),
  Group Y( :measurement_set_name ),
  Group Y( :spc_chart_subset ),
  Wrap( :spc_entity )
 ),
 Elements(
  Line( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 25 ), Connection( "Curve" ), Smoothness( 0.5 ) )
 ),
 SendToReport(
  Dispatch( {}, "spc_txn_date", ScaleBox, {Label Row( Automatic Font Size( 0 ) )} ),
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    25,
    Properties( 2, {Line Color( 19 )} ),
    Properties( 3, {Line Color( 0 ), Line Style( "Dotted" )} )
   )}
  )
 )
);

report(gb) << save picture( "C:\Users\lamquocb\image.jpg" );

[ヘルプ]プルダウンメニューにあるJMPドキュメントライブラリにあるスクリプトガイドをお読みになることを強くお勧めします。