Ciao a tutti,
Sto avendo due grafici individualmente e vorrei avere un grafico sull'altro.
Ho provato a utilizzare finestre combinate e copiare e incollare il contenuto del frame, ma quando passo il mouse sul contenuto del grafico incollato, i valori non vengono visualizzati. Qualcuno può aiutarmi a risolverlo.
Grazie,
Hanuja
Sebbene sia facile sovrapporre i grafici utilizzando Graph Builder, c'è un problema con la visualizzazione dei limiti delle specifiche quando è sovrapposta più di una colonna.Tuttavia, è un processo semplice aggiungere un piccolo script che aggiungerà le linee di riferimento.Ecco un modo per farlo
Names Default To Here( 1 );
dt = Open( "$sample_data/semiconductor capability.jmp" );
gb = Graph Builder(
Size( 534, 450 ),
Show Control Panel( 0 ),
Variables( X( :wafer ), Y( :NPN1 ), Y( :NPN2, Position( 1 ) ) ),
Elements( Points( X, Y( 1 ), Y( 2 ), Legend( 8 ) ) )
);
// determine the columns to add limit reference lines from
theReport = Current Report();
theScript = Char( (theReport[Outline Box( 1 )] << get scriptable object) << get script );
theYColList = {};
While( Contains( theScript, "Y(:" ) != 0,
theScript = Substr( theScript, Contains( theScript, "Y(:" ) + 3 );
Insert Into( theYColList, Word( 1, theScript, ":)," ) );
);
// Create the reference lines
For( i = 1, i <= N Items( theYColList ),i++,
specs = Column( theYColList[i] ) << get property( "spec limits" );
If( Try( specs["USL"], "" ) != "",
theReport[AxisBox( 2 )] << Add Ref Line( specs["USL"], "Dashed", black, theYColList[i] || " USL" )
);
If( Try( specs["LSL"], "" ) != "",
theReport[AxisBox( 2 )] << Add Ref Line( specs["LSL"], "Dashed", black, theYColList[i] || " LSL" )
);
If( Try( specs["Target"], "" ) != "",
theReport[AxisBox( 2 )] << Add Ref Line( specs["Target"], "Dashed", black, theYColList[i] || " Target" )
);
);