JSL을 사용하여 행과 열로 데이터 테이블의 일부 업데이트안녕하세요, 죄송합니다. 지금 몇 시간 동안 Google 검색을 하고 있는데 어떻게 해야 할지 모르겠습니다. 나는 최선을 다해 질문을 공식화하는 방법을 모르겠습니다. 정말 짜증이 나고 지금 저에게 다가오고 있습니다. 마지막으로 어떻게 그렇게 단순한 것이 그렇게 복잡할 수 있는지. 결국 JMP는 어떤 목적을 위한 것이지 다른 목적을 위한 것은 아닙니다. 파이썬에서 이것은 나에게 매우 쉬울 것입니다. 그러나 모든 것은 경험에 관한 것이라고 생각합니다. 부상에 모욕을 더하지 마십시오.
내 데이터 테이블의 하위 집합을 새 데이터로 바꾸고 싶습니다. 대상 행과 대상 열, 이전 테이블과 새 데이터가 있습니다. 이를 수행하는 구문은 무엇입니까?
감사합니다.
남자 이름
고급 통계 모델링자동화 및 스크립팅소비자 및 시장 조사데이터 접근데이터 혼합 및 정리대량 맞춤화Re: JSL을 사용하여 행과 열로 데이터 테이블의 일부 업데이트안녕 마이클,
테이블 작업에 일반적으로 사용되는 구문을 설명하기 위해 몇 달 전에 작성한 스크립트를 첨부했습니다. 확인할 때 로그를 켜서 결과를 보고 한 번에 한 줄씩 실행하십시오. 이전에 실행한 코드에 의존하는 일을 가끔 하기 때문에 순서가 어긋나면 제대로 작동하지 않을 수 있습니다.
특정 경우에 첨자를 사용하여 테이블 내용을 바꿀 수 있습니다... 이 스크립트를 살펴보고 한 줄씩 실행합니다.
names default to here(1);
//create a 10x10 table of random integers between 1 and 20
dt = As Table( J( 10, 10, Random Integer( 1, 20 ) ) );
//replace column 1 with fibonacci numbers... note 0th row means ALL rows
//note that ` is the transpose operator.
dt[0, 1] = (Round( 1 / Sqrt( 5 ) * ((1 + Sqrt( 5 )) / 2) ^ (1 :: 10) ))` ;
//replace a subbloc of the table with numbers 81-100 in a 4x5 shape
dt[3::6, 4::8] = shape(81::100, 4);
//set a subbloc to all zeros
dt[8::10, 2::4] = 0;
//store a cell's value in a variable
x = dt[2,3];
//store a subbloc in a matrix
mat = dt[4::6, 0];
//set the whole table to missing
dt[0,0] = .;
Re: JSL을 사용하여 행과 열로 데이터 테이블의 일부 업데이트다음은 한 테이블의 데이터를 다른 테이블의 값으로 업데이트하는 3가지 방법입니다.
Names Default To Here( 1 );
// Open Data Table: big class.jmp
// → Data Table( "big class" )
Open( "$SAMPLE_DATA/big class.jmp" );
// Create a table with values to be input
// into the big class table
New Table( "Using Update",
New Column( "Name", character, values( {"JANE", "TIM", "ALICE"} ) ),
New Column( "Height", values( {58, 69, 64} ) ),
New Column( "Weight", values( {88, 100, 120} ) )
);
// Wait for a short time to be able to see the two
// data tables before combining them
Wait( 5 );
// Update data tables
Data Table( "big class" ) << Update( With( Data Table( "Using Update" ) ), Match Columns( :name = :Name ) );
// Update a block of data into the data table
// Create a table to get values from
New Table( "Just Data",
New Column( "A", values( {100, 101, 102, 103} ) ),
New Column( "B", values( {90, 91, 92, 93} ) )
);
// Wait for a short time to be able to see the two
// data tables before combining them
Wait( 5 );
dt = Data Table( "big class" );
dt2 = Data Table( "Just Data" );
dt[3 :: 6, 4 :: 5] = dt2[1 :: 4, 1 :: 2];
// One last simple way to move data
dt:age[2] = dt2:a[4];
