398923_zh-CN

liliconcom

使用主题格式的表达式

我正在尝试将多个相似图的格式设置为一个表达式，以便我可以更改代码的单个部分来更新所有看起来相似的图。但是，我很难将其实现为代码。我提供了一个最小的工作示例，展示了我希望绘图是什么样子以及我希望我的代码是什么样子，存储一段用于格式化的代码和每个绘图的紧凑代码。关于如何修改它以使其工作有什么想法吗？我正在开发 JMP 版本 15.2。

dt = New Table( "Minimal Working Example",
	Add Rows( 400 ),
	New Column( "X", Numeric, Set Values( Repeat( 1 :: 20, 20 ) ) ),
	New Column( "Y", Numeric, Set Values( Sort Ascending( Shape( Repeat( 1 :: 20, 20 ), 1 ) ) ) ),
	New Column( "Size", Numeric, <<FORMULA></FORMULA>

<LINGO-LABS id="lingo-labs-398923" slang="en-US" mode="UPDATE"><LINGO-LABEL>高级统计建模</LINGO-LABEL><LINGO-LABEL>数据存取</LINGO-LABEL><LINGO-LABEL>数据混合和清理</LINGO-LABEL><LINGO-LABEL>大规模定制</LINGO-LABEL></LINGO-LABS>回复：使用主题格式的表达式

你好，

 

表达式处理功能强大，需要一些练习。 这是一个让您入门的示例，但您需要阅读 Eval()、Expr()、NameExpr()、Substitute()、Substitute Into() 等内容。

 

Names Default To Here(1);

//make a 5-column table
dt = astable((1::20)` || J(20,4,randominteger(0,20)));

//the x column will be the first column
xCol = column (dt, 1);

//the y columns will be the remaining columns
yColList = (dt << get column names())[2::ncol(dt)];

//write the graph builder script, wrapping it in an expression. Use _XXX_ format for things
//you'll be substituting later. Here, that is just the "y" variable for a particular graph.
gbExpr = expr(
 dt << Graph Builder(
  Variables( X( xcol ), Y( _Y_ ) ),
  Elements( Points( X, Y, Legend( 8 ) ) ),
  SendToReport(
   Dispatch(
    {},
    "400",
    ScaleBox,
    {Legend Model(
     8,
     Properties(
      0,
      {gradient( {Color Theme( "White to Red" )} )},
      Item ID( "Size", 1 )
     )
    )}
   ),
   Dispatch(
    {},
    "400",
    LegendBox,
    {Legend Position( {8, [0, -1]} ), Legend Position( {0, -1} )}
   )
  )
 );
);

//cycling through the items in yColList, we create a graph for each y variable vs the x variable.
//be sure to read up on Name Expr ( ), as it is needed here to prevent evaluation of the Graph
//Builder script... we just want the code itself... we don't want JMP to try to evaluate the code
//until after we've made the substitution.
for (i = 1,i <=nitems(ycolList), i++,
 eval(Substitute( nameExpr(gbExpr),  expr(_Y_) , expr(yColList[i])));
);

干杯，

布雷迪

 

 

 

回复：使用主题格式的表达式

由于 X、Y 和 Color 变量根据我的数据发生变化的方式，这种方法效果不太好，但是我设法使用 JSL Quote、Eval Insert、Parse 和 Eval 找到了更接近我想要的解决方案：

// A theme format I could change for a gazillion of plots
formats = JSL Quote(
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				8,
				Properties(
					0,
					{gradient( {Color Theme( "White to Red" )} )},
					Item ID( "Size", 1 )
				)
			)}
		),
		Dispatch(
			{},
			"400",
			LegendBox,
			{Legend Position( {8, [0, -1]} ), Position( {0, -1} )}
		)
	)
);

// How I would like each plot code to look like
Eval(Parse(Eval Insert("dt << Graph Builder(
	Variables( X( :X ), Y( :Y ), Color( :Size ) ),
	Elements( Points( X, Y, Legend( 8 ) ) ),
	^formats^
);")));