369867_it-IT

liliconcom

Funzione per contare le righe all'interno delle specifiche

Voglio creare una funzione che legge in una colonna, controlla il numero in ogni riga per verificare se rientra nelle specifiche e restituisce il conteggio / conteggio totale / percentuali di passaggio.

 

Questo è quello che ho:

count_in_spec = Function( { col, lsl, usl },
 a=0; //pass count
 b=0; //all count
 for( i = 1, i <= N Rows(col), i++,
  if( col[i] >= lsl & col[i] <= usl, a++ );
  if( not(ismissing(col[i])), b++ );
 );
 pctpass = 100*a/b;
 pctfail = 100 - pctpass;
 
 evallist({a, b, pctpass, pctfail});
);


dt0 = current data table();
colp = dt0:name("param") << get as matrix;

results = count_in_spec(colp, 0.15, 0.30 );
 countpass = results[1];
 countall = results[2];
 pctpass = results[3];
 pctfail = results[4];

Anche se funziona, non mi piace il fatto di dover usare "get as matrix". È un po 'goffo.

 

Vorrei una funzione che funzioni semplicemente scrivendo:

risultati = count_in_spec ("nome parametro", lsl, usl);

 

Come modifico la mia funzione in modo che possa funzionare in questo modo?

ScriptingOggetto: funzione per contare le righe all'interno delle specifiche

Utilizzando la funzione Ottieni righe dove () dovresti ottenere ciò che desideri

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

count_in_spec = Function( {col, lsl, usl},
 result = N Rows( dt << get rows where( lsl <= As Column( dt, col ) <= usl ) )
);

colNames = dt << get column names(string, continuous);

resultColList = {};
resultCountList = {};

For(i=1,i<= 10 /*Nitems(colNames)*/,i++,
 specs = column(dt,colNames[i]) << get property("spec limits");
 If(isMissing(try(specs["LSL"],.))==0 & isMissing(try(specs["USL"],.))==0,
  result = count_in_spec(colNames[i],specs["LSL"],specs["USL"]);
  insert into(resultColList,colNames[i]);
  insert into(resultCountList,result)
 )
);

new window("Results",
 outline box("In Spec Report",
  Table Box(
   string col box("Column", resultColList),
   number col box("Count", resultCountList)
  )
 )
);

Oggetto: funzione per contare le righe all'interno delle specifiche

Le funzioni Col Stat () sono spesso efficienti per riepilogare direttamente i dati della tabella, anche con i condizionali coinvolti. Ecco un esempio senza la necessità di un passaggio della matrice.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

count_in_spec = Function( {col, lsl, usl},
 {default local},
 a = Col Sum( lsl < As Column( col ) < usl );
 b = Col Number( col );
 pctpass = 100 * a / b;
 pctfail = 100 - pctpass;
 Eval List( {a, b, pctpass, pctfail} );
);

results = count_in_spec( Column( dt, "height" ), 55, 70 );
countpass = results[1];
countall = results[2];
pctpass = results[3];
pctfail = results[4];

 

Oggetto: funzione per contare le righe all'interno delle specifiche

EDIT: non posso più raccomandare questa soluzione - usa MS: mostra un modo per farlo usando una formula di colonna; non solo dovrebbe funzionare più velocemente, ma le formule di colonna hanno anche il vantaggio di supportare le variabili di raggruppamento.

-Brady

 

Ciao,

 

È possibile utilizzare le funzioni di matrice incorporate per questo. Uso << get come matrice all'interno della funzione, ma non sono sicuro di come evitarlo senza rendere lo script più ingombrante.

 

Saluti,

Brady

 

Names Default To Here(1);

dt = astable(J(1000, 1, randomnormal(0,3)), <<COLUMN names=""></COLUMN>

 

Oggetto: funzione per contare le righe all'interno delle specifiche

Grazie a tutti. Ho esplorato tutte e tre le categorie di metodi. Poi ho capito che avrei potuto rendere le cose un po 'più facili per me stesso usando qualcosa del genere:

 

dt0 = current data table();
 dt0 << clear row states;

count_in_spec = Function( { col, lsl, usl },
 a=0; //pass count
 b=0; //all count
 
 cola = dt0:col << get as matrix;
 for( i = 1, i <= N Rows( cola ), i++,
   if( cola[i] >= lsl & cola[i] <= usl, a++ );
   if( not(ismissing( cola[i] )), b++ );
 );

 pctpass = 100*a/b;
 pctfail = 100 - pctpass;
 
 evallist({a, b, pctpass, pctfail});
);



colp = "param1";

results = count_in_spec(colp, 0.15, 0.30 );
 countpass = results[1];
 countall = results[2];
 pctpass = results[3];
 pctfail = results[4];

show(countpass);
show(countall);
show(pctpass);
show(pctfail);


colp = "param2";

results = count_in_spec(colp, 0.15, 0.30);
 countpass = results[1];
 countall = results[2];
 pctpass = results[3];
 pctfail = results[4];

show(countpass);
show(countall);
show(pctpass);
show(pctfail);

La sintassi per estrarre le proprietà LSL e USL da una colonna sarà utile.