389341_zh-CN

liliconcom

有关 If 语句的帮助

我目前正在尝试编写一个脚本，从我的数据表中读取一列，并根据该列的值运行一组不同的函数。例如，

如果 A 列中的数据 = A，则创建一个名为“A”的新列并运行下面的函数（A 到 C）。

如果 A 列中的数据 = B，则创建一个名为“B”的新列并运行下面的函数（D 到 F）。

否则，创建一个名为“N/A”的新列。

当我运行脚本时，即使值为“A”或“B”，它也会始终创建新列“N/A”。它也不会运行我为“A”和“B”条件编写的任何函数。我觉得我忽略了一些非常明显的东西。

dt = Current Data Table();
If(
:Column A == "A", dt << New Column( "A", character, nominal ),
Function A
Function B
Function C

:Column B == "B", dt << New Column( "B", character, nominal ),
Function D
Function E
Function F

dt << New Column( "N/A", character, nominal )
)

自动化和脚本消费者和市场研究数据混合和清理大规模定制质量与工艺工程回复：帮助 If 语句

关于更改列名的要点。 这使得为后续处理编写 JSL 变得更加困难。 可能您希望所有案例都使用相同的列名，例如“状态”或“操作类型”。

 

回复：帮助 If 语句

给定您指定的场景，下面的脚本会生成 3 个案例

A 存在于 A 列中

B 存在于 B 列中

A 或 B 都不存在

Names Default To Here( 1 );

A = Function( {},
 Show( "Function A" )
);
B = Function( {},
 Show( "Function B" )
);
C = Function( {},
 Show( "Function C" )
);
D = Function( {},
 Show( "Function D" )
);
EE = Function( {},
 Show( "Function EE" )
);
F = Function( {},
 Show( "Function F" )
);

// First Example Column A has the value A
dt1 = New Table( "Example1",
 Add Rows( 1 ),
 New Column( "Column A", Character, "Nominal", Set Values( {"A"} ) ),
 New Column( "Column B", Character, "Nominal", Set Values( {""} ) )
);
Wait( 5 );

If(
 :Column A[1] == "A",
  dt1 << New Column( "A", character, nominal );
  A();
  B();
  C();,
 :Column B[1] == "B", dt1 << New Column( "B", character, nominal );
  D();
  EE();
  F();
 , 
 dt1 << New Column( "N/A", character, nominal )
);


// Second Example Column B has the value B
dt2 = New Table( "Example2",
 Add Rows( 1 ),
 New Column( "Column A", Character, "Nominal", Set Values( {""} ) ),
 New Column( "Column B", Character, "Nominal", Set Values( {"B"} ) )
);
Wait( 5 );

If(
 :Column A[1] == "A",
  dt2 << New Column( "A", character, nominal );
  A();
  B();
  C();,
 :Column B[1] == "B", dt2 << New Column( "B", character, nominal );
  D();
  EE();
  F();
 , 
 dt2 << New Column( "N/A", character, nominal )
);


// Third Example Neither column A has and A nor Column B has a B
dt3 = New Table( "Example3",
 Add Rows( 1 ),
 New Column( "Column A", Character, "Nominal", Set Values( {""} ) ),
 New Column( "Column B", Character, "Nominal", Set Values( {""} ) )
);
Wait( 5 );

If(
 dt3:Column A[1] == "A",
  dt3 << New Column( "A", character, nominal );
  A();
  B();
  C();,
 dt3:Column B[1] == "B", dt3 << New Column( "B", character, nominal );
  D();
  EE();
  F();
 , 
 dt3 << New Column( "N/A", character, nominal )
);

这是我的猜测，这不是你想要的

回复：帮助 If 语句

如果秘密可能有帮助。 逗号分隔条款在 if 语句中。 分号分隔语句内一个条款。

你可能想要这样的东西

 

dt = Current Data Table();
If( :Column A == "A", // condition, followed by a comma
     dt << New Column( "A", character, nominal ); // one or more stmts
     Function A(); // with ; separators
     Function B();
     Function C(); // last statement has optional ; and required comma next line
, /* else if */ :Column B == "B", // 2nd condition followed by comma
     dt << New Column( "B", character, nominal );
     Function D();
     Function E();
     Function F() // again, another comma. ; omitted for example...I prefer to use them
, /* else */ 
     dt << New Column( "N/A", character, nominal ) // no more commas, this is the otherwise
);

我喜欢缩进和注释 /* else if */ 和 /* else */ 以便于理解。