378002_es-ES

liliconcom

¿Cómo hago un script para cambiar el nombre de mis columnas, fechas actuales, a solo el día?

quiero cambiar sólo las columnas numéricas continuas en mi hoja que actualmente son fechas completas y están en orden del 1 al 31 hasta solo el día

ex 03/01/2020 al 1

02/03/2020 hasta 2

 

También me gustaría agregar una columna a mi hoja con el nombre de Abbv del mes.

 

Gracias por adelantado

Tabla de datosScriptingRe: ¿Cómo hago un script para cambiar el nombre de mis columnas, fechas actuales, a solo el día?

Podrías hacerlo así:

 

Names Default To Here( 1 );

dt = New Table( "Dates",
 New Column( "date", "Numeric", "Continuous", Format( "Date Abbrev", 20 ), set values( Date DMY( Index( 1, 31 ), 3, 2020 ) ) )
);
Wait( 3 );

dt << New Column( "Day", Formula( Day( :date ) ) );
dt:date << hide();
dt << New Column( "Month",
 Formula(
  Match( Month( :date ),
   1, "Jan",
   2, "Feb",
   3, "Mar",
   4, "Apr",
   5, "May",
   6, "Jun",
   7, "Jul",
   8, "Aug",
   9, "Sep",
   10, "Oct",
   11, "Nov",
   12, "Dec"
  )
 )
);

Re: ¿Cómo hago un script para cambiar el nombre de mis columnas, fechas actuales, a solo el día?

Así es como resolvería su solicitud.

Names Default To Here( 1 );
dt = Current Data Table();

theMonth=.;
For( i = 1, i <= N Cols( dt ), i++,
 If( Substr( Column( dt, i ) << get name, 1, 2 ) == "N(",
  If( isMissing(theMonth) == 1,
   theMonth = Month( Informat( Word( 2, Column( dt, i ) << get name, "()" ), "m/d/y" ) );
  );
  Column( dt, i ) << set name(
   Char( Day( Informat( Word( 2, Column( dt, i ) << get name, "()" ), "m/d/y" ) ) )
  )
 )
);

monthList = {"Jan","Feb","Mar","Apr","May","Jun",
 "Jul","Aug","Sep","Oct","Nov","Dec"
};
dt << New Column( monthList[theMonth]);