369867_zh-CN

liliconcom

计数规格内的行的功能

我想创建一个读取列的函数，检查每行中的数字是否在规格范围内，并输出通过计数/总计数/百分比。

 

这就是我所拥有的：

count_in_spec = Function( { col, lsl, usl },
 a=0; //pass count
 b=0; //all count
 for( i = 1, i <= N Rows(col), i++,
  if( col[i] >= lsl & col[i] <= usl, a++ );
  if( not(ismissing(col[i])), b++ );
 );
 pctpass = 100*a/b;
 pctfail = 100 - pctpass;
 
 evallist({a, b, pctpass, pctfail});
);


dt0 = current data table();
colp = dt0:name("param") << get as matrix;

results = count_in_spec(colp, 0.15, 0.30 );
 countpass = results[1];
 countall = results[2];
 pctpass = results[3];
 pctfail = results[4];

虽然这样做有效，但我不喜欢需要使用“作为矩阵获取”这一事实。 这有点笨拙。

 

我想要一个简单地通过编写即可工作的函数：

结果= count_in_spec（“参数名称”，lsl，usl）;

 

我将如何修改我的功能，使其以这种方式工作？

脚本编写回复：对规格内的行进行计数的功能

使用Get Rows Where（）函数应该可以得到想要的结果

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

count_in_spec = Function( {col, lsl, usl},
 result = N Rows( dt << get rows where( lsl <= As Column( dt, col ) <= usl ) )
);

colNames = dt << get column names(string, continuous);

resultColList = {};
resultCountList = {};

For(i=1,i<= 10 /*Nitems(colNames)*/,i++,
 specs = column(dt,colNames[i]) << get property("spec limits");
 If(isMissing(try(specs["LSL"],.))==0 & isMissing(try(specs["USL"],.))==0,
  result = count_in_spec(colNames[i],specs["LSL"],specs["USL"]);
  insert into(resultColList,colNames[i]);
  insert into(resultCountList,result)
 )
);

new window("Results",
 outline box("In Spec Report",
  Table Box(
   string col box("Column", resultColList),
   number col box("Count", resultCountList)
  )
 )
);

回复：对规格内的行进行计数的功能

Col Stat（）函数通常对于直接汇总表数据（包括条件）非常有效。 这是一个无需矩阵步骤的示例。

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

count_in_spec = Function( {col, lsl, usl},
 {default local},
 a = Col Sum( lsl < As Column( col ) < usl );
 b = Col Number( col );
 pctpass = 100 * a / b;
 pctfail = 100 - pctpass;
 Eval List( {a, b, pctpass, pctfail} );
);

results = count_in_spec( Column( dt, "height" ), 55, 70 );
countpass = results[1];
countall = results[2];
pctpass = results[3];
pctfail = results[4];

 

回复：对规格内的行进行计数的功能

编辑：我不再推荐此解决方案-使用MS：它显示了一种使用列公式执行此操作的方法；它不仅应该运行得更快，而且列公式还具有支持分组变量的好处。

-布雷迪

 

你好，

 

您可以为此使用内置的矩阵函数。 我在函数内使用<< get作为矩阵，但是我不确定在不使脚本更加繁琐的情况下如何避免这种情况。

 

干杯，

布雷迪

 

Names Default To Here(1);

dt = astable(J(1000, 1, randomnormal(0,3)), <<COLUMN names=""></COLUMN>

 

回复：对规格内的行进行计数的功能

谢谢大家。 我已经探讨了所有三种方法。 然后，我意识到我可以通过使用以下方法使自己更轻松一些：

 

dt0 = current data table();
 dt0 << clear row states;

count_in_spec = Function( { col, lsl, usl },
 a=0; //pass count
 b=0; //all count
 
 cola = dt0:col << get as matrix;
 for( i = 1, i <= N Rows( cola ), i++,
   if( cola[i] >= lsl & cola[i] <= usl, a++ );
   if( not(ismissing( cola[i] )), b++ );
 );

 pctpass = 100*a/b;
 pctfail = 100 - pctpass;
 
 evallist({a, b, pctpass, pctfail});
);



colp = "param1";

results = count_in_spec(colp, 0.15, 0.30 );
 countpass = results[1];
 countall = results[2];
 pctpass = results[3];
 pctfail = results[4];

show(countpass);
show(countall);
show(pctpass);
show(pctfail);


colp = "param2";

results = count_in_spec(colp, 0.15, 0.30);
 countpass = results[1];
 countall = results[2];
 pctpass = results[3];
 pctfail = results[4];

show(countpass);
show(countall);
show(pctpass);
show(pctfail);

从列中提取LSL和USL属性的语法将很有用。