378002_de-DE

liliconcom

Wie ändere ich den Namen meiner Spalten, derzeit Daten, in nur den Tag?

Ich will es verändern Nur die fortlaufenden numerischen Spalten in meinem Blatt, die derzeit vollständige Daten sind und vom 1. bis zum 31. bis zum Tag geordnet sind

ab 01.03.2020 bis 1

02.03.2020 bis 2

 

Ich möchte meinem Blatt auch eine Spalte mit dem Abbv-Namen des Monats hinzufügen.

 

Danke im Voraus

DatentabelleSkripterstellungBetreff: Wie ändere ich den Namen meiner Spalten, derzeit Daten, in nur den Tag?Danke Jim, das ist großartig.Betreff: Wie ändere ich den Namen meiner Spalten, derzeit Daten, in nur den Tag?

So würde ich Ihre Anfrage lösen

Names Default To Here( 1 );
dt = Current Data Table();

theMonth=.;
For( i = 1, i <= N Cols( dt ), i++,
 If( Substr( Column( dt, i ) << get name, 1, 2 ) == "N(",
  If( isMissing(theMonth) == 1,
   theMonth = Month( Informat( Word( 2, Column( dt, i ) << get name, "()" ), "m/d/y" ) );
  );
  Column( dt, i ) << set name(
   Char( Day( Informat( Word( 2, Column( dt, i ) << get name, "()" ), "m/d/y" ) ) )
  )
 )
);

monthList = {"Jan","Feb","Mar","Apr","May","Jun",
 "Jul","Aug","Sep","Oct","Nov","Dec"
};
dt << New Column( monthList[theMonth]);

Betreff: Wie ändere ich den Namen meiner Spalten, derzeit Daten, in nur den Tag?

Du könntest es so machen:

 

Names Default To Here( 1 );

dt = New Table( "Dates",
 New Column( "date", "Numeric", "Continuous", Format( "Date Abbrev", 20 ), set values( Date DMY( Index( 1, 31 ), 3, 2020 ) ) )
);
Wait( 3 );

dt << New Column( "Day", Formula( Day( :date ) ) );
dt:date << hide();
dt << New Column( "Month",
 Formula(
  Match( Month( :date ),
   1, "Jan",
   2, "Feb",
   3, "Mar",
   4, "Apr",
   5, "May",
   6, "Jun",
   7, "Jul",
   8, "Aug",
   9, "Sep",
   10, "Oct",
   11, "Nov",
   12, "Dec"
  )
 )
);