392389_it-IT

liliconcom

Nome irrisolto. Funziona quando rifaccio la sceneggiatura ma non nella sceneggiatura originale??

Quindi ho uno script che sta creando grafici YbyX, eseguendo un Tukey T-Test, quindi creando un dt combinato con i valori p, quindi selezionando ed escludendo in base al valore p.

 

Al momento l'ho incorporato in una funzione dt << New Script() per salvarlo nella tabella dei dati di origine.

 

Non sono sicuro di cosa stia succedendo, ma quando arrivo alla sezione per selezionare i valori p, ottengo questo errore:

dt1 << select where("p-Value"n > 0.05);

Nome irrisolto: p-Value alla riga 1 in accesso o valutazione di 'p-Value' , "p-Value"n /*####*/

 

La cosa strana è che quando lo copio in una nuova finestra di script vuota e lo eseguo manualmente, funziona. Non sono sicuro di cosa stia succedendo o perché. Qualche idea?

 

//need to force it to use a certain file name AND force SPC script to label dt appropriately
dtSPC = current data table();
dtSPC << set name( "SPC Data");

/*plotting a basic Fit YbyX just to get pValues. Formatting and style done on final plot*/
ow1 = Oneway(
 Y( :MEAN ),
 X( :TOOL_PROCESS_CHAMBER ),
 By(Chart_ID,),
 
 //All pairs Tukey HSD test
 All Pairs(
  1,
  Confidence Quantile( 0 ),
  Difference Matrix( 0 ),
  LSD Threshold Matrix( 0 ),
  Connecting Letters Report( 0 ),
  Ordered Differences Report( 1 )
 ),
 
 SendToReport(
  //x-axis formatting
  Dispatch(
   {},
   "2",
   ScaleBox,
   {Label Row(
    {Label Orientation( "Angled" ), Lower Frame( 1 ),
    Show Major Grid( 1 ), Tick Mark Style( "Long Divider" )}
    )
   }
  ),
  
  //row legend by chamber
  Dispatch(
   {},
   "Oneway Plot",
   FrameBox,
   {Marker Size( 6 ), Marker Drawing Mode( "Normal" ),
   Row Legend(
    :Chamber,
    Color( 1 ),
    Color Theme( "JMP Default" ),
    Marker( 0 ),
    Marker Theme( "" ),
    Continuous Scale( 0 ),
    Reverse Scale( 0 ),
    Excluded Rows( 0 )
    )
   }
  )
 )
);
/***********************************/

/***********************************/
// Create the combined data table of Summary Statistics
dt1 = Report( ow1[1] )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD","Ordered Differences Report"][Table Box( 1 )] << Make Combined Data Table;

dt1 = current data table();
dt1 << set name( "pValue PairWise by Channel Tukey");

dt1:Chart_ID << Data type( Numeric ) << Set Modeling Type( Nominal );
/***********************************/

/**********************************/
//Screen and show only the Channel_ID's w/ a Tukey pair pVal<0.05

//exclude all high pVal rows, leaving only low pVal Channels. Does not work in reverse.
dt1 << select where("p-Value"n > 0.05);
dt1 << exclude;
dt1 << clear select;

//create a list of remaining Unique Chart_ID
summarize(dt1, uniqueVals=by(:Chart_ID));
//Convert to numeric
For( i = 1, i <= N Items(uniqueVals ), i++,
 uniqueVals[i] = Num(uniqueVals[i] )
);

//extra, just to look at the data
//dtUnique = New Table( "uniqueVals less 0.05");
//dtUnique << New Column( "Chart_ID", Values(uniqueVals));

//select on SPC source data just the channels w/ low pVals
//need to choose SPC data table
dtSPC << clear select;
dtSPC << select where( contains( uniqueVals, :Chart_ID));

//invert and exclude, leaving only low pVal Chart_ID's
dtSPC << invert row selection << exclude;
dtSPC << clear select;

//close old stuff
close(dt1);
ow1 << close window;

 

 

 

Organizzazione dei contenutiRe: nome irrisolto. Funziona quando rifaccio la sceneggiatura ma non nella sceneggiatura originale??

Prova a cambiare il tuo riferimento sulla riga 58 da

dt1 = Current Data Table();

A

current data table( dt1 );

La differenza è che nella prima istruzione stai impostando il valore di dt1, qualunque sia la tabella di dati corrente, e JMP potrebbe non puntare alla tabella che ti interessa.La seconda istruzione dichiara a JMP di impostare dt1 come tabella dati corrente.