376292_zh-TW

liliconcom

GraphBuilder - 透過 JSL 自訂/重新排序段

在 GraphBuilder 中，當多個元件加入到同一個圖表時，某些元件會被隱藏或被推到其他元件後面並且不太可見。

下面的線段位於條形段後面。  

 

在圖表上，可以選擇右鍵 > 使用向上/向下箭頭自訂和重新排序元件，並將條形段傳送到後面。

 

 

我找到了一種在 JMP16 中編寫腳本的方法（完整程式碼如下），但相同的解決方案在 JMP15 中失敗。

JMP15 有等效的解法嗎？

 

gbFB1 = report(gb)[Framebox(1)];
gbFB1 << Reorder Segs({1, 2, 5});

 

 

謝謝

射線

 

要重新建立的完整 JSL 程式碼：

 

dt_sampledata = New Table( "Exampe Data",
 Add Rows( 24 ),
 New Column( "Month",
  Numeric,
  "Ordinal",
  Format( "Best", 12 ),
  Set Values(
   [202101, 202101, 202101, 202101, 202102, 202102, 202102, 202102, 202103,
   202103, 202103, 202103, 202104, 202104, 202104, 202104, 202105, 202105,
   202105, 202105, 202106, 202106, 202106, 202106]
  )
 ),
 New Column( "Product",
  Character( 16 ),
  "Nominal",
  Set Values(
   {"ProductA", "ProductB", "ProductC", "ProductD", "ProductA", "ProductB",
   "ProductC", "ProductD", "ProductA", "ProductB", "ProductC", "ProductD",
   "ProductA", "ProductB", "ProductC", "ProductD", "ProductA", "ProductB",
   "ProductC", "ProductD", "ProductA", "ProductB", "ProductC", "ProductD"}
  )
 ),
 New Column( "Volume",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values(
   [3869, 4964, 3188, 3109, 2623, 3447, 3179, 1038, 1781, 3195, 1621, 2034,
   3231, 1390, 3187, 1998, 3280, 3570, 4443, 2150, 1638, 4083, 4242, 1186]
  )
 ),
 New Column( "Chem_A",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values(
   [5, 19, 45, 36, 35, 42, 28, 46, 33, 43, 19, 5, 11, 14, 47, 21, 5, 8, 33,
   32, 7, 6, 9, 33]
  )
 ),
 New Column( "Chem_B",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values(
   [64, 38, 90, 41, 69, 70, 79, 75, 79, 59, 25, 71, 64, 65, 62, 51, 88, 79,
   41, 47, 22, 62, 57, 38]
  )
 )
);

// Graph Builder
gb = dt_sampledata << Graph Builder(
 Size( 1040, 562 ),
 Variables(
  X( :Month ),
  Y( :Volume, Side( "Right" ) ),
  Y( :Chem_A, Position( 1 ) ),
  Y( :Chem_B, Position( 1 ) ),
  Overlay( :Product )
 ),
 Elements(
  Line( X, Y( 2 ), Y( 3 ), Overlay( 0 ), Legend( 12 ) ),
  Bar( X, Y( 1 ), Legend( 11 ), Bar Style( "Stacked" ) )
 ),
 SendToReport(
  Dispatch(
   {},
   "400",
   LegendBox,
   {Legend Position( {12, [4, 5], 11, [0, 1, 2, 3]} )}
  )
 )
);<BR />gbFB1 = report(gb)[Framebox(1)];<BR /><BR />gbFB1 << Reorder Segs({1, 2, 5});<BR />

 

 

大規模客製化回覆：GraphBuilder - 透過 JSL 自訂/重新排序段非常感謝！
它比 JMP16 多一點，但仍然相對簡短和整潔。
而且，對我來說額外的好處是您的解決方案還提供了有關如何解析和搜尋 JSL GB 腳本的介紹。回覆：GraphBuilder - 透過 JSL 自訂/重新排序段

在 Graph Builder 的 JSL 表示中，「段」的順序似乎是由它們出現在元素()爭論。

以下是有關如何在 JMP15 中使用 JSL 對元素重新排序的想法。 它假設您的 dt_sampledata 是當前資料表。

// Graph Builder
gb = Graph Builder(
 Size( 1040, 562 ),
 Variables(
  X( :Month ),
  Y( :Volume, Side( "Right" ) ),
  Y( :Chem_A, Position( 1 ) ),
  Y( :Chem_B, Position( 1 ) ),
  Overlay( :Product )
 ),
 Elements(
  Line( X, Y( 2 ), Y( 3 ), Overlay( 0 ), Legend( 12 ) ),
  Bar( X, Y( 1 ), Legend( 11 ), Bar Style( "Stacked" ) )
 )
);
Wait( 2 );
gbexpr = gb << get script;
// Find the position of the Elements() argument
i = 1;
While( Head( Arg( gbexpr, i ) ) != Expr( Elements ), i++ );
// Move forward the most background element to front
n = N Arg( Arg( gbexpr, i ) );
reordered_elem = Eval Expr( Elements( Expr( Arg( gbexpr, {i, n} ) ), Expr( Arg( gbexpr, {i, 1} ) ) ) );
// Replace old Elements() with the new re-ordered elements
Substitute Into( gbexpr, Arg( gbexpr, i ), Name Expr( reordered_elem ) );
// Replace the graph builder
gb << close window;
Eval( gbexpr );