389341_ja-JP

liliconcom

If ステートメントのヘルプ

現在、データ テーブルから列を読み取り、その列の値に応じて異なる関数セットを実行するスクリプトを作成しようとしています。たとえば、

列 A のデータ = A の場合、「A」という名前の新しい列を作成し、以下の関数 (A ～ C) を実行します。

列 A = B のデータの場合、「B」という名前の新しい列を作成し、代わりに以下の関数 (D ～ F) を実行します。

それ以外の場合は、「N/A」という新しい列を作成します。

スクリプトを実行すると、値が「A」または「B」であっても、常に新しい列「N/A」が作成されます。また、「A」および「B」条件用に作成した関数も実行されません。非常に明白な何かが欠けているように感じます。

dt = Current Data Table();
If(
:Column A == "A", dt << New Column( "A", character, nominal ),
Function A
Function B
Function C

:Column B == "B", dt << New Column( "B", character, nominal ),
Function D
Function E
Function F

dt << New Column( "N/A", character, nominal )
)

自動化とスクリプト作成消費者および市場調査データのブレンディングとクリーンアップマスカスタマイゼーション品質およびプロセスエンジニアリングRe：Ifステートメントのヘルプ

列名の変更についての良い点。 後続の処理のためにJSLを作成するのが難しくなります。 おそらく、「ステータス」や「アクションタイプ」など、すべてのケースで同じ列名が必要です。

 

Re：Ifステートメントのヘルプ

指定したシナリオを前提として、以下のスクリプトは3つのケースを生成します

Aは列Aに存在します

Bは列Bに存在します

AもBも存在しません

Names Default To Here( 1 );

A = Function( {},
 Show( "Function A" )
);
B = Function( {},
 Show( "Function B" )
);
C = Function( {},
 Show( "Function C" )
);
D = Function( {},
 Show( "Function D" )
);
EE = Function( {},
 Show( "Function EE" )
);
F = Function( {},
 Show( "Function F" )
);

// First Example Column A has the value A
dt1 = New Table( "Example1",
 Add Rows( 1 ),
 New Column( "Column A", Character, "Nominal", Set Values( {"A"} ) ),
 New Column( "Column B", Character, "Nominal", Set Values( {""} ) )
);
Wait( 5 );

If(
 :Column A[1] == "A",
  dt1 << New Column( "A", character, nominal );
  A();
  B();
  C();,
 :Column B[1] == "B", dt1 << New Column( "B", character, nominal );
  D();
  EE();
  F();
 , 
 dt1 << New Column( "N/A", character, nominal )
);


// Second Example Column B has the value B
dt2 = New Table( "Example2",
 Add Rows( 1 ),
 New Column( "Column A", Character, "Nominal", Set Values( {""} ) ),
 New Column( "Column B", Character, "Nominal", Set Values( {"B"} ) )
);
Wait( 5 );

If(
 :Column A[1] == "A",
  dt2 << New Column( "A", character, nominal );
  A();
  B();
  C();,
 :Column B[1] == "B", dt2 << New Column( "B", character, nominal );
  D();
  EE();
  F();
 , 
 dt2 << New Column( "N/A", character, nominal )
);


// Third Example Neither column A has and A nor Column B has a B
dt3 = New Table( "Example3",
 Add Rows( 1 ),
 New Column( "Column A", Character, "Nominal", Set Values( {""} ) ),
 New Column( "Column B", Character, "Nominal", Set Values( {""} ) )
);
Wait( 5 );

If(
 dt3:Column A[1] == "A",
  dt3 << New Column( "A", character, nominal );
  A();
  B();
  C();,
 dt3:Column B[1] == "B", dt3 << New Column( "B", character, nominal );
  D();
  EE();
  F();
 , 
 dt3 << New Column( "N/A", character, nominal )
);

これはあなたが望むものではないというのは私の推測です

Re：Ifステートメントのヘルプ

秘密なら役立つかもしれません。 カンマは条項ifステートメントで。 セミコロンで区切るステートメント内部条項。

あなたはおそらくこのようなものが欲しいでしょう

 

dt = Current Data Table();
If( :Column A == "A", // condition, followed by a comma
     dt << New Column( "A", character, nominal ); // one or more stmts
     Function A(); // with ; separators
     Function B();
     Function C(); // last statement has optional ; and required comma next line
, /* else if */ :Column B == "B", // 2nd condition followed by comma
     dt << New Column( "B", character, nominal );
     Function D();
     Function E();
     Function F() // again, another comma. ; omitted for example...I prefer to use them
, /* else */ 
     dt << New Column( "N/A", character, nominal ) // no more commas, this is the otherwise
);

/ * else if*/と/*else * /をインデントしてコメントし、わかりやすくするのが好きです。