391079_de-DE

liliconcom

Wie man zwei Diagramme kombiniert, meine ich, als würde man sie übereinander legen

Hallo an alle,

 

Ich habe zwei Diagramme einzeln und möchte ein Diagramm über dem anderen haben.

Ich habe versucht, kombinierte Fenster zu verwenden und den Inhalt des eingefügten Diagramms zu kopieren, aber wenn ich mit der Maus über den eingefügten Diagramminhalt fahre, werden die Werte nicht angezeigt. Kann mir jemand bei der Lösung dieses Problems helfen?

 

 

 

Danke schön,

Hanuja

InhaltsorganisationBetreff: Wie kombiniere ich zwei Diagramme? Ich meine, als würde man sie übereinander legen

Hier ist ein Beispiel, das etwas Ihrer Eingabe aus zwei Datentabellen ähnelt, die in einem Diagramm zusammengefasst werden müssen.Sie müssen das Skript studieren und dann die neuen Informationen übernehmen und sie wieder auf Ihre Skripte anwenden.

Hier ist das Skript

Names Default To Here( 1 );
dt = Open( "$sample_data/semiconductor capability.jmp" );

// Create 2 Data tables to mimic the Discussion Question situation
dt1 = dt << subset( columns(Wafer, Site, NPN1), selected rows(0));
dt2 = dt << subset( columns(lot_id, Wafer, Site, NPN2), selected rows(0));

// Select rows wanted from table dt1
dt1 << select where( :wafer <= 10 );
// Create new subset of selected rows
dt1Final = dt1 << subset( selected rows( 1 ), selected columns( 0 ) );

// Select rows wanted from table dt2
dt2 << select where( contains( {"lot01", "lot02"}, :lot_id  ));
// Create new subset of selected rows
dt2Final = dt2 << subset( selected rows( 1 ), selected columns( 0 ) );

// put the data together
dtTogether = dt1Final << concatenate( dt2Final );

gb = Graph Builder(
 Size( 534, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :wafer ), Y( :NPN1 ), Y( :NPN2, Position( 1 ) ) ),
 Elements( Points( X, Y( 1 ), Y( 2 ), Legend( 5 ) ) )
);
theReport = report(gb);

// Create the reference lines
theYColList = { "NPN1", "NPN2" };
For( i = 1, i <= N Items( theYColList ),i++,
 specs = Column( theYColList[i] ) << get property( "spec limits" );
 If( Try( specs["USL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["USL"], "Dashed", black, theYColList[i] || " USL" )
 );
 If( Try( specs["LSL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["LSL"], "Dashed", black, theYColList[i] || " LSL" )
 );
 If( Try( specs["Target"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["Target"], "Dashed", black, theYColList[i] || " Target" )
 );
);

 

 

Betreff: Wie kombiniere ich zwei Diagramme? Ich meine, als würde man sie übereinander legenIst das von mir vorgeschlagene Diagramm eine akzeptable Kombination der beiden Diagramme? Wenn nicht, und Sie die verschiedenen Überlagerungen benötigen, die in Ihren beiden Skripten definiert sind, ist mir keine Möglichkeit bekannt, die Diagramme aus zwei verschiedenen Datentabellen auszuschneiden und einzufügen.Betreff: Wie kombiniere ich zwei Diagramme? Ich meine, als würde man sie übereinander legen

Während es mit Graph Builder einfach ist, Diagramme zu überlagern, gibt es ein Problem bei der Anzeige von Spezifikationsgrenzen, wenn mehr als eine Spalte überlagert wird.Es ist jedoch ein einfacher Vorgang, ein kleines Skript hinzuzufügen, das die Referenzlinien hinzufügt.Hier ist eine Möglichkeit, dies zu tun

Names Default To Here( 1 );
dt = Open( "$sample_data/semiconductor capability.jmp" );

gb = Graph Builder(
 Size( 534, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :wafer ), Y( :NPN1 ), Y( :NPN2, Position( 1 ) ) ),
 Elements( Points( X, Y( 1 ), Y( 2 ), Legend( 8 ) ) )
);



// determine the columns to add limit reference lines from
theReport = Current Report();
theScript = Char( (theReport[Outline Box( 1 )] << get scriptable object) << get script );
theYColList = {};
While( Contains( theScript, "Y(:" ) != 0,
 theScript = Substr( theScript, Contains( theScript, "Y(:" ) + 3 );
 Insert Into( theYColList, Word( 1, theScript, ":)," ) );
);
// Create the reference lines
For( i = 1, i <= N Items( theYColList ),i++,
 specs = Column( theYColList[i] ) << get property( "spec limits" );
 If( Try( specs["USL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["USL"], "Dashed", black, theYColList[i] || " USL" )
 );
 If( Try( specs["LSL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["LSL"], "Dashed", black, theYColList[i] || " LSL" )
 );
 If( Try( specs["Target"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["Target"], "Dashed", black, theYColList[i] || " Target" )
 );
);