379518_zh-TW

liliconcom

JSL總和更改列

您好，如果我有一個有時會更改的表，例如：

 

但又有一天可能是這樣的：

我想以某種方式創建一個新行，該行將對除“日期”和“數據”之外的所有列求和

在JSL中做到這一點的最佳方法是什麼？

我嘗試獲取列名稱，然後刪除數據和日期，但是我不確定如何對每一列進行求和

我嘗試使用摘要，但是每次更改時，一次將是a，b，r，x和一次a，c，f的總和，因此我不確定這是可能的。

Summary(
 Sum( :A ),
 Sum( :B ),
 Sum( :R ),
 Sum( :X ),
 Freq( "None" ),
 Weight( "None" )
)

Summary(
 Sum( :A ),
 Sum( :C ),
 Sum( :F ),
 Freq( "None" ),
 Weight( "None" )
)

腳本編寫回复：JSL總和更改列

也許您可以使用與此處類似的想法：

如何在不指定列名的情況下創建一列col的摘要？

 

Names Default To Here(1);
dt1 = New Table("Untitled1",
 Add Rows(3),
 Compress File When Saved(1),
 New Column("data", Character, "Nominal", Set Values({"a", "b", "c"})),
 New Column("date", Numeric, "Continuous", Format("Best", 12), Set Values([2021, 2021, 2021])),
 New Column("a", Numeric, "Continuous", Format("Best", 12), Set Values([0, 50, 2])),
 New Column("c", Numeric, "Continuous", Format("Best", 12), Set Values([1, 0, 0])),
 New Column("f", Numeric, "Continuous", Format("Best", 12), Set Values([0, 0, 7]))
);
colname = dt1 << get column names(string);
colname = Substr(colname, 3); //remove data and date columns from list
summary_dt1 = dt1 << Summary(Sum(Eval(colname)), Freq("None"), Weight("None"));
summary_dt1 << Delete Columns("N Rows");

dt2 = New Table("Untitled2",
 Add Rows(3),
 Compress File When Saved(1),
 New Column("data", Character, "Nominal", Set Values({"a", "b", "c"})),
 New Column("date", Numeric, "Continuous", Format("Best", 12), Set Values([2021, 2021, 2021])),
 New Column("a", Numeric, "Continuous", Format("Best", 12), Set Values([0, 50, 2])),
 New Column("b", Numeric, "Continuous", Format("Best", 12), Set Values([1, 0, 0])),
 New Column("r", Numeric, "Continuous", Format("Best", 12), Set Values([0, 0, 7])),
 New Column("x", Numeric, "Continuous", Format("Best", 12), Set Values([2, 7, 1]))
);
colname = dt2 << get column names(string);
colname = Substr(colname, 3); //remove data and date columns from list
summary_dt2 = dt2 << Summary(Sum(Eval(colname)), Freq("None"), Weight("None"));
summary_dt2 << Delete Columns("N Rows");

回复：JSL總和更改列

@jthi提供了正確的答案。我做了一點修改，發現在我編寫的許多腳本中都非常有用。

我發現在大多數情況下，我要使用的數據表從一次訪問到接下來的幾周訪問都不會遵循相同的列順序。因此，當我需要配對要匯總的列列表時，等等。 我使用以下代碼。

colNamesNotToUse = {"DATA", "DATE"};
colname = dt << get column names( string );

For( i = N Items( colName ), i >= 1, i--,
 If( Contains( colNamesNotToUse, Uppercase( colName[i] ) ),
  Remove From( colName, i, 1 )
 )
);