391079_es-ES

liliconcom

cómo combinar 2 gráficos, quiero decir, como superponer uno sobre el otro

Hola a todos,

 

Tengo dos gráficos individualmente y me gustaría tener un gráfico en el otro.

Intenté usar ventanas combinadas y copiar el contenido del marco de pegado, pero cuando coloco el mouse sobre el contenido del gráfico pegado, los valores no aparecen, ¿alguien puede ayudarme a resolver esto?

 

 

 

Gracias,

Hanuja

GráficosRe: como combinar 2 graficos me refiero como superponer uno sobre el otro

Si bien es fácil superponer gráficos con Graph Builder, existe un problema con la visualización de los límites de especificación cuando hay más de una columna sobrepasada.Sin embargo, es un proceso simple agregar un pequeño script que agregará las líneas de referencia.Aquí hay una forma de hacerlo.

Names Default To Here( 1 );
dt = Open( "$sample_data/semiconductor capability.jmp" );

gb = Graph Builder(
 Size( 534, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :wafer ), Y( :NPN1 ), Y( :NPN2, Position( 1 ) ) ),
 Elements( Points( X, Y( 1 ), Y( 2 ), Legend( 8 ) ) )
);



// determine the columns to add limit reference lines from
theReport = Current Report();
theScript = Char( (theReport[Outline Box( 1 )] << get scriptable object) << get script );
theYColList = {};
While( Contains( theScript, "Y(:" ) != 0,
 theScript = Substr( theScript, Contains( theScript, "Y(:" ) + 3 );
 Insert Into( theYColList, Word( 1, theScript, ":)," ) );
);
// Create the reference lines
For( i = 1, i <= N Items( theYColList ),i++,
 specs = Column( theYColList[i] ) << get property( "spec limits" );
 If( Try( specs["USL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["USL"], "Dashed", black, theYColList[i] || " USL" )
 );
 If( Try( specs["LSL"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["LSL"], "Dashed", black, theYColList[i] || " LSL" )
 );
 If( Try( specs["Target"], "" ) != "",
  theReport[AxisBox( 2 )] << Add Ref Line( specs["Target"], "Dashed", black, theYColList[i] || " Target" )
 );
);

Re: como combinar 2 graficos me refiero como superponer uno sobre el otro¿El gráfico que propuse es una combinación aceptable de los 2 gráficos? Si no es así, y necesita tener las diferentes superposiciones definidas en sus 2 scripts, entonces no conozco una forma de cortar y pegar los gráficos de 2 tablas de datos diferentes.