391079_fr-FR

liliconcom

comment combiner 2 graphiques je veux dire comme superposer l'un sur l'autre

Bonjour à tous,

 

J'ai deux graphiques individuellement et j'aimerais avoir un graphique sur l'autre.

J'ai essayé d'utiliser des fenêtres combinées et de copier-coller le contenu du cadre, mais lorsque je passe la souris sur le contenu du graphique collé, les valeurs ne s'affichent pas, quelqu'un peut-il m'aider à résoudre ce problème.

 

 

 

Merci,

Hanuja

Organisation du contenuRe: comment combiner 2 graphiques je veux dire comme superposer l'un sur l'autre

Voici un exemple qui ressemble quelque peu à vos 2 entrées de table de données qui doivent être regroupées en un seul tracé.Vous devez étudier le script, puis prendre les nouvelles informations et les réappliquer à vos scripts.

Voici le scénario

Names Default To Here( 1 );
dt = Open( "$sample_data/semiconductor capability.jmp" );

// Create 2 Data tables to mimic the Discussion Question situation
dt1 = dt << subset( columns(Wafer, Site, NPN1), selected rows(0));
dt2 = dt << subset( columns(lot_id, Wafer, Site, NPN2), selected rows(0));

// Select rows wanted from table dt1
dt1 << select where( :wafer <= 10 );
// Create new subset of selected rows
dt1Final = dt1 << subset( selected rows( 1 ), selected columns( 0 ) );

// Select rows wanted from table dt2
dt2 << select where( contains( {"lot01", "lot02"}, :lot_id  ));
// Create new subset of selected rows
dt2Final = dt2 << subset( selected rows( 1 ), selected columns( 0 ) );

// put the data together
dtTogether = dt1Final << concatenate( dt2Final );

gb = Graph Builder(
 Size( 534, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :wafer ), Y( :NPN1 ), Y( :NPN2, Position( 1 ) ) ),
 Elements( Points( X, Y( 1 ), Y( 2 ), Legend( 5 ) ) )
);
theReport = report(gb);

// Create the reference lines
theYColList = { "NPN1", "NPN2" };
For( i = 1, i <= N Items( theYColList ),i++,
 specs = Column( theYColList[i] ) << get property( "spec limits" );
 If( Try( specs["USL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["USL"], "Dashed", black, theYColList[i] || " USL" )
 );
 If( Try( specs["LSL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["LSL"], "Dashed", black, theYColList[i] || " LSL" )
 );
 If( Try( specs["Target"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["Target"], "Dashed", black, theYColList[i] || " Target" )
 );
);

 

 

Re: comment combiner 2 graphiques je veux dire comme superposer l'un sur l'autreLe graphique que j'ai proposé est-il une combinaison acceptable des 2 graphiques ? Si ce n'est pas le cas, et que vous devez avoir les différentes superpositions telles que définies dans vos 2 scripts, je ne connais pas de moyen de couper et coller les graphiques de 2 tables de données différentes.Re: comment combiner 2 graphiques je veux dire comme superposer l'un sur l'autre

Bien qu'il soit facile de superposer des graphiques à l'aide de Graph Builder, l'affichage des limites de spécifications pose un problème lorsque plusieurs colonnes sont superposées.Cependant, c'est un processus simple pour ajouter un petit script qui ajoutera les lignes de référence.Voici une façon de le faire

Names Default To Here( 1 );
dt = Open( "$sample_data/semiconductor capability.jmp" );

gb = Graph Builder(
 Size( 534, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :wafer ), Y( :NPN1 ), Y( :NPN2, Position( 1 ) ) ),
 Elements( Points( X, Y( 1 ), Y( 2 ), Legend( 8 ) ) )
);



// determine the columns to add limit reference lines from
theReport = Current Report();
theScript = Char( (theReport[Outline Box( 1 )] << get scriptable object) << get script );
theYColList = {};
While( Contains( theScript, "Y(:" ) != 0,
 theScript = Substr( theScript, Contains( theScript, "Y(:" ) + 3 );
 Insert Into( theYColList, Word( 1, theScript, ":)," ) );
);
// Create the reference lines
For( i = 1, i <= N Items( theYColList ),i++,
 specs = Column( theYColList[i] ) << get property( "spec limits" );
 If( Try( specs["USL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["USL"], "Dashed", black, theYColList[i] || " USL" )
 );
 If( Try( specs["LSL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["LSL"], "Dashed", black, theYColList[i] || " LSL" )
 );
 If( Try( specs["Target"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["Target"], "Dashed", black, theYColList[i] || " Target" )
 );
);