378002_fr-FR

liliconcom

Comment puis-je écrire pour changer le nom de mes colonnes, actuellement les dates, en juste le jour?

je veux changer juste les colonnes numériques continues dans ma feuille qui sont actuellement des dates complètes et sont dans l'ordre du 1er au 31e au jour juste

ex 03/01/2020 au 1

03/02/2020 au 2

 

Je voudrais également ajouter une colonne à ma feuille avec le nom Abbv du mois.

 

Merci d'avance

Tableau de donnéesScriptingRe: Comment puis-je écrire pour changer le nom de mes colonnes, actuellement les dates, en juste le jour?

Vous pouvez le faire comme ceci:

 

Names Default To Here( 1 );

dt = New Table( "Dates",
 New Column( "date", "Numeric", "Continuous", Format( "Date Abbrev", 20 ), set values( Date DMY( Index( 1, 31 ), 3, 2020 ) ) )
);
Wait( 3 );

dt << New Column( "Day", Formula( Day( :date ) ) );
dt:date << hide();
dt << New Column( "Month",
 Formula(
  Match( Month( :date ),
   1, "Jan",
   2, "Feb",
   3, "Mar",
   4, "Apr",
   5, "May",
   6, "Jun",
   7, "Jul",
   8, "Aug",
   9, "Sep",
   10, "Oct",
   11, "Nov",
   12, "Dec"
  )
 )
);

Re: Comment puis-je écrire pour changer le nom de mes colonnes, actuellement les dates, en juste le jour?

Voici comment je résoudrais votre demande

Names Default To Here( 1 );
dt = Current Data Table();

theMonth=.;
For( i = 1, i <= N Cols( dt ), i++,
 If( Substr( Column( dt, i ) << get name, 1, 2 ) == "N(",
  If( isMissing(theMonth) == 1,
   theMonth = Month( Informat( Word( 2, Column( dt, i ) << get name, "()" ), "m/d/y" ) );
  );
  Column( dt, i ) << set name(
   Char( Day( Informat( Word( 2, Column( dt, i ) << get name, "()" ), "m/d/y" ) ) )
  )
 )
);

monthList = {"Jan","Feb","Mar","Apr","May","Jun",
 "Jul","Aug","Sep","Oct","Nov","Dec"
};
dt << New Column( monthList[theMonth]);