369867_es-ES

liliconcom

Función para contar filas dentro de la especificación

Quiero crear una función que lea en una columna, verifique el número en cada fila para ver si está dentro de las especificaciones y generará el recuento de aprobados / recuento total / porcentajes.

 

Esto es lo que tengo:

count_in_spec = Function( { col, lsl, usl },
 a=0; //pass count
 b=0; //all count
 for( i = 1, i <= N Rows(col), i++,
  if( col[i] >= lsl & col[i] <= usl, a++ );
  if( not(ismissing(col[i])), b++ );
 );
 pctpass = 100*a/b;
 pctfail = 100 - pctpass;
 
 evallist({a, b, pctpass, pctfail});
);


dt0 = current data table();
colp = dt0:name("param") << get as matrix;

results = count_in_spec(colp, 0.15, 0.30 );
 countpass = results[1];
 countall = results[2];
 pctpass = results[3];
 pctfail = results[4];

Si bien esto funciona, no me gusta el hecho de que necesito usar "get as matrix". Es un poco torpe.

 

Me gustaría una función que funcione simplemente escribiendo:

resultados = count_in_spec ("nombre de parámetro", lsl, usl);

 

¿Cómo modificaría mi función para que funcione de esta manera?

ScriptingRe: función para contar filas dentro de la especificación

El uso de la función Get Rows Where () debería obtener lo que desea

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

count_in_spec = Function( {col, lsl, usl},
 result = N Rows( dt << get rows where( lsl <= As Column( dt, col ) <= usl ) )
);

colNames = dt << get column names(string, continuous);

resultColList = {};
resultCountList = {};

For(i=1,i<= 10 /*Nitems(colNames)*/,i++,
 specs = column(dt,colNames[i]) << get property("spec limits");
 If(isMissing(try(specs["LSL"],.))==0 & isMissing(try(specs["USL"],.))==0,
  result = count_in_spec(colNames[i],specs["LSL"],specs["USL"]);
  insert into(resultColList,colNames[i]);
  insert into(resultCountList,result)
 )
);

new window("Results",
 outline box("In Spec Report",
  Table Box(
   string col box("Column", resultColList),
   number col box("Count", resultCountList)
  )
 )
);

Re: función para contar filas dentro de la especificación

Las funciones Col Stat () a menudo son eficientes para resumir directamente los datos de la tabla, también con condicionales involucrados. Aquí hay un ejemplo sin la necesidad de un paso de matriz.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

count_in_spec = Function( {col, lsl, usl},
 {default local},
 a = Col Sum( lsl < As Column( col ) < usl );
 b = Col Number( col );
 pctpass = 100 * a / b;
 pctfail = 100 - pctpass;
 Eval List( {a, b, pctpass, pctfail} );
);

results = count_in_spec( Column( dt, "height" ), 55, 70 );
countpass = results[1];
countall = results[2];
pctpass = results[3];
pctfail = results[4];

 

Re: función para contar filas dentro de la especificación

EDITAR: Ya no puedo recomendar esta solución, use MS: muestra una forma de hacer esto usando una fórmula de columna; no solo debería ejecutarse más rápido, sino que las fórmulas de columna también tienen la ventaja de admitir variables de agrupación.

-Brady

 

Hola,

 

Puede utilizar las funciones de matriz integradas para esto. Utilizo << obtener como matriz dentro de la función, pero no estoy seguro de cómo evitarlo sin hacer que el script sea más engorroso.

 

Salud,

Brady

 

Names Default To Here(1);

dt = astable(J(1000, 1, randomnormal(0,3)), <<COLUMN names=""></COLUMN>

 

Re: función para contar filas dentro de la especificación

Gracias a todos. He explorado las tres categorías de métodos. Luego me di cuenta de que podría haberme facilitado un poco las cosas usando algo como esto:

 

dt0 = current data table();
 dt0 << clear row states;

count_in_spec = Function( { col, lsl, usl },
 a=0; //pass count
 b=0; //all count
 
 cola = dt0:col << get as matrix;
 for( i = 1, i <= N Rows( cola ), i++,
   if( cola[i] >= lsl & cola[i] <= usl, a++ );
   if( not(ismissing( cola[i] )), b++ );
 );

 pctpass = 100*a/b;
 pctfail = 100 - pctpass;
 
 evallist({a, b, pctpass, pctfail});
);



colp = "param1";

results = count_in_spec(colp, 0.15, 0.30 );
 countpass = results[1];
 countall = results[2];
 pctpass = results[3];
 pctfail = results[4];

show(countpass);
show(countall);
show(pctpass);
show(pctfail);


colp = "param2";

results = count_in_spec(colp, 0.15, 0.30);
 countpass = results[1];
 countall = results[2];
 pctpass = results[3];
 pctfail = results[4];

show(countpass);
show(countall);
show(pctpass);
show(pctfail);

La sintaxis para extraer propiedades LSL y USL de una columna será útil.