389341_zh-TW

liliconcom

有關 If 語句的幫助

我目前正在嘗試編寫一個腳本，該腳本從資料表中讀取一列，並根據該列的值運行一組不同的函數。例如，

如果 A 列中的資料 = A，則建立名為「A」的新欄位並執行下面的函數（A 到 C）。

如果 A 列中的資料 = B，則建立名為「B」的新欄位並執行下面的函數（D 到 F）。

否則，建立一個名為“N/A”的新欄位。

當我運行腳本時，即使值為“A”或“B”，它也始終會建立新列“N/A”。它也不會運行我為“A”和“B”條件編寫的任何函數。我覺得我錯過了一些非常明顯的東西。

dt = Current Data Table();
If(
:Column A == "A", dt << New Column( "A", character, nominal ),
Function A
Function B
Function C

:Column B == "B", dt << New Column( "B", character, nominal ),
Function D
Function E
Function F

dt << New Column( "N/A", character, nominal )
)

自動化和腳本編寫消費者與市場研究資料混合與清理大規模客製化品質和工藝工程回复：幫助 If 語句

關於更改列名的要點。 這使得為後續處理編寫 JSL 變得更加困難。 可能您希望所有案例都使用相同的列名，例如“狀態”或“操作類型”。

 

回复：幫助 If 語句

給定您指定的場景，下面的腳本會生成 3 個案例

A 存在於 A 列中

B 存在於 B 列中

A 或 B 都不存在

Names Default To Here( 1 );

A = Function( {},
 Show( "Function A" )
);
B = Function( {},
 Show( "Function B" )
);
C = Function( {},
 Show( "Function C" )
);
D = Function( {},
 Show( "Function D" )
);
EE = Function( {},
 Show( "Function EE" )
);
F = Function( {},
 Show( "Function F" )
);

// First Example Column A has the value A
dt1 = New Table( "Example1",
 Add Rows( 1 ),
 New Column( "Column A", Character, "Nominal", Set Values( {"A"} ) ),
 New Column( "Column B", Character, "Nominal", Set Values( {""} ) )
);
Wait( 5 );

If(
 :Column A[1] == "A",
  dt1 << New Column( "A", character, nominal );
  A();
  B();
  C();,
 :Column B[1] == "B", dt1 << New Column( "B", character, nominal );
  D();
  EE();
  F();
 , 
 dt1 << New Column( "N/A", character, nominal )
);


// Second Example Column B has the value B
dt2 = New Table( "Example2",
 Add Rows( 1 ),
 New Column( "Column A", Character, "Nominal", Set Values( {""} ) ),
 New Column( "Column B", Character, "Nominal", Set Values( {"B"} ) )
);
Wait( 5 );

If(
 :Column A[1] == "A",
  dt2 << New Column( "A", character, nominal );
  A();
  B();
  C();,
 :Column B[1] == "B", dt2 << New Column( "B", character, nominal );
  D();
  EE();
  F();
 , 
 dt2 << New Column( "N/A", character, nominal )
);


// Third Example Neither column A has and A nor Column B has a B
dt3 = New Table( "Example3",
 Add Rows( 1 ),
 New Column( "Column A", Character, "Nominal", Set Values( {""} ) ),
 New Column( "Column B", Character, "Nominal", Set Values( {""} ) )
);
Wait( 5 );

If(
 dt3:Column A[1] == "A",
  dt3 << New Column( "A", character, nominal );
  A();
  B();
  C();,
 dt3:Column B[1] == "B", dt3 << New Column( "B", character, nominal );
  D();
  EE();
  F();
 , 
 dt3 << New Column( "N/A", character, nominal )
);

這是我的猜測，這不是你想要的

回复：幫助 If 語句

如果秘密可能有幫助。 逗號分隔條款在 if 語句中。 分號分隔語句內一個條款。

你可能想要這樣的東西

 

dt = Current Data Table();
If( :Column A == "A", // condition, followed by a comma
     dt << New Column( "A", character, nominal ); // one or more stmts
     Function A(); // with ; separators
     Function B();
     Function C(); // last statement has optional ; and required comma next line
, /* else if */ :Column B == "B", // 2nd condition followed by comma
     dt << New Column( "B", character, nominal );
     Function D();
     Function E();
     Function F() // again, another comma. ; omitted for example...I prefer to use them
, /* else */ 
     dt << New Column( "N/A", character, nominal ) // no more commas, this is the otherwise
);

我喜歡縮進和註釋 /* else if */ 和 /* else */ 以便於理解。