391079_zh-TW

liliconcom

我的意思是如何組合兩個圖表，就像將一個圖表疊加在另一個圖表上一樣

大家好，

 

我有兩張圖，我想在另一張圖上有一張圖。

我嘗試使用組合窗口並複制粘貼框架內容，但是當我將鼠標懸停在粘貼的圖形內容上時，值沒有彈出，任何人都可以幫助我解決這個問題。

 

 

 

謝謝你，

哈努賈

內容組織回复：如何組合兩個圖表，我的意思是像將一個圖表疊加在另一個圖表上一樣

這是一個有點類似於您需要將 2 個數據表輸入放在一起繪製成一個圖的示例。您需要研究腳本，然後獲取新信息並將其應用到您的腳本中。

這是腳本

Names Default To Here( 1 );
dt = Open( "$sample_data/semiconductor capability.jmp" );

// Create 2 Data tables to mimic the Discussion Question situation
dt1 = dt << subset( columns(Wafer, Site, NPN1), selected rows(0));
dt2 = dt << subset( columns(lot_id, Wafer, Site, NPN2), selected rows(0));

// Select rows wanted from table dt1
dt1 << select where( :wafer <= 10 );
// Create new subset of selected rows
dt1Final = dt1 << subset( selected rows( 1 ), selected columns( 0 ) );

// Select rows wanted from table dt2
dt2 << select where( contains( {"lot01", "lot02"}, :lot_id  ));
// Create new subset of selected rows
dt2Final = dt2 << subset( selected rows( 1 ), selected columns( 0 ) );

// put the data together
dtTogether = dt1Final << concatenate( dt2Final );

gb = Graph Builder(
 Size( 534, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :wafer ), Y( :NPN1 ), Y( :NPN2, Position( 1 ) ) ),
 Elements( Points( X, Y( 1 ), Y( 2 ), Legend( 5 ) ) )
);
theReport = report(gb);

// Create the reference lines
theYColList = { "NPN1", "NPN2" };
For( i = 1, i <= N Items( theYColList ),i++,
 specs = Column( theYColList[i] ) << get property( "spec limits" );
 If( Try( specs["USL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["USL"], "Dashed", black, theYColList[i] || " USL" )
 );
 If( Try( specs["LSL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["LSL"], "Dashed", black, theYColList[i] || " LSL" )
 );
 If( Try( specs["Target"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["Target"], "Dashed", black, theYColList[i] || " Target" )
 );
);

 

 

回复：如何組合兩個圖表，我的意思是像將一個圖表疊加在另一個圖表上一樣我提出的圖表是兩個圖表的可接受組合嗎？ 如果沒有，並且您需要在兩個腳本中定義不同的覆蓋，那麼我不知道如何從兩個不同的數據表中剪切並粘貼圖表。回复：如何組合兩個圖表，我的意思是像將一個圖表疊加在另一個圖表上一樣

雖然使用圖形生成器很容易覆蓋圖形，但當覆蓋多於一列時，顯示規格限制會出現問題。然而，添加一個小腳本來添加參考線是一個簡單的過程。這是一種方法

Names Default To Here( 1 );
dt = Open( "$sample_data/semiconductor capability.jmp" );

gb = Graph Builder(
 Size( 534, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :wafer ), Y( :NPN1 ), Y( :NPN2, Position( 1 ) ) ),
 Elements( Points( X, Y( 1 ), Y( 2 ), Legend( 8 ) ) )
);



// determine the columns to add limit reference lines from
theReport = Current Report();
theScript = Char( (theReport[Outline Box( 1 )] << get scriptable object) << get script );
theYColList = {};
While( Contains( theScript, "Y(:" ) != 0,
 theScript = Substr( theScript, Contains( theScript, "Y(:" ) + 3 );
 Insert Into( theYColList, Word( 1, theScript, ":)," ) );
);
// Create the reference lines
For( i = 1, i <= N Items( theYColList ),i++,
 specs = Column( theYColList[i] ) << get property( "spec limits" );
 If( Try( specs["USL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["USL"], "Dashed", black, theYColList[i] || " USL" )
 );
 If( Try( specs["LSL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["LSL"], "Dashed", black, theYColList[i] || " LSL" )
 );
 If( Try( specs["Target"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["Target"], "Dashed", black, theYColList[i] || " Target" )
 );
);