382744_es-ES

liliconcom

Extraer pendiente de Fit Special

Tengo dos variables X e Y que ajusté una línea con la intersección y restringida a 0.

Necesito el valor de la pendiente de esta línea para un cálculo posterior.

¿Hay alguna forma de guardar este valor de pendiente en una columna para que pueda usarlo para el cálculo posterior?

Bivariado (
Y (: Y),
X (: X),
Ajuste especial (intercepción (0),

Tabla de datosScriptingRe: Extraer pendiente de Fit Special

Si solo está tratando de encontrar los coeficientes mientras trabaja de forma interactiva, puede buscar en la tabla 'Estimaciones de parámetros' dentro de la plataforma de ajuste Bivariante.Si desea sacar esto con un script, hay algunas opciones, una es convertir esa tabla de Estimaciones de parámetros en una tabla de datos y obtenerla desde allí:

 

 

Names Default To Here( 1 );

//Sample data
dt = Open("$Sample_data/iris.jmp");

//Fit line
bv = dt << Bivariate(
 Y( :Sepal length ),
 X( :Sepal width ),
 Fit Special( Intercept( 0 ), {Line Color( {212, 73, 88} )} )
);
Wait( 0 );

//Save estimates to a table
dtEstimates = Report( bv )[Outline Box( "Bivariate Fit of Sepal length By Sepal width" )][
Outline Box( "Linear Fit" )][Outline Box( "Parameter Estimates" )][Table Box( 1 )]
 << Make Into Data Table;
 
// Pull estimate out of data table
dtEstimates:Estimate[dtEstimates << Get Rows Where(:Term == "Sepal width")][1];

// Clean up
// Report( bv ) << Close Window;
// dtEstimates << Close Window;